openMSP430之Custom linker script

　　The use of the -mmcu switch is of course NOT mandatory. It is simply a convenient way to use the pre-existing linker scripts provided with the MSPGCC4 toolchain. However, if the peripheral address space is larger than the standard 512B of the original MSP430 (see the Advanced System Configuration section), a customized linker script MUST be provided.

　　To create a custom linker script, the simplest way is to start from an existing one:
　　• The MSPGCC(4) toolchain provides a wide range of examples for all supported MSP430 models (see “msp430/lib/ldscripts/” sub-directory in the MSPGCC(4) installation directory).

　　• The openMSP430 project also provide a simple linker script example:
　　　　ldscript_example.x

From there, the script can be modified to match YOUR openMSP430 configuration:

　　• In the text (rx) section definition, update the ORIGIN and LENGTH fields to match the PROGRAM MEMORY configuration.
　　• In the data (rwx) section definition, update the ORIGIN field to match the PERIPHERAL SPACE configuration and the LENGTH field to match the DATA MEMORY configuration.

ldscript_example.x

 /* Default linker script, for normal executables */
 OUTPUT_FORMAT("elf32-msp430")
 OUTPUT_ARCH("msp430")
 MEMORY
 {
   data    (rwx)      : ORIGIN = 0x0200,     LENGTH = 0x0080
   text    (rx)       : ORIGIN = 0xf800,      LENGTH = 0x0800-0x20
   vectors (rw)      : ORIGIN = 0xffe0,      LENGTH = 0x20
 }
 REGION_ALIAS("REGION_TEXT", text);
 REGION_ALIAS("REGION_DATA", data);
 __WDTCTL = 0x0120;
 __MPY    = 0x0130;
 __MPYS   = 0x0132;
 __MAC    = 0x0134;
 __MACS   = 0x0136;
 __OP2    = 0x0138;
 __RESLO  = 0x013A;
 __RESHI  = 0x013C;
 __SUMEXT = 0x013E;

 SECTIONS
 {
   /* Read-only sections, merged into text segment.  */
   .hash          : { *(.hash)             }
   .dynsym        : { *(.dynsym)           }
   .dynstr        : { *(.dynstr)           }
   .gnu.version   : { *(.gnu.version)      }
   .gnu.version_d   : { *(.gnu.version_d)  }
   .gnu.version_r   : { *(.gnu.version_r)  }
   .rel.init      : { *(.rel.init) }
   .rela.init     : { *(.rela.init) }
   .rel.text      :
     {
       *(.rel.text)
       *(.rel.text.*)
       *(.rel.gnu.linkonce.t*)
     }
   .rela.text     :
     {
       *(.rela.text)
       *(.rela.text.*)
       *(.rela.gnu.linkonce.t*)
     }
   .rel.fini      : { *(.rel.fini) }
   .rela.fini     : { *(.rela.fini) }
   .rel.rodata    :
     {
       *(.rel.rodata)
       *(.rel.rodata.*)
       *(.rel.gnu.linkonce.r*)
     }
   .rela.rodata   :
     {
       *(.rela.rodata)
       *(.rela.rodata.*)
       *(.rela.gnu.linkonce.r*)
     }
   .rel.data      :
     {
       *(.rel.data)
       *(.rel.data.*)
       *(.rel.gnu.linkonce.d*)
     }
   .rela.data     :
     {
       *(.rela.data)
       *(.rela.data.*)
       *(.rela.gnu.linkonce.d*)
     }
   .rel.ctors     : { *(.rel.ctors)        }
   .rela.ctors    : { *(.rela.ctors)       }
   .rel.dtors     : { *(.rel.dtors)        }
   .rela.dtors    : { *(.rela.dtors)       }
   .rel.got       : { *(.rel.got)          }
   .rela.got      : { *(.rela.got)         }
   .rel.bss       : { *(.rel.bss)          }
   .rela.bss      : { *(.rela.bss)         }
   .rel.plt       : { *(.rel.plt)          }
   .rela.plt      : { *(.rela.plt)         }
   /* Internal text space.  */
   .text :
   {
     . = ALIGN();
     *(.init)
     *(.init0)  /* Start here after reset.  */
     *(.init1)
     *(.init2)  /* Copy data loop  */
     *(.init3)
     *(.init4)  /* Clear bss  */
     *(.init5)
     *(.init6)  /* C++ constructors.  */
     *(.init7)
     *(.init8)
     *(.init9)  /* Call main().  */
      __ctors_start = . ;
      *(.ctors)
      __ctors_end = . ;
      __dtors_start = . ;
      *(.dtors)
      __dtors_end = . ;
     . = ALIGN();
     *(.text)
     . = ALIGN();
     *(.text.*)
     . = ALIGN();
     *(.fini9)  /*   */
     *(.fini8)
     *(.fini7)
     *(.fini6)  /* C++ destructors.  */
     *(.fini5)
     *(.fini4)
     *(.fini3)
     *(.fini2)
     *(.fini1)
     *(.fini0)  /* Infinite loop after program termination.  */
     *(.fini)
   }  > text
   .rodata   :
   {
      . = ALIGN();
     *(.rodata .rodata.* .gnu.linkonce.r.*)
      . = ALIGN();
   }  > text
    _etext = .; /* Past last read-only (loadable) segment */
   .data   : AT (ADDR (.text) + SIZEOF (.text) + SIZEOF (.rodata) )
   {
      PROVIDE (__data_start = .) ;
     . = ALIGN();
     *(.data)
     . = ALIGN();
     *(.gnu.linkonce.d*)
     . = ALIGN();
      _edata = . ;
   }  > data
    PROVIDE (__data_load_start = LOADADDR(.data) );
    PROVIDE (__data_size = SIZEOF(.data) );
   .bss  SIZEOF(.data) + ADDR(.data) :
   {
      PROVIDE (__bss_start = .) ;
     *(.bss)
     *(COMMON)
      PROVIDE (__bss_end = .) ;
      _end = . ;
   }  > data
    PROVIDE (__bss_size = SIZEOF(.bss) );
   .noinit  SIZEOF(.bss) + ADDR(.bss) :
   {
      PROVIDE (__noinit_start = .) ;
     *(.noinit)
     *(COMMON)
      PROVIDE (__noinit_end = .) ;
      _end = . ;
   }  > data
   .vectors  :
   {
      PROVIDE (__vectors_start = .) ;
     *(.vectors*)
      _vectors_end = . ;
   }  > vectors
   /* Stabs for profiling information*/
   .profiler  : { *(.profiler) }
   /* Stabs debugging sections.  */
   .stab  : { *(.stab) }
   .stabstr  : { *(.stabstr) }
   .stab.excl  : { *(.stab.excl) }
   .stab.exclstr  : { *(.stab.exclstr) }
   .stab.index  : { *(.stab.index) }
   .stab.indexstr  : { *(.stab.indexstr) }
   .comment  : { *(.comment) }
   /* DWARF debug sections.
      Symbols in the DWARF debugging sections are relative to the beginning
      of the section so we begin them at 0.  */
   /* DWARF 1 */
   .debug           : { *(.debug) }
   .line            : { *(.line) }
   /* GNU DWARF 1 extensions */
   .debug_srcinfo   : { *(.debug_srcinfo) }
   .debug_sfnames   : { *(.debug_sfnames) }
   /* DWARF 1.1 and DWARF 2 */
   .debug_aranges   : { *(.debug_aranges) }
   .debug_pubnames  : { *(.debug_pubnames) }
   /* DWARF 2 */
   .debug_info      : { *(.debug_info) *(.gnu.linkonce.wi.*) }
   .debug_abbrev    : { *(.debug_abbrev) }
   .debug_line      : { *(.debug_line) }
   .debug_frame     : { *(.debug_frame) }
   .debug_str       : { *(.debug_str) }
   .debug_loc       : { *(.debug_loc) }
   .debug_macinfo   : { *(.debug_macinfo) }
   PROVIDE (__stack = ORIGIN(data) + LENGTH(data));
   PROVIDE (__data_start_rom = _etext) ;
   PROVIDE (__data_end_rom   = _etext + SIZEOF (.data)) ;
 }