SQL With AS Expression

A. Creating a simple common table expression

The following example shows the total number of sales orders per year for each sales representative at Adventure Works Cycles.

SQLCopy

-- Define the CTE expression name and column list.

WITH Sales_CTE (SalesPersonID, SalesOrderID, SalesYear)

AS

-- Define the CTE query.

(

    SELECT SalesPersonID, SalesOrderID, YEAR(OrderDate) AS SalesYear

    FROM Sales.SalesOrderHeader

    WHERE SalesPersonID IS NOT NULL

)

-- Define the outer query referencing the CTE name.

SELECT SalesPersonID, COUNT(SalesOrderID) AS TotalSales, SalesYear

FROM Sales_CTE

GROUP BY SalesYear, SalesPersonID

ORDER BY SalesPersonID, SalesYear;

B. Using a common table expression to limit counts and report averages

The following example shows the average number of sales orders for all years for the sales representatives.

SQLCopy

WITH Sales_CTE (SalesPersonID, NumberOfOrders)

AS

(

    SELECT SalesPersonID, COUNT(*)

    FROM Sales.SalesOrderHeader

    WHERE SalesPersonID IS NOT NULL

    GROUP BY SalesPersonID

)

SELECT AVG(NumberOfOrders) AS "Average Sales Per Person"

FROM Sales_CTE;

C. Using multiple CTE definitions in a single query

The following example shows how to define more than one CTE in a single query. Notice that a comma is used to separate the CTE query definitions. The FORMAT function, used to display the monetary amounts in a currency format, is available in SQL Server 2012 and higher.

SQLCopy

WITH Sales_CTE (SalesPersonID, TotalSales, SalesYear)

AS

-- Define the first CTE query.

(

    SELECT SalesPersonID, SUM(TotalDue) AS TotalSales, YEAR(OrderDate) AS SalesYear

    FROM Sales.SalesOrderHeader

    WHERE SalesPersonID IS NOT NULL

       GROUP BY SalesPersonID, YEAR(OrderDate)  

)

,   -- Use a comma to separate multiple CTE definitions.  

-- Define the second CTE query, which returns sales quota data by year for each sales person.

Sales_Quota_CTE (BusinessEntityID, SalesQuota, SalesQuotaYear)

AS

(

       SELECT BusinessEntityID, SUM(SalesQuota)AS SalesQuota, YEAR(QuotaDate) AS SalesQuotaYear

       FROM Sales.SalesPersonQuotaHistory

       GROUP BY BusinessEntityID, YEAR(QuotaDate)

)  

-- Define the outer query by referencing columns from both CTEs.

SELECT SalesPersonID

  , SalesYear

  , FORMAT(TotalSales,'C','en-us') AS TotalSales

  , SalesQuotaYear

  , FORMAT (SalesQuota,'C','en-us') AS SalesQuota

  , FORMAT (TotalSales -SalesQuota, 'C','en-us') AS Amt_Above_or_Below_Quota

FROM Sales_CTE

JOIN Sales_Quota_CTE ON Sales_Quota_CTE.BusinessEntityID = Sales_CTE.SalesPersonID

                    AND Sales_CTE.SalesYear = Sales_Quota_CTE.SalesQuotaYear

ORDER BY SalesPersonID, SalesYear;

Here is a partial result set.

Copy

SalesPersonID SalesYear   TotalSales    SalesQuotaYear SalesQuota  Amt_Above_or_Below_Quota

------------- ---------   -----------   -------------- ---------- ----------------------------------

274           2005        $32,567.92    2005           $35,000.00  ($2,432.08)

274           2006        $406,620.07   2006           $455,000.00 ($48,379.93)

274           2007        $515,622.91   2007           $544,000.00 ($28,377.09)

274           2008        $281,123.55   2008           $271,000.00  $10,123.55

D. Using a recursive common table expression to display multiple levels of recursion

The following example shows the hierarchical list of managers and the employees who report to them. The example begins by creating and populating the dbo.MyEmployees table.

SQLCopy

-- Create an Employee table.

CREATE TABLE dbo.MyEmployees

(

EmployeeID smallint NOT NULL,

FirstName nvarchar(30)  NOT NULL,

LastName  nvarchar(40) NOT NULL,

Title nvarchar(50) NOT NULL,

DeptID smallint NOT NULL,

ManagerID int NULL,

 CONSTRAINT PK_EmployeeID PRIMARY KEY CLUSTERED (EmployeeID ASC)

);

-- Populate the table with values.

INSERT INTO dbo.MyEmployees VALUES

 (1, N'Ken', N'Sánchez', N'Chief Executive Officer',16,NULL)

,(273, N'Brian', N'Welcker', N'Vice President of Sales',3,1)

,(274, N'Stephen', N'Jiang', N'North American Sales Manager',3,273)

,(275, N'Michael', N'Blythe', N'Sales Representative',3,274)

,(276, N'Linda', N'Mitchell', N'Sales Representative',3,274)

,(285, N'Syed', N'Abbas', N'Pacific Sales Manager',3,273)

,(286, N'Lynn', N'Tsoflias', N'Sales Representative',3,285)

,(16,  N'David',N'Bradley', N'Marketing Manager', 4, 273)

,(23,  N'Mary', N'Gibson', N'Marketing Specialist', 4, 16);

SQLCopy

USE AdventureWorks2012;

GO

WITH DirectReports(ManagerID, EmployeeID, Title, EmployeeLevel) AS

(

    SELECT ManagerID, EmployeeID, Title, 0 AS EmployeeLevel

    FROM dbo.MyEmployees

    WHERE ManagerID IS NULL

    UNION ALL

    SELECT e.ManagerID, e.EmployeeID, e.Title, EmployeeLevel + 1

    FROM dbo.MyEmployees AS e

        INNER JOIN DirectReports AS d

        ON e.ManagerID = d.EmployeeID

)

SELECT ManagerID, EmployeeID, Title, EmployeeLevel

FROM DirectReports

ORDER BY ManagerID;

E. Using a recursive common table expression to display two levels of recursion

The following example shows managers and the employees reporting to them. The number of levels returned is limited to two.

SQLCopy

USE AdventureWorks2012;

GO

WITH DirectReports(ManagerID, EmployeeID, Title, EmployeeLevel) AS

(

    SELECT ManagerID, EmployeeID, Title, 0 AS EmployeeLevel

    FROM dbo.MyEmployees

    WHERE ManagerID IS NULL

    UNION ALL

    SELECT e.ManagerID, e.EmployeeID, e.Title, EmployeeLevel + 1

    FROM dbo.MyEmployees AS e

        INNER JOIN DirectReports AS d

        ON e.ManagerID = d.EmployeeID

)

SELECT ManagerID, EmployeeID, Title, EmployeeLevel

FROM DirectReports

WHERE EmployeeLevel <= 2 ;

F. Using a recursive common table expression to display a hierarchical list

The following example builds on Example D by adding the names of the manager and employees, and their respective titles. The hierarchy of managers and employees is additionally emphasized by indenting each level.

SQLCopy

USE AdventureWorks2012;

GO

WITH DirectReports(Name, Title, EmployeeID, EmployeeLevel, Sort)

AS (SELECT CONVERT(varchar(255), e.FirstName + ' ' + e.LastName),

        e.Title,

        e.EmployeeID,

        1,

        CONVERT(varchar(255), e.FirstName + ' ' + e.LastName)

    FROM dbo.MyEmployees AS e

    WHERE e.ManagerID IS NULL

    UNION ALL

    SELECT CONVERT(varchar(255), REPLICATE ('|    ' , EmployeeLevel) +

        e.FirstName + ' ' + e.LastName),

        e.Title,

        e.EmployeeID,

        EmployeeLevel + 1,

        CONVERT (varchar(255), RTRIM(Sort) + '|    ' + FirstName + ' ' +

                 LastName)

    FROM dbo.MyEmployees AS e

    JOIN DirectReports AS d ON e.ManagerID = d.EmployeeID

    )

SELECT EmployeeID, Name, Title, EmployeeLevel

FROM DirectReports

ORDER BY Sort;

G. Using MAXRECURSION to cancel a statement

MAXRECURSION can be used to prevent a poorly formed recursive CTE from entering into an infinite loop. The following example intentionally creates an infinite loop and uses the MAXRECURSION hint to limit the number of recursion levels to two.

SQLCopy

USE AdventureWorks2012;

GO

--Creates an infinite loop

WITH cte (EmployeeID, ManagerID, Title) as

(

    SELECT EmployeeID, ManagerID, Title

    FROM dbo.MyEmployees

    WHERE ManagerID IS NOT NULL

  UNION ALL

    SELECT cte.EmployeeID, cte.ManagerID, cte.Title

    FROM cte

    JOIN  dbo.MyEmployees AS e

        ON cte.ManagerID = e.EmployeeID

)

--Uses MAXRECURSION to limit the recursive levels to 2

SELECT EmployeeID, ManagerID, Title

FROM cte

OPTION (MAXRECURSION 2);

After the coding error is corrected, MAXRECURSION is no longer required. The following example shows the corrected code.

SQLCopy

USE AdventureWorks2012;

GO

WITH cte (EmployeeID, ManagerID, Title)

AS

(

    SELECT EmployeeID, ManagerID, Title

    FROM dbo.MyEmployees

    WHERE ManagerID IS NOT NULL

  UNION ALL

    SELECT  e.EmployeeID, e.ManagerID, e.Title

    FROM dbo.MyEmployees AS e

    JOIN cte ON e.ManagerID = cte.EmployeeID

)

SELECT EmployeeID, ManagerID, Title

FROM cte;

H. Using a common table expression to selectively step through a recursive relationship in a SELECT statement

The following example shows the hierarchy of product assemblies and components that are required to build the bicycle for ProductAssemblyID = 800.

SQLCopy

USE AdventureWorks2012;

GO

WITH Parts(AssemblyID, ComponentID, PerAssemblyQty, EndDate, ComponentLevel) AS

(

    SELECT b.ProductAssemblyID, b.ComponentID, b.PerAssemblyQty,

        b.EndDate, 0 AS ComponentLevel

    FROM Production.BillOfMaterials AS b

    WHERE b.ProductAssemblyID = 800

          AND b.EndDate IS NULL

    UNION ALL

    SELECT bom.ProductAssemblyID, bom.ComponentID, p.PerAssemblyQty,

        bom.EndDate, ComponentLevel + 1

    FROM Production.BillOfMaterials AS bom

        INNER JOIN Parts AS p

        ON bom.ProductAssemblyID = p.ComponentID

        AND bom.EndDate IS NULL

)

SELECT AssemblyID, ComponentID, Name, PerAssemblyQty, EndDate,

        ComponentLevel

FROM Parts AS p

    INNER JOIN Production.Product AS pr

    ON p.ComponentID = pr.ProductID

ORDER BY ComponentLevel, AssemblyID, ComponentID;

I. Using a recursive CTE in an UPDATE statement

The following example updates the PerAssemblyQty value for all parts that are used to build the product 'Road-550-W Yellow, 44' (ProductAssemblyID``800). The common table expression returns a hierarchical list of parts that are used to build ProductAssemblyID 800 and the components that are used to create those parts, and so on. Only the rows returned by the common table expression are modified.

SQLCopy

USE AdventureWorks2012;

GO

WITH Parts(AssemblyID, ComponentID, PerAssemblyQty, EndDate, ComponentLevel) AS

(

    SELECT b.ProductAssemblyID, b.ComponentID, b.PerAssemblyQty,

        b.EndDate, 0 AS ComponentLevel

    FROM Production.BillOfMaterials AS b

    WHERE b.ProductAssemblyID = 800

          AND b.EndDate IS NULL

    UNION ALL

    SELECT bom.ProductAssemblyID, bom.ComponentID, p.PerAssemblyQty,

        bom.EndDate, ComponentLevel + 1

    FROM Production.BillOfMaterials AS bom

        INNER JOIN Parts AS p

        ON bom.ProductAssemblyID = p.ComponentID

        AND bom.EndDate IS NULL

)

UPDATE Production.BillOfMaterials

SET PerAssemblyQty = c.PerAssemblyQty * 2

FROM Production.BillOfMaterials AS c

JOIN Parts AS d ON c.ProductAssemblyID = d.AssemblyID

WHERE d.ComponentLevel = 0;

J. Using multiple anchor and recursive members

The following example uses multiple anchor and recursive members to return all the ancestors of a specified person. A table is created and values inserted to establish the family genealogy returned by the recursive CTE.

SQLCopy

-- Genealogy table

IF OBJECT_ID('dbo.Person','U') IS NOT NULL DROP TABLE dbo.Person;

GO

CREATE TABLE dbo.Person(ID int, Name varchar(30), Mother int, Father int);

GO

INSERT dbo.Person

VALUES(1, 'Sue', NULL, NULL)

      ,(2, 'Ed', NULL, NULL)

      ,(3, 'Emma', 1, 2)

      ,(4, 'Jack', 1, 2)

      ,(5, 'Jane', NULL, NULL)

      ,(6, 'Bonnie', 5, 4)

      ,(7, 'Bill', 5, 4);

GO

-- Create the recursive CTE to find all of Bonnie's ancestors.

WITH Generation (ID) AS

(

-- First anchor member returns Bonnie's mother.

    SELECT Mother

    FROM dbo.Person

    WHERE Name = 'Bonnie'

UNION

-- Second anchor member returns Bonnie's father.

    SELECT Father

    FROM dbo.Person

    WHERE Name = 'Bonnie'

UNION ALL

-- First recursive member returns male ancestors of the previous generation.

    SELECT Person.Father

    FROM Generation, Person

    WHERE Generation.ID=Person.ID

UNION ALL

-- Second recursive member returns female ancestors of the previous generation.

    SELECT Person.Mother

    FROM Generation, dbo.Person

    WHERE Generation.ID=Person.ID

)

SELECT Person.ID, Person.Name, Person.Mother, Person.Father

FROM Generation, dbo.Person

WHERE Generation.ID = Person.ID;

GO

K. Using analytical functions in a recursive CTE

The following example shows a pitfall that can occur when using an analytical or aggregate function in the recursive part of a CTE.

SQLCopy

DECLARE @t1 TABLE (itmID int, itmIDComp int);

INSERT @t1 VALUES (1,10), (2,10);   

DECLARE @t2 TABLE (itmID int, itmIDComp int);

INSERT @t2 VALUES (3,10), (4,10);   

WITH vw AS

 (

    SELECT itmIDComp, itmID

    FROM @t1  

    UNION ALL  

    SELECT itmIDComp, itmID

    FROM @t2

)

,r AS

 (

    SELECT t.itmID AS itmIDComp

           , NULL AS itmID

           ,CAST(0 AS bigint) AS N

           ,1 AS Lvl

    FROM (SELECT 1 UNION ALL SELECT 2 UNION ALL SELECT 3 UNION ALL SELECT 4) AS t (itmID)   

UNION ALL  

SELECT t.itmIDComp

    , t.itmID

    , ROW_NUMBER() OVER(PARTITION BY t.itmIDComp ORDER BY t.itmIDComp, t.itmID) AS N

    , Lvl + 1

FROM r

    JOIN vw AS t ON t.itmID = r.itmIDComp

)   

SELECT Lvl, N FROM r;

The following results are the expected results for the query.

Copy

The following results are the actual results for the query.

Copy

N returns 1 for each pass of the recursive part of the CTE because only the subset of data for that recursion level is passed to ROWNUMBER. For each of the iterations of the recursive part of the query, only one row is passed to ROWNUMBER.

Examples: SQL Data Warehouse and Parallel Data Warehouse

L. Using a common table expression within a CTAS statement

The following example creates a new table containing the total number of sales orders per year for each sales representative at Adventure Works Cycles.

SQLCopy

USE AdventureWorks2012;

GO

CREATE TABLE SalesOrdersPerYear

WITH

(

    DISTRIBUTION = HASH(SalesPersonID)

)

AS

    -- Define the CTE expression name and column list.

    WITH Sales_CTE (SalesPersonID, SalesOrderID, SalesYear)

    AS

    -- Define the CTE query.

    (

        SELECT SalesPersonID, SalesOrderID, YEAR(OrderDate) AS SalesYear

        FROM Sales.SalesOrderHeader

        WHERE SalesPersonID IS NOT NULL

    )

    -- Define the outer query referencing the CTE name.

    SELECT SalesPersonID, COUNT(SalesOrderID) AS TotalSales, SalesYear

    FROM Sales_CTE

    GROUP BY SalesYear, SalesPersonID

    ORDER BY SalesPersonID, SalesYear;

GO

M. Using a common table expression within a CETAS statement

The following example creates a new external table containing the total number of sales orders per year for each sales representative at Adventure Works Cycles.

SQLCopy

USE AdventureWorks2012;

GO

CREATE EXTERNAL TABLE SalesOrdersPerYear

WITH

(

    LOCATION = 'hdfs://xxx.xxx.xxx.xxx:5000/files/Customer',

    FORMAT_OPTIONS ( FIELD_TERMINATOR = '|' )

)

AS

    -- Define the CTE expression name and column list.

    WITH Sales_CTE (SalesPersonID, SalesOrderID, SalesYear)

    AS

    -- Define the CTE query.

    (

        SELECT SalesPersonID, SalesOrderID, YEAR(OrderDate) AS SalesYear

        FROM Sales.SalesOrderHeader

        WHERE SalesPersonID IS NOT NULL

    )

    -- Define the outer query referencing the CTE name.

    SELECT SalesPersonID, COUNT(SalesOrderID) AS TotalSales, SalesYear

    FROM Sales_CTE

    GROUP BY SalesYear, SalesPersonID

    ORDER BY SalesPersonID, SalesYear;

GO

N. Using multiple comma separated CTEs in a statement

The following example demonstrates including two CTEs in a single statement. The CTEs cannot be nested (no recursion).

SQLCopy

WITH

 CountDate (TotalCount, TableName) AS

    (

     SELECT COUNT(datekey), 'DimDate' FROM DimDate

    ) ,

 CountCustomer (TotalAvg, TableName) AS

    (

     SELECT COUNT(CustomerKey), 'DimCustomer' FROM DimCustomer

    )

SELECT TableName, TotalCount FROM CountDate

UNION ALL

SELECT TableName, TotalAvg FROM CountCustomer;