as3中的embed

actionscript3允许把外部swf直接用Embed标记嵌入到主类中(当然用UrlLoader动态加载也行)

原 作者：菩提树下的杨过
出处：http://yjmyzz.cnblogs.com

关键点：

设计师把素材放入到库中时，一定要指定类名，这样代码才能创建这些类的实例。

如上图所示，这里库中放了三种基本的素材(按钮，位图，电影夹)，然后在代码中可以这样处理：

 package
 {

     import flash.display.Sprite;
     import flash.display.DisplayObject;
     import flash.display.SimpleButton;
     import flash.events.MouseEvent;
     import flash.display.MovieClip;
     import flash.display.BitmapData;
     import flash.display.Bitmap;

     public class Demo extends MovieClip
     {
         [Embed(source = "skin.swf",symbol = "ButtonPause")]
         private var ButtonPause:Class;

         [Embed(source = "skin.swf",symbol = "ButtonPlay")]
         private var ButtonPlay:Class;

         [Embed(source = "skin.swf",symbol = "LogoImage")]
         private var LogoImage:Class;

         [Embed(source = "skin.swf",symbol = "TestMovie")]
         private var TestMovie:Class;

         public function Demo()
         {
             init();
         }

         private function init():void
         {
             var btnTest:SimpleButton = new ButtonPause() as SimpleButton;
             trace(btnTest,btnTest is SimpleButton);//Demo_ButtonPause0,true
             addChild(btnTest);
             btnTest.x = btnTest.y = 50;
             btnTest.addEventListener(MouseEvent.CLICK,btnTestClick);

             var btnTest2:SimpleButton = new ButtonPlay() as SimpleButton;
             trace(btnTest2);//Demo_ButtonPlay1
             addChild(btnTest2);
             btnTest2.y = 50;
             btnTest2.x = 100;
             btnTest2.addEventListener(MouseEvent.CLICK,btnTest2Click);

             var bmd:Bitmap = new LogoImage() as Bitmap;
             trace(bmd);//Demo_LogoImage2
             addChild(bmd);
             bmd.x = bmd.y = 200;

             var testMovie:MovieClip = new TestMovie() as MovieClip;
             addChild(testMovie);
             testMovie.x = testMovie.y = 180;
             trace(testMovie);//Demo_TestMovie3

         }

         private function btnTestClick(e:MouseEvent):void
         {
             trace("btnTest 被点击了!");
         }

         private function btnTest2Click(e:MouseEvent):void
         {
             trace("btnTest2 被点击了!");
         }
     }

 }

 

 

Embed 后面还跟着一个symbol属性，该属性就是指明你要调用哪一个MC，就是SWF里面的MC，记得，都要为每个MC做链接，并链接名字要与symbol里的名字致

 

 

作者：菩提树下的杨过
出处：http://yjmyzz.cnblogs.com 
本文版权归作者和博客园共有，欢迎转载，但未经作者同意必须保留此段声明，且在文章页面明显位置给出原文连接，否则保留追究法律责任的权利。

 

分类: 12.Flex/Flash/AS3.0

标签: flash, 协同开发, 界面, 代码, 分离