sqlserver 使用脚本创建作业
- --【作业常用的几个步骤】
- EXEC msdb.dbo.sp_delete_job
- EXEC msdb.dbo.sp_add_job
- EXEC msdb.dbo.sp_add_jobstep
- EXEC msdb..sp_add_jobschedule
- EXEC msdb.dbo.sp_add_jobserver
- EXEC msdb.dbo.sp_start_job
- --删除作业
- IF EXISTS (SELECT JOB_ID FROM MSDB.DBO.SYSJOBS_VIEW WHERE NAME =N'作业名称')
- EXECUTE MSDB.DBO.SP_DELETE_JOB @JOB_NAME=N'作业名称'
- --定义创建作业
- DECLARE @jobid uniqueidentifier
- EXEC msdb.dbo.sp_add_job
- @job_name = N'作业名称',
- @job_id = @jobid OUTPUT
- --定义作业步骤
- DECLARE @sql nvarchar(400),@dbname sysname
- SELECT @dbname=DB_NAME(), --执行的数据库（当前）
- @sql=N'作业步骤内容' --一般定义的是使用TSQL处理的作业,这里定义要执行的Transact-SQL语句
- EXEC msdb.dbo.sp_add_jobstep
- @job_id = @jobid,
- @step_name = N'作业步骤名称',
- @subsystem = 'TSQL', --步骤的类型,一般为TSQL
- @database_name=@dbname,
- @command = @sql
- --创建调度(使用后面专门定义的几种作业调度模板)
- EXEC msdb..sp_add_jobschedule
- @job_id = @jobid,
- @name = N'调度名称',
- @freq_type=4, --每天
- @freq_interval=1, --指定每多少天发生一次,这里是1天.
- @freq_subday_type=0x8, --重复方式,0x1=在指定的时间,0x4=多少分钟,0x8=多少小时执行一次
- @freq_subday_interval=1, --重复周期数,这里每小时执行一次
- @active_start_date = NULL, --作业执行的开始日期,为NULL时表示当前日期,格式为YYYYMMDD
- @active_end_date = 99991231, --作业执行的停止日期,默认为99991231,格式为YYYYMMDD
- @active_start_time = 00000, --作业执行的开始时间,格式为HHMMSS
- @active_end_time = 235959 --作业执行的停止时间,格式为HHMMSS
- --添加目标服务器
- DECLARE @servername sysname
- SET @servername=CONVERT(nvarchar(128),SERVERPROPERTY(N'ServerName'))--当前SQL实例
- EXEC msdb.dbo.sp_add_jobserver
- @job_id = @jobid,
- @server_name = @servername
- -----------------------------------------------------------------------------------------------
- --调度模板定义 sp_add_jobschedule
- --只执行一次的作业调度
- EXEC msdb..sp_add_jobschedule
- @job_id = @jobid,
- @name = N'调度名称',
- @freq_type=1, --仅执行一次
- @active_start_date = NULL, --作业执行的开始日期,为NULL时表示当前日期,格式为YYYYMMDD
- @active_start_time = 00000 --作业执行的开始时间,格式为HHMMSS
- --日调度
- EXEC msdb..sp_add_jobschedule
- @job_id = @jobid,
- @name = N'调度名称',
- @freq_type=4, --每天
- @freq_interval=1, --指定每多少天发生一次,这里是1天.
- @freq_subday_type=0x8, --重复方式,(0x1=指定的时间;0x4=多少分钟;0x8=多少小时)执行一次
- @freq_subday_interval=1, --重复周期数,这里每小时执行一次
- @active_start_date = NULL, --作业执行的开始日期,为NULL时表示当前日期,格式为YYYYMMDD
- @active_end_date = 99991231, --作业执行的停止日期,默认为99991231,格式为YYYYMMDD
- @active_start_time = 00000, --作业执行的开始时间,格式为HHMMSS
- @active_end_time = 235959 --作业执行的停止时间,格式为HHMMSS
- --周调度
- EXEC msdb.dbo.sp_add_jobschedule
- @job_id = @jobid,
- @name = N'调度名称',
- @freq_type = 8, --每周
- @freq_recurrence_factor = 1, --每多少周执行一次,这里是每周
- @freq_interval = 62, --在星期几执行,由POWER(2,N)表示,N的值为0~6,代表星期日~星期六,如果指定两个,则将值相加,例如,值为65表示在星期天和星期日执行(POWER(2,0)+POWER(2,6))
- @freq_subday_type = 0x8, --重复方式,0x1=在指定的时间,0x4=多少分钟,0x8=多少小时执行一次
- @freq_subday_interval = 1, --重复周期数,这里每小时执行一次
- @active_start_date = NULL, --作业执行的开始日期,为NULL时表示当前日期,格式为YYYYMMDD
- @active_end_date = 99991231, --作业执行的停止日期,默认为99991231,格式为YYYYMMDD
- @active_start_time = 00000, --作业执行的开始时间,格式为HHMMSS
- @active_end_time = 235959 --作业执行的停止时间,格式为HHMMSS
- --月调度(每X个月的每月几号)
- EXEC msdb.dbo.sp_add_jobschedule
- @job_id = @jobid,
- @name = N'调度名称',
- @freq_type = 16, --每月
- @freq_recurrence_factor = 2, --每多少月执行一次,这里是每2个月
- @freq_interval = 2, --在执行月的第几天执行,这里是第2天
- @freq_subday_type = 0x8, --重复方式,0x1=在指定的时间,0x4=多少分钟,0x8=多少小时执行一次
- @freq_subday_interval = 1, --重复周期数,这里每小时执行一次
- @active_start_date = NULL, --作业执行的开始日期,为NULL时表示当前日期,格式为YYYYMMDD
- @active_end_date = 99991231, --作业执行的停止日期,默认为99991231,格式为YYYYMMDD
- @active_start_time = 00000, --作业执行的开始时间,格式为HHMMSS
- @active_end_time = 235959 --作业执行的停止时间,格式为HHMMSS
- --月调度(每X个月的相对时间)
- EXEC msdb.dbo.sp_add_jobschedule
- @job_id = @jobid,
- @name = N'调度名称',
- @freq_type = 32, --每月
- @freq_recurrence_factor = 2, --每多少月执行一次,这里是每2个月
- @freq_interval = 9, --在当月的那个时间执行,1~7=星期日至星期六,8=日 ,9=工作日,10=周末
- @freq_relative_interval = 1, --在第几个相对时间执行,允许的值为1,2,4,8代表第1~4个相对时间,16表示最后一个相对时间
- @freq_subday_type = 0x8, --重复方式,0x1=在指定的时间,0x4=多少分钟,0x8=多少小时执行一次
- @freq_subday_interval = 1, --重复周期数,这里每小时执行一次
- @active_start_date = NULL, --作业执行的开始日期,为NULL时表示当前日期,格式为YYYYMMDD
- @active_end_date = 99991231, --作业执行的停止日期,默认为99991231,格式为YYYYMMDD
- @active_start_time = 00000, --作业执行的开始时间,格式为HHMMSS
- @active_end_time = 235959 --作业执行的停止时间,格式为HHMMSS
- --在特定时候执行的作业调度
- EXEC msdb.dbo.sp_add_jobschedule
- @job_id = @jobid,
- @name = N'调度名称',
- @freq_type = 64 --64=在SQLServerAgent 服务启动时运行,128=计算机空闲时运行
- -----------------------------------------------------------------------------------------------
- IF EXISTS (SELECT * FROM DBO.SYSOBJECTS WHERE ID = OBJECT_ID(N'[DBO].SP_AUTO_CREATEJOB') AND OBJECTPROPERTY(ID, N'ISPROCEDURE') = 1)
- DROP PROCEDURE [DBO].SP_AUTO_CREATEJOB
- GO
- CREATE PROCEDURE DBO.SP_AUTO_CREATEJOB
- @DBNAME VARCHAR(100), --执行数据库
- @JOBNAME VARCHAR(100),
- @EXECSQL NVARCHAR(4000) --执行语句
- AS
- PRINT '----作业 :'+@JOBNAME
- PRINT '----开始执行:' +@EXECSQL
- BEGIN TRANSACTION
- DECLARE
- @JOBID UNIQUEIDENTIFIER,
- @RETURNCODE INT
- SELECT @RETURNCODE = 0
- BEGIN
- IF EXISTS (SELECT JOB_ID FROM MSDB.DBO.SYSJOBS_VIEW WHERE NAME =@JOBNAME)
- EXECUTE MSDB.DBO.SP_DELETE_JOB @JOB_NAME=@JOBNAME
- EXECUTE @RETURNCODE = MSDB.DBO.SP_ADD_JOB --返回值:0成功,1失败
- @JOB_NAME = @JOBNAME,
- @ENABLED = 1, --状态。默认值为 1（启用）,为 0 不启用
- @OWNER_LOGIN_NAME = 'SA', --拥有作业的登录名。默认值为 NULL,可解释为当前登录名
- @JOB_ID = @JOBID OUTPUT
- IF (@@ERROR <> 0 OR @RETURNCODE <> 0) GOTO QUITWITHROLLBACK
- EXECUTE @RETURNCODE = MSDB.DBO.SP_ADD_JOBSTEP
- @JOB_ID = @JOBID,
- @STEP_NAME = N'STEP1', --步骤名称
- @SUBSYSTEM = 'TSQL', --步骤的类型,一般为TSQL
- @DATABASE_NAME = @DBNAME, --执行数据库
- @COMMAND = @EXECSQL --执行语句
- IF (@@ERROR <> 0 OR @RETURNCODE <> 0) GOTO QUITWITHROLLBACK
- EXECUTE @RETURNCODE = MSDB.DBO.SP_UPDATE_JOB
- @JOB_ID = @JOBID,
- @START_STEP_ID = 1 --作业中要执行的第一个步骤的标识号
- IF (@@ERROR <> 0 OR @RETURNCODE <> 0) GOTO QUITWITHROLLBACK
- EXECUTE @RETURNCODE = MSDB.DBO.SP_ADD_JOBSERVER
- @JOB_ID = @JOBID,
- @SERVER_NAME = N'(LOCAL)'
- IF (@@ERROR <> 0 OR @RETURNCODE <> 0) GOTO QUITWITHROLLBACK
- END
- COMMIT TRANSACTION
- GOTO ENDSAVE
- QUITWITHROLLBACK:
- IF (@@TRANCOUNT > 0)
- BEGIN
- ROLLBACK TRANSACTION
- RETURN 1
- END
- ENDSAVE:
- EXEC @RETURNCODE = MSDB.DBO.SP_START_JOB @JOB_ID = @JOBID --启动作业
- RETURN @RETURNCODE
sqlserver 使用脚本创建作业的更多相关文章
- SqlServer 使用脚本创建分发服务及事务复制的可更新订阅
原文:SqlServer 使用脚本创建分发服务及事务复制的可更新订阅 [创建使用本地分发服务器] /************************[使用本地分发服务器配置发布]*********** ...
- sqlserver 使用脚本创建Sql Server代理作业
use master GO /* --开启sql server代理 sp_configure 'show advanced options', 1; GO RECONFIGURE; GO sp_con ...
- SQL2000中创建作业（定时查询，更新）(转)
出处:http://blog.csdn.net/xys_777/article/details/5683413 SQL2000中创建作业(定时查询,更新)企业管理器 --管理 --SQL Server ...
- SQL SERVER 中如何用脚本管理作业
在SQL SERVER中用脚本管理作业,在绝大部分场景下,脚本都比UI界面管理作业要高效.简洁.打个简单的比方,如果你要查看作业的运行时长,如果用UI界面查看,100个作业,你就得在历史记录里面至少查 ...
- 使用SQL Server Management Studio 创建作业备份数据库
在项目中,经常需要备份数据库,如果能做到只需点个按钮(“开始备份数据库”按钮),然后什么都不管,数据库就自动备份好了,或者服务器上的数据库隔一段时间自动备份一次,那该多好啊. Sql server 的 ...
- 创建作业(JOB)
在SQL Server日常需求处理中,会遇到定时执行或统计数据的需求,这时我们可以通过作业(JOB)来处理,从而通过代理的方式来实现数据的自动处理.一下为SQL Server中创建作业的脚本,供大家参 ...
- sql server 用脚本管理作业
转自:https://blog.csdn.net/yunye114105/article/details/6594826 摘要: 在SQL SERVER中用脚本管理作业,在绝大部分场景下,脚本都比UI ...
- SQL Server 批量创建作业（备份主分区）
一. 需求背景 在我的数据库实例中,有很多类似下图所示的数据库,这些数据库的名称是有规律的,每个数据库包含的表都是相同的,其中2个表是类似流水记录的表,表的数据量会比较大,占用的空间有几十G到上百G不 ...
- SqlServer游标的创建与使用
前言 大家都对SqlServer视图.存储过程.触发器的创建与使用有一定的了解了,我们来看下什么是游标,怎么使用,什么时候用. SqlServer视图的创建与使用 SqlServer存储过程的创建与使 ...
随机推荐
- 使用min-device-pixel-ratio媒体功能实现真正的1像素border
关于设备像素比的知识,想必做过移动端开发的都有接触,这里就不介绍啦,万一有不懂的可以看张鑫旭大神的设备像素比devicePixelRatio简单介绍 由于设备像素比存在的原因,我们在处理设计图的一些边 ...
- Apache HTTP 服务器 2.4（又名httpd）安装\配置 \启动
Apache HTTP 服务器 2.4 源文档
- .Net中World转PDF
using System;using System.Collections.Generic;using System.Linq;using System.Web;using Aspose.Words; ...
- 微信小程序之跳转、请求、带参数请求小例子
wx.request(OBJECT) wx.request发起的是 HTTPS 请求.一个微信小程序,同时只能有5个网络请求连接. 具体参数说明参看微信小程序官方文档-发起请求. 例: //当页面加载 ...
- 在Unity 3D中加入Image图片
在Unity 3D中加入Image图片,我在刚开始是加不进去的,为什么呢?因为没有图片,图如下: 原因就是我们没有把图片设置为Script,图片的格式还是默认的那个,这只能作为贴图使用.我们将图片进行 ...
- 在Ubuntu15.10中，使用wxPython的webview和JS进行交互
在Ubuntu下进行wxPython开发,因为需求,所以使用了wxPython的webview和JS的交互. 在Windows下,下图显示的代码可以正常的运行,但是在Ubuntu下进行开发,以下的代码 ...
- hsdf -- 6.21 -- day6
差点忘写总结…… 这么快就到day6了啊 感觉前面写的总结都是苟屁,跟没有有什么区别…… 今天认真总结一下 最大的失误就是全程肝a题,最后还挂了…… 感觉今天方向偏了,由进行一次测试到仅仅是想要尽可能 ...
- 在<canvas>上绘制img（drawImage()）时需要注意的事
<canvas>标签相当于是一个画布,css决定画布的样式(这块画布的背景颜色.大小等),脚本(一般使用JavaScript)就是画笔,我们可以在这个画布上绘制线条.形状.文字.图片等. ...
- proxmox网络
root@t1:~# cat /etc/network/interfaces# network interface settings; autogenerated# Please do NOT mod ...
- cmake add_custom_command 使用
cmake add_custom_command 使用 今天整理编译工程,想在编译工程前面用tolua生成c文件, 使用命令add_custom_command后,附加的命令并不执行,如下: add_ ...