Motion Blur

【Motion Blur】

　　此篇介绍最简单的全局Motion Blur。算法是将当前帧与前一帧按某一比例混合。这是一个过程，例如有10帧，在第1帧中，只有第1帧原图，第2帧中有1、2帧原图，第3帧中会有1、2、3帧原图，依次类推。

　　

　　假设混合比较为a，即原图为1-a，累积图为a，那么1帧新进入的图，在下一帧中，所占的比例就只有a，再下一帧就只有a^2，再下一帧就只有a^3，依次类推，第N帧后，比例会接近于0。a越小，消失的会越快，也就意味着MotionBlur效果越弱。相反，a越大，MotionBlur效果越强。通过将此混合参数叫做BlurAmount。为了防止完全抛弃新进帧的情况，通常会限制BlurAmount不大于0.92。

　　

　　最后，MotionBlur的Shader需要特殊处理一下。首先需要将原始帧与累积帧混合在一起。但普通的混合会连带alpha一起混合，而我们想做做的只是混合RGB，希望alpha保留。所以需要2个Pass，第一个Pass根据BlurAmount混合RGB，第二个Pass直接写入新的alpha。完整Shader如下：

 Shader "Hidden/MotionBlur" {
 Properties {
     _MainTex ("Base (RGB)", 2D) = "white" {}
     _AccumOrig("AccumOrig", Float) = 0.65
 }

     SubShader {
         ZTest Always Cull Off ZWrite Off
         Fog { Mode off }
         Pass {
             Blend SrcAlpha OneMinusSrcAlpha
             ColorMask RGB
             BindChannels {
                 Bind "vertex", vertex
                 Bind "texcoord", texcoord
             } 

             CGPROGRAM
             #pragma vertex vert
             #pragma fragment frag
             #pragma fragmentoption ARB_precision_hint_fastest

             #include "UnityCG.cginc"

             struct appdata_t {
                 float4 vertex : POSITION;
                 float2 texcoord : TEXCOORD;
             };

             struct v2f {
                 float4 vertex : POSITION;
                 float2 texcoord : TEXCOORD;
             };

             float4 _MainTex_ST;
             float _AccumOrig;

             v2f vert (appdata_t v)
             {
                 v2f o;
                 o.vertex = mul(UNITY_MATRIX_MVP, v.vertex);
                 o.texcoord = TRANSFORM_TEX(v.texcoord, _MainTex);
                 return o;
             }

             sampler2D _MainTex;

             half4 frag (v2f i) : COLOR
             {
                 return half4(tex2D(_MainTex, i.texcoord).rgb, _AccumOrig );
             }
             ENDCG
         } 

         Pass {
             Blend One Zero
             ColorMask A

             BindChannels {
                 Bind "vertex", vertex
                 Bind "texcoord", texcoord
             } 

             CGPROGRAM
             #pragma vertex vert
             #pragma fragment frag
             #pragma fragmentoption ARB_precision_hint_fastest

             #include "UnityCG.cginc"

             struct appdata_t {
                 float4 vertex : POSITION;
                 float2 texcoord : TEXCOORD;
             };

             struct v2f {
                 float4 vertex : POSITION;
                 float2 texcoord : TEXCOORD;
             };

             float4 _MainTex_ST;

             v2f vert (appdata_t v)
             {
                 v2f o;
                 o.vertex = mul(UNITY_MATRIX_MVP, v.vertex);
                 o.texcoord = TRANSFORM_TEX(v.texcoord, _MainTex);
                 return o;
             }

             sampler2D _MainTex;

             half4 frag (v2f i) : COLOR
             {
                 return tex2D(_MainTex, i.texcoord);
             }
             ENDCG
         }

     }

 SubShader {
     ZTest Always Cull Off ZWrite Off
     Fog { Mode off }
     Pass {
         Blend SrcAlpha OneMinusSrcAlpha
         ColorMask RGB
         SetTexture [_MainTex] {
             ConstantColor (,,,[_AccumOrig])
             Combine texture, constant
         }
     }
     Pass {
         Blend One Zero
         ColorMask A
         SetTexture [_MainTex] {
             Combine texture
         }
     }
 }

 Fallback off

 }