12、SQL Server 行列转换
SQL Server 行转列
在SQL Server 2005中PIVOT 用于将列值转换为列名(行转列),在SQL Server 2000中是没有这个关键字的 只能用case语句实现。
--创建测试数据库
use master
go
if ( exists (select * from sys.databases where name = 'webDB') )
drop database webDB
go
create database webDB on primary
(
name = 'webDB',
filename = 'f:\database\webDB.mdf',
size = 5mb,
maxsize = unlimited,
filegrowth = 10%
)
log on
(
name = 'webDB_log',
filename = 'f:\database\webDB_log.ldf',
size = 3mb,
maxsize = 50mb,
filegrowth = 2mb
) use webDB
go --创建测试表
if( exists ( select * from sys.objects where name = 'student'))
drop table student
go
create table student
(
id int identity(1,1) primary key,
name varchar(20) not null,
subject varchar(20) not null,
score int not null
) --插入测试数据
insert into student values ('张三','语文',90),
('张三','数学',100),
('张三','英语',80),
('李四','英语',90),
('王五','语文',90),
('李四','语文',90),
('李四','数学',70),
('王五','数学',62),
('王五','英语',82) select * from student
SQL Server 2000 行转列
select name as 姓名,
SUM(case [subject] when '语文' then score else 0 end) as '语文',
SUM(case [subject] when '数学' then score else 0 end ) as '数学',
SUM(case [subject] when '英语' then score else 0 end ) as '英语'
from student group by name
如图所示,已经按照脚本中指定的列名进行转换,但这样做需要知道表中都有哪些数据可以作为列。通常将这种方法称为静态方法。
declare @sql varchar(1000)
set @sql = 'select name as 姓名 , '
select @sql = @sql + 'sum(case [subject] when ''' + [subject] + ''' then score else 0 end ) as '''
+ QUOTENAME([subject]) + ''',' from (select distinct [subject] from student ) as s --后加逗号,然后截取最后一个逗号
select @sql = LEFT(@sql,len(@sql)-1) + ' from student group by name ' print(@sql)
exec(@sql) select QUOTENAME('aa[]bb') --其中quotename 用于将字符串为有效的标识符
这种方法不需要知道到底需要将哪些数据作为列转换,它会自动去数据中查找不重复的数据,都会作为列来显示。通常将这种方法称为动态方法,拼接sql方法。
SQL Server 2005 行转列
select * from (
select name,[subject],score from student
) s pivot (sum(score) for [subject] in (语文,数学,英语)) as pvt
order by pvt.name
PIVOT语法是:PIVOT(聚合函数(列) for 列 in (值,值,值)) as p
这个是静态方法行转列,怎么样代码简洁吧。
declare @sql_str varchar(1000)
declare @sql_col varchar(1000)
select @sql_col = ISNULL(@sql_col + ',','') + QUOTENAME([subject]) from student group by [subject] --先确定要转换的列名
set @sql_str = '
select * from (
select name,[subject],score from student
) s pivot (sum(score) for [subject] in (' + @sql_col + ')) as pvt
order by pvt.name'
print(@sql_str)
exec(@sql_str)
以上2005中动态创建方法。
SQL Server 列转行
在SQL Server 2005中UNPIVOT用于将列名转换为值(列转行),在SQL Server 2000中只能用UNION语句实现。
use webDB
go
--创建测试表
if( exists ( select * from sys.objects where name = 'student'))
drop table student
go
create table student
(
id int identity(1,1) primary key,
name varchar(20) not null,
语文 int not null,
英语 int not null,
数学 int not null
) --插入测试数据
insert into student values ('张三',87,90,62),
('李四',87,90,65),
('王五',23,90,34) select * from student
SQL Server 2000中列转行
SQL Server 2000 静态方法
select * from (
select name,课程='语文',分数=语文 from student
union all
select name,课程='数学',分数=数学 from student
union all
select name,课程='英语',分数=英语 from student
) t order by name, case 课程 when '语文' then 1 when '数学' then 2 when '英语' then 3 end
SQL Server 2000 动态SQL
declare @sql varchar(1000)
select @sql = ISNULL(@sql + ' union all ','') + ' select name,课程='
+ QUOTENAME(name,'''')+' , 分数 = ' + QUOTENAME(name) + ' from student' from syscolumns
where id=object_id('student') and name not in ('id','name')
print(@sql)
exec(@sql)
SQL Server 2005 静态SQL 使用UNPIVOT关键字
select name,课程,分数 from student unpivot (分数 for 课程 in (语文,英语,数学)) s
SQL Server 2005 动态SQL
declare @sql varchar(1000)
select @sql = isnull(@sql + ',','') + quotename(name) from syscolumns
where id = object_id('student') and name not in ('id','name')
order by colid
set @sql = 'select name,课程,分数 from student unpivot (分数 for 课程 in ('+@sql+')) s'
print(@sql)
exec(@sql)
12、SQL Server 行列转换的更多相关文章
- SQL Server 行列转换
/* 标题:普通行列转换(version 2.0) 作者:范中磊 说明:普通行列转换(version 1.0)仅针对sql server 2000提供静态和动态写法,version 2.0增加sql ...
- [转载]SQL Server行列转换实现
可以用聚合函数配合CASE语句实现 PIVOT的一般语法是:PIVOT(聚合函数(列) FOR 列 in (…) )AS P 完整语法: table_source PIVOT( 聚合函数(value_ ...
- SQL SERVER 行列转换(动态)
行转列测试数据: --测试数据 if not object_id(N'Tempdb..#T') is null drop table #T Go Create table #T([Name] nvar ...
- SQL点滴12—SQL Server备份还原数据库中的小把戏
原文:SQL点滴12-SQL Server备份还原数据库中的小把戏 备份数据库时出现一个不太了解的错误 ,错误信息“is formatted to support 1 media families, ...
- SQL Server数据库转换成oracle
来源:http://blog.csdn.net/hzfu007/article/details/6182151 经常碰到需要把sql server的数据迁移到Oracle的情况. 在网上查找一下,有很 ...
- SQL SERVER 日期转换大全
博客转自:http://blog.csdn.net/baiduandxunlei/article/details/9180075 CONVERT(data_type,expression[,style ...
- sql server 日期转换
一.时间函数 在使用存储过程,sql函数的时候,会遇到一些对时间的处理.比如时间的获取与加减.这里就用到了sql自带的时间函数.下面我列出这些函数,方便日后记忆,使用. --getdate 获取当前时 ...
- Sql的行列转换
创建表scores 一.传统的行列转换 纵表转横表 我们要转成的横表是这样子的: pivot是sql server 2005 提供的运算符,所以只要数据库在05版本以上的都可以使用.主要用于行和列的转 ...
- Sql实现行列转换
从MS Sql Server 2005微软就推出了pivot和unpivot实现行列转换,这极大的方便了我们存储数据和呈现数据.今天就对这两个关键字进行分析,结合实例讲解如何存储数据,如何呈现数据. ...
随机推荐
- Vim的学习心得
现在的工作是在unix平台,平时是用UE的ftp功能来写代码的,有时候文件大了,传输就很慢,而且经常不是很稳定.下定决心要学学Vim(现在应该没有人用原始的vi了吧),在经过二周的使用后,发现Vim实 ...
- 【RabbitMQ】 Routing
Routing 之前的章节里我们构建了一个简单的日志系统.我们可以广播所有的日志消息给所有的接收端. 本节我们将给它添加一个新特性 - 我们将允许只订阅一个消息的子集.例如,我们只将关键的错误消息定位 ...
- 20141127 测试使用Word2013书写博客(代码高亮+公式支持)。
PS :又经过几次测试,发现用于Word2010的高亮插件在Word2013上排版效果不是很好,慎用.不过公式编辑倒是挺方便的 测试使用Word2013书写博客. 大概一个月前,使用WindowL ...
- Unity图片处理类,包括压缩、截屏和滤镜
先上代码: 1 using System.Threading; using UnityEngine; using System.IO; using System.Collections; public ...
- GNU DAEMON THREAD <1>
尝试写一个简单的守护进程 /** @File daemon.c * * Build a daemon process for game * */ #include <unistd.h> # ...
- 符合搜索引擎SEO规则的HTML代码
实话说,部落在有时候,也经常会修改一下自己的主题,当然,很多时候,对自己修改过后的主题,会通过查看源代码的方式,来查看自己HTML代码,很多时候,也没有去刻意对代码进行符合搜索引擎SEO规则的优化,而 ...
- DELL 720XD和R820玩赏
- Mysql中类似于nvl()函数的ifnull()函数
IFNULL(expr1,expr2) 如果expr1不是NULL,IFNULL()返回expr1,否则它返回expr2.IFNULL()返回一个数字或字符串值,取决于它被使用的上下文环境. mysq ...
- Delphi编程中资源文件的应用
Delphi编程中资源文件的应用/转自 http://chamlly.spaces.live.com/blog/cns!548f73d8734d3acb!236.entry一.引子: 现在的Windo ...
- Oracle 11g ORA-12514:TNS:监听程序当前无法识别连接描述符中请求的服务
1. 找到listener.ora监听文件,具体位置:D:\app\Administrator\product\11.2.0\dbhome_1\NETWORK\ADMIN\listener.ora 2 ...