剖析Defi之Uinswap_1
学习UniswapERC20,它是交易对的父合约。UniswapV2ERC20 是流动性代币合约,也称为 LP Token。功能主要实习ERC20代币功能以及对线下签名授权。
1 pragma solidity =0.5.16;
2
3 import './interfaces/IUniswapV2ERC20.sol';
4 import './libraries/SafeMath.sol';
5
6 contract UniswapV2ERC20 is IUniswapV2ERC20 {
7 using SafeMath for uint;
8
9 string public constant name = 'Uniswap V2';
10 string public constant symbol = 'UNI-V2';
11 uint8 public constant decimals = 18;
12 uint public totalSupply;
13 mapping(address => uint) public balanceOf;
14 mapping(address => mapping(address => uint)) public allowance;
15
16 bytes32 public DOMAIN_SEPARATOR;
17 // keccak256("Permit(address owner,address spender,uint256 value,uint256 nonce,uint256 deadline)");
18 bytes32 public constant PERMIT_TYPEHASH = 0x6e71edae12b1b97f4d1f60370fef10105fa2faae0126114a169c64845d6126c9;
19 mapping(address => uint) public nonces;
20
21 event Approval(address indexed owner, address indexed spender, uint value);
22 event Transfer(address indexed from, address indexed to, uint value);
23
24 constructor() public {
25 uint chainId;
26 assembly {
27 chainId := chainid
28 }
29 DOMAIN_SEPARATOR = keccak256(
30 abi.encode(
31 keccak256('EIP712Domain(string name,string version,uint256 chainId,address verifyingContract)'),
32 keccak256(bytes(name)),
33 keccak256(bytes('1')),
34 chainId,
35 address(this)
36 )
37 );
38 }
39
40 function _mint(address to, uint value) internal {
41 totalSupply = totalSupply.add(value);
42 balanceOf[to] = balanceOf[to].add(value);
43 emit Transfer(address(0), to, value);
44 }
45
46 function _burn(address from, uint value) internal {
47 balanceOf[from] = balanceOf[from].sub(value);
48 totalSupply = totalSupply.sub(value);
49 emit Transfer(from, address(0), value);
50 }
51
52 function _approve(address owner, address spender, uint value) private {
53 allowance[owner][spender] = value;
54 emit Approval(owner, spender, value);
55 }
56
57 function _transfer(address from, address to, uint value) private {
58 balanceOf[from] = balanceOf[from].sub(value);
59 balanceOf[to] = balanceOf[to].add(value);
60 emit Transfer(from, to, value);
61 }
62
63 function approve(address spender, uint value) external returns (bool) {
64 _approve(msg.sender, spender, value);
65 return true;
66 }
67
68 function transfer(address to, uint value) external returns (bool) {
69 _transfer(msg.sender, to, value);
70 return true;
71 }
72
73 function transferFrom(address from, address to, uint value) external returns (bool) {
74 if (allowance[from][msg.sender] != uint(-1)) {
75 allowance[from][msg.sender] = allowance[from][msg.sender].sub(value);
76 }
77 _transfer(from, to, value);
78 return true;
79 }
80
81 function permit(address owner, address spender, uint value, uint deadline, uint8 v, bytes32 r, bytes32 s) external {
82 require(deadline >= block.timestamp, 'UniswapV2: EXPIRED');
83 bytes32 digest = keccak256(
84 abi.encodePacked(
85 '\x19\x01',
86 DOMAIN_SEPARATOR,
87 keccak256(abi.encode(PERMIT_TYPEHASH, owner, spender, value, nonces[owner]++, deadline))
88 )
89 );
90 address recoveredAddress = ecrecover(digest, v, r, s);
91 require(recoveredAddress != address(0) && recoveredAddress == owner, 'UniswapV2: INVALID_SIGNATURE');
92 _approve(owner, spender, value);
93 }
94 }
1 第一行指明Solidity版本。
2 第三、四行, 导入需要实现的接口IUniswapV2ERC20合约,SafeMath 。SafeMath 是用来更安全的处理数据。防止数据溢出 。
3 第六行:创建合约UniswapV2ERC20 实现IUniswapV2ERC20接口
4 第七行:uint类型实现SafeMath库。使用方法 using xx for xxx
5 第9-11:定义代币的名字 符号 精度。
6 第十二行:定义代币发现总量。
7 第十三行:用mapping 记录地址的代币余额
8 第十四行:mapping 记录地址的授权。
9 第十六行: 区分在不同Dapp之间相同结构和内容签名消息。使用户分辨。
10 第十七行: 根据事先使用permit函数 定义计算哈希值,重建消息签名
11 第十九行:记录地址使用链下签名消息交易的数量,防止重放攻击
12 第二十一二十二行:定义两个事件便于检索 approve事件(发起者,消费者,交易额).transfer转账事件(发送者,接收者,金额)
13 二十四行开始为构造器 计算 DOMAIN_SEPARATOR 的值。
1) 定义变量 chainid
2)内联汇编赋值
3)keccak256 哈希运算,abi.encode 计算参数的ABI编码,EIP712Domain 有四个参数,name:可读签名域名称(代币名称),version 可读签名域版本。chainId 当前链ID,verifyingContract 验证合约的地址。.
14 _mint函数,代币增发。
1 function _mint(address to, uint value) internal {
2 totalSupply = totalSupply.add(value);
3 balanceOf[to] = balanceOf[to].add(value);
4 emit Transfer(address(0), to, value);
5 }
6
函数参数to(接受地址) value(增加数量)修饰符 internal 外部无法调用。
1)totalSupply 代币总量增加,接受账户代币增加。触发转移事件。
15 _burn 燃烧函数,和上面_mint函数类似,totalSupply 总量减少,指定用户代币减少,触发转移事件。
16 _approve 授权函数 函数修饰符private, allowance[owner][spender] = value;触发授权事件
17 _transfer 转移函数 ,修饰符private ,发起者代币减少,接受者地址代币增加。触发转移事件。
18 approve 授权函数,修饰符 external,外部可调用,返回值布尔,调用_approve函数。
19 transfer 转移函数,修饰符 external,外部可调用,返回值布尔类型,调用_transfer函数
20 代表授权转移函数,修饰符external,返回值布尔类型。
1 function transferFrom(address from, address to, uint value) external returns (bool) {
2 if (allowance[from][msg.sender] != uint(-1)) {
3 allowance[from][msg.sender] = allowance[from][msg.sender].sub(value);
4 }
5 _transfer(from, to, value);
6 return true;
7 }
如果授权额度是最大值,uniswapV2中 为减少gas,不会在授权中减少代币数量,如果不是则会减少授权的代币数量,然后调用_transfer 转移函数.
21 permit 使用线下签名消息进行授权操作.UniswapV2 使用线下签名消息主要消除代币授权转移时对授权交易的需求。
1 function permit(address owner, address spender, uint value, uint deadline, uint8 v, bytes32 r, bytes32 s) external {
2 require(deadline >= block.timestamp, 'UniswapV2: EXPIRED');
3 bytes32 digest = keccak256(
4 abi.encodePacked(
5 '\x19\x01',
6 DOMAIN_SEPARATOR,
7 keccak256(abi.encode(PERMIT_TYPEHASH, owner, spender, value, nonces[owner]++, deadline))
8 )
9 );
10 address recoveredAddress = ecrecover(digest, v, r, s);
11 require(recoveredAddress != address(0) && recoveredAddress == owner, 'UniswapV2: INVALID_SIGNATURE');
12 _approve(owner, spender, value);
13 }
14 }
require验证截止时间与当前区块时间
digest 是使用keccak256 得到的哈希值。ecrecover 是solidity内置函数可以获取消息的签名地址。这与就可以与Owner地址对比,就可以验证是否是owner签名的。它允许用户在链下签署授权(approve)的交易,生成任何人都可以使用并提交给区块链的签名。
剖析Defi之Uinswap_1的更多相关文章
- 剖析Defi之Uinswap_2
学习核心合约UniswapV2Pair,在父合约UniswapV2ERC20的基础上增加资产交易及流动性提供等功能. 交易对合约本身是erc20合约,代币表示流动性,代币在提供流动性的地址里,当提供流 ...
- 剖析Defi之Uinswap_0
Uniswap是什么,不需要讲了吧.YYDS(永远嘀神) 介绍几个概念: 恒定乘积算法:可以简单看作X * Y = K,这里K(乘积)保持不变,所以叫恒定乘积算法,该函数是一个反曲线. 自动流动性协议 ...
- 探索C#之6.0语法糖剖析
阅读目录: 自动属性默认初始化 自动只读属性默认初始化 表达式为主体的函数 表达式为主体的属性(赋值) 静态类导入 Null条件运算符 字符串格式化 索引初始化 异常过滤器when catch和fin ...
- jQuery之Deferred源码剖析
一.前言 大约在夏季,我们谈过ES6的Promise(详见here),其实在ES6前jQuery早就有了Promise,也就是我们所知道的Deferred对象,宗旨当然也和ES6的Promise一样, ...
- [C#] 剖析 AssemblyInfo.cs - 了解常用的特性 Attribute
剖析 AssemblyInfo.cs - 了解常用的特性 Attribute [博主]反骨仔 [原文]http://www.cnblogs.com/liqingwen/p/5944391.html 序 ...
- Membership三步曲之进阶篇 - 深入剖析Provider Model
Membership 三步曲之进阶篇 - 深入剖析Provider Model 本文的目标是让每一个人都知道Provider Model 是什么,并且能灵活的在自己的项目中使用它. Membershi ...
- 《AngularJS深度剖析与最佳实践》简介
由于年末将至,前阵子一直忙于工作的事务,不得已暂停了微信订阅号的更新,我将会在后续的时间里尽快的继续为大家推送更多的博文.毕竟一个人的力量微薄,精力有限,希望大家能理解,仍然能一如既往的关注和支持sh ...
- 探索c#之Async、Await剖析
阅读目录: 基本介绍 基本原理剖析 内部实现剖析 重点注意的地方 总结 基本介绍 Async.Await是net4.x新增的异步编程方式,其目的是为了简化异步程序编写,和之前APM方式简单对比如下. ...
- ASP.NET Core管道深度剖析(2):创建一个“迷你版”的管道来模拟真实管道请求处理流程
从<ASP.NET Core管道深度剖析(1):采用管道处理HTTP请求>我们知道ASP.NET Core请求处理管道由一个服务器和一组有序的中间件组成,所以从总体设计来讲是非常简单的,但 ...
随机推荐
- Linux下强制踢掉登陆用户
1.pkill -kill -t tty 例:pkill -kill -t tty1
- Android: EditText设置属性和设置输入规则
1.EditText输入限制规则 在xml:EditText 设置属性 android:digits="ABCDE123&*" ABCDE123&*是你的限制规则 ...
- LoadRunner中怎么设置密码参数化与用户名关联
对密码参数化时从parameter里的"Select next row"列表中选择Same Line As这一选项,意思就是每一个密码参数化取值与对应行的用户名关联起来了
- MySQL(3):SELECT语法
一,数据库语句 数据库数据是通过DML语句管理数据库数据,包括: INSERT (添加数据语句) UPDATE (更新数据语句) DELETE (删除数据语句) 1:INSERT (添加数据语句) I ...
- 【MySQL】亲测可用的教程筛选:安装与卸载
windows版本的 安装看这篇,非常详细:https://www.cnblogs.com/winton-nfs/p/11524007.html 彻底清除:https://www.pianshen.c ...
- 深入分析 Java ZGC
传统的垃圾回收 CMS 与 G1 停顿时间瓶颈 ZGC 概览 深入 ZGC 原理 标记 Marking 着色指针 Reference Coloring Relocation 重映射和读屏障 Remap ...
- gogs报错解决合集
目录 一.在组织中添加成员,一直显示普通用户 一.在组织中添加成员,一直显示普通用户 组织是公司,团队是公司中的不同队伍.例如A团队设置为加入就有管理员权限,那加入就有管理员. 但在组织成员那一栏中加 ...
- 基于bootstrap的模态框使用
使用步骤两步 1:按顺序引入以下三个文件 <link rel="stylesheet" href="../css/bootstrap.min.css"&g ...
- Mybatis动态SQL语句使用
在实际开发中,有时候查询条件可能是不确定的,查询条件可能有多条也可能没有,这时候就需要用到动态的sql语句拼接功能. 一.if.where.sql标签的使用 需求:在一些高级查询中,查询条件存在的个数 ...
- 在React中使用 react-router-dom 编程式路由导航的正确姿势【含V5.x、V6.x】
## react-router-dom 编程式路由导航 (v5) ###### 1.push跳转+携带params参数 ```jsx props.history.push(`/b/child1/${i ...