sqlserver 中的时间算法

DECLARE @Date  DATETIME

SET @Date=GETDATE()

--前一天，给定日期的前一天

SELECT DATEADD(DAY,-1,@Date) AS '前一天'

--后一天，给定日期的后一天

SELECT DATEADD(DAY,1,@Date) AS '后一天'

GO

--月初，计算给定日期所在月的第一天

--这个计算的技巧是先计算当前日期到“1900-01-01”的时间间隔数，然后把它加到“1900-01-01”上来获得特殊的日期，这个技巧可以用---来计算很多不同的日期。

DECLARE @Date  DATETIME

SET @Date=GETDATE()

SELECT DATEADD(MONTH,DATEDIFF(MONTH,'1900-01-01',@Date),'1900-01-01') AS '所在月的第一天'

--精简算法，根据SQL Server的时间表示方式可知，'1900-01-01' 可以用0代替

SELECT DATEADD(MONTH,DATEDIFF(MONTH,0,@Date),0) AS '所在月的第一天'

--上面两种算法精确到天 时分秒均为00:00:00.000

--下面算法课以保留时分秒

--思路：用给定日期减去月第一天与给定日期差的天数

SELECT DATEADD(DAY,1-DATEPART(DAY,@Date),@Date)

GO

--月末，计算给定日期所在月的最后一天

DECLARE @Date  DATETIME

SET @Date=GETDATE()

--思路：当前月的下一月1号在减1天

SELECT DATEADD(DAY,-1,DATEADD(MONTH,1+DATEDIFF(MONTH,'1900-01-01',@Date),'1900-01-01')) AS '所在月的最一天'

SELECT DATEADD(MONTH,1+DATEDIFF(MONTH,'1900-01-01',@Date),'1900-01-01')-1 AS '所在月的最一天'

--1900-01-01 用0代替

SELECT DATEADD(DAY,-1,DATEADD(MONTH,1+DATEDIFF(MONTH,0,@Date),0)) AS '所在月的最一天'

SELECT DATEADD(MONTH,1+DATEDIFF(MONTH,0,@Date),0)-1 AS '所在月的最一天'

--思路：与月初计算思路相同

SELECT DATEADD(MONTH,DATEDIFF(MONTH,'1989-12-31',@Date),'1989-12-31') AS '所在月的最一天'

--精简算法，'1989-12-31' 用-1代替

SELECT DATEADD(MONTH,DATEDIFF(MONTH,-1,@Date),-1) AS '所在月的最一天'

--保留时分秒的算法

SELECT DATEADD(DAY,-1,DATEADD(MONTH,1,DATEADD(DAY,1-DATEPART(DAY,@Date),@Date)))

GO

--其他月计算

--计算给定日期所在月的上月第一天

DECLARE @Date  DATETIME

SET @Date=GETDATE()

--当前月第一天减去一个月

SELECT DATEADD(MONTH,-1,DATEADD(MONTH,DATEDIFF(MONTH,0,@Date),0)) AS '上月第一天'

--简化

SELECT DATEADD(MONTH,DATEDIFF(MONTH,0,@Date)-1,0) AS '上月第一天'

--另一种当前月第一天算法

SELECT DATEADD(MONTH,-1,DATEADD(DAY,1-DATEPART(DAY,@Date),@Date)) '上月第一天'

GO

--计算给定日期所在月的上月最后一天

DECLARE @Date  DATETIME

SET @Date=GETDATE()

--当前月第一天减去一天

SELECT DATEADD(DAY,-1,DATEADD(MONTH,DATEDIFF(MONTH,0,@Date),0)) AS '上月最后一天'

--另一种当前月第一天算法

SELECT DATEADD(DAY,-1,DATEADD(DAY,1-DATEPART(DAY,@Date),@Date)) '上月最后一天'

SELECT DATEADD(DAY,1-DATEPART(DAY,@Date),@Date)-1 '上月最后一天'

--另一种算法，不能用当前月的最后一天加一个月，因为当前月可能是30天。

--例如 SELECT DATEADD(MONTH,1,'2010-06-30') --结果是2010-07-30而不是2010-07-31，

--这也是月末算法采用下月第一天减1天计算的原因

--但是如果计算月是31天择无此问题

--例如 SELECT DATEADD(MONTH,1,'2010-05-31') --结果是2010-06-30

--因此下面算法是正确的，-1 表示'1899-12-31 00:00:00.000'-- SELECT CONVERT(DATETIME,-1)

SELECT DATEADD(MONTH,DATEDIFF(MONTH,-1,@Date)-1,-1)

--另一种当前月算法

SELECT DATEADD(DAY,-1,DATEADD(DAY,1-DATEPART(DAY,@Date),@Date)) '上月最后一天'

--简化

SELECT DATEADD(DAY,0-DATEPART(DAY,@Date),@Date) '上月最后一天'

GO

--计算给定日期所在月的下月第一天

DECLARE @Date  DATETIME

SET @Date=GETDATE()

--当前月第一天加一个月

SELECT DATEADD(MONTH,1,DATEADD(MONTH,DATEDIFF(MONTH,0,@Date),0)) AS '下月第一天'

--简化

SELECT DATEADD(MONTH,DATEDIFF(MONTH,0,@Date)+1,0) AS '下月第一天'

--另一种当前月第一天算法

SELECT DATEADD(MONTH,1,DATEADD(DAY,1-DATEPART(DAY,@Date),@Date)) '下月第一天'

GO

--计算给定日期所在月的下月最后一天

DECLARE @Date  DATETIME

SET @Date=GETDATE()

--当前月第一天加2个月再减去1天

SELECT DATEADD(DAY,-1,DATEADD(MONTH,2,DATEADD(MONTH,DATEDIFF(MONTH,0,@Date),0))) AS '下月最后一天'

--简化

SELECT DATEADD(DAY,-1,DATEADD(MONTH,DATEDIFF(MONTH,0,@Date)+2,0)) AS '下月最后一天'

SELECT DATEADD(MONTH,DATEDIFF(MONTH,0,@Date)+2,0)-1 AS '下月最后一天'

--另一种算法

SELECT DATEADD(MONTH,DATEDIFF(MONTH,-1,@Date)+1,-1) '下月最后一天'

--另一种当前月第一天算法

SELECT DATEADD(DAY,-1,DATEADD(MONTH,2,DATEADD(DAY,1-DATEPART(DAY,@Date),@Date))) '下月最后一天'

GO

--所在星期的第一天，计算给定日期所在星期的第1天(星期日为第一天)

DECLARE @Date  DATETIME

SET @Date= GETDATE()

--与SQL Server语言版本相关的算法

--思路：当前日期+星期日(每周的第1天)与当前日期的差的天数

--DATEPART(WEEKDAY,DATE)的返回值与@@DATEFIRST相关

SET DATEFIRST 7 -- 或者设置为美国英语SET LANGUAGE us_english; (星期日为第一天)

SELECT DATEADD(WEEKDAY,1-DATEPART(WEEKDAY,@Date),@Date) AS '所在星期的第一天，星期日'

--星期日，与SQL Server语言版本或@@DATEFIRST无关

--'1989-12-31' 是星期日，'1989-12-31' 再加上(当前日期与1989-12-31差的星期数)个星期

SELECT DATEADD(WEEK,DATEDIFF(WEEK,-1,@Date),-1) AS '所在星期的星期日'

--或者

SELECT DATEADD(WEEK,DATEDIFF(WEEK,6,@Date),6) AS '所在星期的星期日'

GO

--所在星期的第二天，计算给定日期所在星期的第2天(星期日为第一天)

DECLARE @Date  DATETIME

SET @Date= GETDATE()

--思路：当前日期+星期一(每周的第2天)与当前日期的差的天数

--DATEPART(WEEKDAY,DATE)的返回值与@@DATEFIRST相关

SET DATEFIRST 7 -- 或者设置为美国英语SET LANGUAGE us_english; (星期日为第一天)

SELECT DATEADD(DAY,2-DATEPART(WEEKDAY,@Date),@Date) AS '所在星期的第二天，星期一'

--星期一，与SQL Server语言版本或@@DATEFIRST无关

--'1900-01-01' 是星期一，'1900-01-01' 再加上(当前日期与1900-01-01差的星期数)个星期

SELECT DATEADD(WEEK,DATEDIFF(WEEK,0,@Date),0) AS '所在星期的星期一'

GO

--上个星期第一天，计算给定日期所在星期的上一个星期日(星期日为第一天)

DECLARE @Date  DATETIME

SET @Date= GETDATE()

--思路：当前日志所在星期的星期日再减1周

--DATEPART(WEEKDAY,DATE)的返回值与@@DATEFIRST相关

SET DATEFIRST 7 -- 或者设置为美国英语SET LANGUAGE us_english; (星期日为第一天)

SELECT DATEADD(WEEK,-1,DATEADD(DAY,1-DATEPART(WEEKDAY,@Date),@Date)) AS '上个星期第一天，星期日'

--一周等于7天

SELECT DATEADD(DAY,-7,DATEADD(DAY,1-DATEPART(WEEKDAY,@Date),@Date)) AS '上个星期第一天，星期日'

--简化

SELECT DATEADD(DAY,-6-DATEPART(WEEKDAY,@Date),@Date) AS '上个星期第一天，星期日'

--上个星期日，与SQL Server语言版本或@@DATEFIRST无关

SELECT DATEADD(WEEK,-1+DATEDIFF(WEEK,-1,@Date),-1) AS '上个星期日'

--或者

SELECT DATEADD(WEEK,DATEDIFF(WEEK,6,@Date),-1) AS '上个星期日'

GO

--下个星期第一天，计算给定日期所在星期的下一个星期日(星期日为第一天)

DECLARE @Date  DATETIME

SET @Date= GETDATE()

--思路：当前日志所在星期的星期日再加1周

--DATEPART(WEEKDAY,DATE)的返回值与@@DATEFIRST相关

SET DATEFIRST 7 -- 或者设置为美国英语SET LANGUAGE us_english; (星期日为第一天)

SELECT DATEADD(WEEK,1,DATEADD(DAY,1-DATEPART(WEEKDAY,@Date),@Date)) AS '下个星期第一天，星期日'

--一周等于7天

SELECT DATEADD(DAY,7,DATEADD(DAY,1-DATEPART(WEEKDAY,@Date),@Date)) AS '下个星期第一天，星期日'

--简化

SELECT DATEADD(DAY,8-DATEPART(WEEKDAY,@Date),@Date) AS '下个星期第一天，星期日'

--下个星期日，与SQL Server语言版本或@@DATEFIRST无关

SELECT DATEADD(WEEK,1+DATEDIFF(WEEK,-1,@Date),-1) AS '下个星期日'

--或者

SELECT DATEADD(WEEK,DATEDIFF(WEEK,-1,@Date),6) AS '下个星期日'

GO

--判断给定日期是星期几

DECLARE @Date  DATETIME

SET @Date= GETDATE()

--DATEPART(WEEKDAY,DATE)的返回值与@@DATEFIRST相关

SET DATEFIRST 7 -- 或者设置为美国英语SET LANGUAGE us_english; (星期日为第一天)

SELECT DATEPART(WEEKDAY,@Date) --返回值 1-星期日，2-星期一，3-星期二......7-星期六

--上面算法与SQL 语言版本或 @@DATEFIRST 相关

--下面算法与SQL Server语言版本或@@DATEFIRST无关

SELECT DATENAME(WEEKDAY,@Date) '星期'

GO

--年度计算

DECLARE @Date  DATETIME

SET @Date=GETDATE()

--年初，计算给定日期所在年的第一天

SELECT DATEADD(YEAR,DATEDIFF(YEAR,0,@Date),0) AS '所在年的第一天'

--年末，计算给定日期所在年的最后一天

SELECT DATEADD(YEAR,DATEDIFF(YEAR,-1,@Date),-1) AS '所在年的最后一天'

--上一年年初，计算给定日期所在年的上一年的第一天

SELECT DATEADD(YEAR,DATEDIFF(YEAR,-0,@Date)-1,0) AS '所在年的上一年的第一天'

--上一年年末，计算给定日期所在年的上一年的最后一天

SELECT DATEADD(YEAR,DATEDIFF(YEAR,0,@Date),-1) AS '所在年的上一年的最后一天'

--下一年年初，计算给定日期所在年的下一年的第一天

SELECT DATEADD(YEAR,1+DATEDIFF(YEAR,0,@Date),0) AS '所在年的下一年的第一天'

--下一年年末，计算给定日期所在年的下一年的最后一天

SELECT DATEADD(YEAR,1+DATEDIFF(YEAR,-1,@Date),-1) AS '所在年的下一年的最后一天'

GO

--季度计算

DECLARE @Date  DATETIME

SET @Date=GETDATE()

--季度初，计算给定日期所在季度的第一天

SELECT DATEADD(QUARTER,DATEDIFF(QUARTER,0,@Date),0) AS '当前季度的第一天'

--季度末，计算给定日期所在季度的最后一天

SELECT DATEADD(QUARTER,1+DATEDIFF(QUARTER,0,@Date),-1) AS '当前季度的最后一天'

--上个季度初

SELECT DATEADD(QUARTER,DATEDIFF(QUARTER,0,@Date)-1,0) AS '当前季度的上个季度初'

--上个季度末

SELECT DATEADD(QUARTER,DATEDIFF(QUARTER,0,@Date),-1) AS '当前季度的上个季度末'

--下个季度初

SELECT DATEADD(QUARTER,1+DATEDIFF(QUARTER,0,@Date),0) AS '当前季度的下个季度初'

--下个季度末

SELECT DATEADD(QUARTER,2+DATEDIFF(QUARTER,0,@Date),-1) AS '当前季度的下个季度末'

--计算给定日期所在月的天数

DECLARE @Date DATETIME;

SET @Date = GETDATE()

--本月度第一天与下月度第一天所差的天数

SELECT DATEDIFF(DAY,DATEADD(MONTH,DATEDIFF(MONTH,0,@Date),0),DATEADD(MONTH,1+DATEDIFF(MONTH,0,@Date),0))

--借助变量简化

SELECT @Date = DATEADD(MONTH,DATEDIFF(MONTH,0,@Date),0) --本月度第一天

SELECT DATEDIFF(DAY,@Date,DATEADD(MONTH,1,@Date))

--另一种思路：给定月最后一天的日期，记为本月天数

SELECT DAY(DATEADD(MONTH,DATEDIFF(MONTH,-1,@Date),-1))

GO

--计算给定日期所在季度的天数

DECLARE @Date DATETIME;

SET @Date = GETDATE()

--本季度第一天与下季度第一天所差的天数

SELECT DATEDIFF(DAY,DATEADD(QUARTER,DATEDIFF(QUARTER,0,@Date),0),DATEADD(QUARTER,1+DATEDIFF(QUARTER,0,@Date),0))

--借助变量简化

SELECT @Date = DATEADD(QUARTER,DATEDIFF(QUARTER,0,@Date),0) --本季度第一天

SELECT DATEDIFF(DAY,@Date,DATEADD(QUARTER,1,@Date))

GO

--计算给定日期所在年度的天数

DECLARE @Date DATETIME;

SET @Date = GETDATE()

--本年度第一天与下年度第一天所差的天数

SELECT DATEDIFF(DAY,DATEADD(YEAR,DATEDIFF(YEAR,0,@Date),0),DATEADD(YEAR,1+DATEDIFF(YEAR,0,@Date),0))

--借助变量简化

SELECT @Date = DATEADD(YEAR,DATEDIFF(YEAR,0,@Date),0) --本年度第一天

SELECT DATEDIFF(DAY,@Date,DATEADD(YEAR,1,@Date))

GO

--判断给定日期所在年是否闰年

--根据全年总天数判断

DECLARE @Date DATETIME;

SET @Date = GETDATE()

SELECT CASE DATEDIFF(DAY,DATEADD(YEAR,DATEDIFF(YEAR,0,@Date),0),DATEADD(YEAR,1+DATEDIFF(YEAR,0,@Date),0))

  WHEN 365 THEN '平年' ELSE '闰年' END

--根据二月天数判断

--给日期的上一年最后一天加2个月，即为当年2月最后一天

SELECT CASE DAY(DATEADD(MONTH,2,DATEADD(YEAR,DATEDIFF(YEAR,0,@Date),-1))) WHEN 28 THEN '平年' ELSE '闰年' END

GO

--计算给定日期是当年的第几天

DECLARE @Date DATETIME;

SET @Date = GETDATE()

SELECT DATEPART(DAYOFYEAR,@Date) [DayOfYear];

SELECT DATENAME(DAYOFYEAR,@Date)  [DayOfYear];

--另一种思路：当前日期与上年最后一天差的天数

SELECT DATEDIFF(DAY,DATEADD(YEAR,DATEDIFF(YEAR,0,@Date),-1),@Date)[DayOfYear]

GO

--计算给定日期是当年的第几周

DECLARE @Date DATETIME;

SET @Date = GETDATE()

SELECT DATEPART(WEEK,@Date) [WeekOfYear]; --返回int型

SELECT DATENAME(WEEK,@Date) [WeekOfYear]; --返回varchar型

GO

--计算给定日期是当年的第几月

DECLARE @Date DATETIME;

SET @Date = GETDATE()

SELECT DATEPART(MONTH,@Date) [MonthOfYear]; --返回int型

SELECT DATENAME(MONTH,@Date) [MonthOfYear]; --返回varchar型

SELECT MONTH(@Date) [MonthOfYear];--返回int型

GO

--计算给定日期是当年的第几季度

DECLARE @Date DATETIME;

SET @Date = GETDATE()

SELECT DATEPART(QUARTER,@Date) [QuarterOfYear]; --返回int型

SELECT DATENAME(QUARTER,@Date) [QuarterOfYear]; --返回varchar型

GO

--计算给定日期是当月的第几周

DECLARE @Date DATETIME;

SET @Date = GETDATE()

--思路，给定日期是当年的第几周-给定日期所在月第一天是当年的第几周

SELECT DATEPART(WEEK,@Date)-DATEPART(WEEK,DATEADD(MONTH,DATEDIFF(MONTH,0,@Date),0))+1 [WeekOfMonth]

SELECT DATEPART(WEEK,@Date)-DATEPART(WEEK,DATEADD(DAY,1-DATEPART(DAY,@Date),@Date))+1 [WeekOfMonth]

GO

--计算给定日期所在月的第一个星期一是哪天

DECLARE @Date DATETIME;

SET @Date = GETDATE()

--思路，1900-01-01(星期一)加上(给定日志所在月的月6号与1900-01-01差的周数)个周

--为什么不选7号？如果是7号，那么7好恰好是星期日的话，第一个周一就会算到8号。

--为什么不选5号？如果5号是星期六，那么周一就跑到上月了。小于5号与这个道理一样。

SELECT DATEADD(WEEK,DATEDIFF(WEEK,0,DATEADD(DAY,6-DATEPART(DAY,@Date),@Date)),0) '所在月的第一个星期一'

SELECT DATEADD(WEEK,DATEDIFF(WEEK,0,DATEADD(DAY,6-DATEPART(DAY,@Date),@Date)),7) '所在月的第二个星期一'

SELECT DATEADD(WEEK,DATEDIFF(WEEK,0,DATEADD(DAY,6-DATEPART(DAY,@Date),@Date)),1) '所在月的第一个星期二'

SELECT DATEADD(WEEK,DATEDIFF(WEEK,0,DATEADD(DAY,6-DATEPART(DAY,@Date),@Date)),8) '所在月的第二个星期二'

GO

sqlserver 中的时间算法的更多相关文章

SQLServer中对时间和长度的处理
---关于时间处理的函数 GETDATE() DATEADD(DAY,-20,GETDATE()) CONVERT(VARCHAR(100), GETDATE(), 112) DATENAME(PAR ...
sqlserver中对时间类型的字段转换
获取当前日期利用 convert 来转换成我们需要的datetime格式． select CONVERT(varchar(12) , getdate(), 112 ) 20040912-------- ...
sqlserver中的时间比较
例子: select count(*) from table where DATEDIFF ([second], '2004-09-18 00:00:18', '2004-09-18 00:00:19 ...
日期时间函数 mysql 和sqlserver 中对于常用函数的日期和时间函数的区别
1. sqlserver中获取时间用getdate(),默认返回格式是2019-01-21 13:58:33.053,具体的年月日,时分秒毫米,年月日之间用短线连接,时分秒之间用冒号连接,秒和毫米之间 ...
C#批量插入数据到Sqlserver中的四种方式
我的新书ASP.NET MVC企业级实战预计明年2月份出版,感谢大家关注! 本篇,我将来讲解一下在Sqlserver中批量插入数据. 先创建一个用来测试的数据库和表,为了让插入数据更快,表中主键采用的 ...
SQLSERVER中的假脱机spool
SQLSERVER中的假脱机spool 我发现网上对于假脱机的解释都非常零散,究竟假脱机是什么? 这几天在家里研究了一下,收集了很多网上的资料假脱机是中文的翻译,而英文的名字叫做 spool 在徐老 ...
C#批量插入数据到Sqlserver中的三种方式
本篇,我将来讲解一下在Sqlserver中批量插入数据. 先创建一个用来测试的数据库和表,为了让插入数据更快,表中主键采用的是GUID,表中没有创建任何索引.GUID必然是比自增长要快的,因为你生成 ...
SQLSERVER中KeyHashValue的作用（上）
SQLSERVER中KeyHashValue的作用(上) SQLSERVER中KeyHashValue的作用(下) 原文的标题是:SQLSERVER在索引下如何找到哈希值的随想现在知道KeyHash ...
【转载】C#批量插入数据到Sqlserver中的三种方式
引用:https://m.jb51.net/show/99543 这篇文章主要为大家详细介绍了C#批量插入数据到Sqlserver中的三种方式,具有一定的参考价值,感兴趣的小伙伴们可以参考一下本篇, ...

随机推荐

TP5内部异常API数据输出的自定义方法编写
需求:利用postman进行请求api接口过程中关于一些数据输出异常的情况下我们希望通过自己编写一些类和方法实现便于后端人员进行根据提示进行调试处理! 以下测试的时候请设置 app_debug ...
ERROR 1146 (42S02): Table 'mysql.servers' doesn't exist
MySQL版本:mysql5.7.21 修改用户权限,刷新权限表,报1146 mysql> flush privileges; ERROR 1146 (42S02): Table 'mysql. ...
点击" ./start_navicat"安装出现界面便面为乱码
环境:ubuntu16.4 下载Navicat:navicat112_mariadb_cs_x64.tar.gz 点击" ./start_navicat"安装出现界面便面为乱码解 ...
vs2017或vs2019添加引用时报错
我先安装的是vs2019,进入VS命令提示符里后一直说:gacutil 不是有效的命令,一直没能解决,然后直接装了vs2017后,该命令可以使用了, 还是用VS2017吧,2019的版本感觉还有点问题 ...
day37—javascript对表格table的操作应用（二）
转行学开发,代码100天——2018-04-22 昨天学习了JavaScript对table的基本操作,包括表格的创建,表格元素的获取,隔行换色及鼠标动作等.今天主要学习table的搜索查询及排序操作 ...
《图解设计模式》读书笔记2-1 Template Method模式
目录模板方法模式类图思想: 模板方法模式在父类中定义流程,在子类中实现具体的方法. 类图代码 //抽象类 public abstract class AbstractDisplay { pu ...
P4929 【模板】舞蹈链（DLX）
题目背景本题是舞蹈链模板——精确覆盖问题题目描述给定一个N行M列的矩阵,矩阵中每个元素要么是1,要么是0 你需要在矩阵中挑选出若干行,使得对于矩阵的每一列j,在你挑选的这些行中,有且仅有一行的第 ...
python学习第十六天集合的关系测试
在做数据分析的时候,要对一个集合分析,而且分析多个集合的之间的关系分析,那么用传统的循环的比较麻烦,集合提供很多方法,很容易比较多个集合的关系,并集,交集,差集,对称差集等. n1={1,2,4,6} ...
codeforces hack
对某一题,首先你自己要先过TEST. 然后回到比赛的PROBLEM列表,把这题后面的锁锁上(锁上了就不能再提交了,所以没把握就别锁了), 然后到ROOM里面,你就可以看别人代码了,下面有HACK按钮, ...
<一> idea+gradle+springboot创建项目
转载自https://windcoder.com/springbootchutan-chuangjianxiangmu 前言一边学习公司用到的技术,一边重构小程序后端,从而更好的理解公司搭建的框架. ...

sqlserver 中的时间算法

sqlserver 中的时间算法的更多相关文章

随机推荐

热门专题