S3C2440启动代码2440init.s彻底解析

2440可以选择nand启动和nor启动,这两者之间的关系通过一个按键来选择

这个OM0有何玄机,在数据手册中有这么一段

可以看到,只要将OM1接地,那么通过OM0选择1或选择0就可以选择NAND启动或者16位宽RAM启动了(当然,还得设置一些东西,下面就说),

Nanaflash启动经历的过程相当于首先,2440自动从nand里面读取4K的代码,这4K代码将nand里面的数据拷贝到ram中,然后跳转到ram中执行代码,为什么是4K,因为

2440.s的启动代码需要包含几个文件

2440addr.inc

包含2440内部寄存器地址

Memcfg.inc

包含2440各个bank的内存配置数据

Option.inc

包含2440的各种时钟配置代码

Nand.c

包含nanaflash的读写函数

好了,分析开始

;REFRESH寄存器[22]bit : 0- auto refresh; 1 - self refresh

BIT_SELFREFRESH EQU (1<<22) ;用于节电模式中，SDRAM自动刷新

;处理器模式常量: CPSR寄存器的后5位决定目前处理器模式
M[4:0]

USERMODE    EQU 0x10

FIQMODE     EQU 0x11

IRQMODE     EQU 0x12

SVCMODE     EQU 0x13

ABORTMODE   EQU 0x17

UNDEFMODE   EQU 0x1b

MODEMASK    EQU 0x1f  ;M[4:0]//模式计算掩码

NOINT       EQU 0xc0 //除去模式之后的剩余值

CPSR的说明

;定义处理器各模式下堆栈地址常量

UserStack EQU (_STACK_BASEADDRESS-0x3800) ;0x33ff4800 ~   _STACK_BASEADDRESS定义在option.inc中

SVCStack EQU (_STACK_BASEADDRESS-0x2800) ;0x33ff5800 ~

UndefStack EQU (_STACK_BASEADDRESS-0x2400) ;0x33ff5c00 ~

AbortStack EQU (_STACK_BASEADDRESS-0x2000) ;0x33ff6000 ~

IRQStack EQU (_STACK_BASEADDRESS-0x1000) ;0x33ff7000 ~

FIQStack EQU (_STACK_BASEADDRESS-0x0) ;0x33ff8000 ~

剩下的请查看以下代码

;汇编不能使用include包含头文件，所有用Get
;汇编也不认识*.h 文件，所有只能用*.inc
 GET option.inc    ;定义芯片相关的配置
 GET memcfg.inc    ;定义存储器配置
 GET 2440addr.inc  ;定义了寄存器符号

;REFRESH寄存器[22]bit : 0- auto refresh; 1 - self refresh
BIT_SELFREFRESH EQU (1<<22) ;用于节电模式中，SDRAM自动刷新

;处理器模式常量: CPSR寄存器的后5位决定目前处理器模式 M[4:0]
USERMODE    EQU 0x10
FIQMODE     EQU 0x11
IRQMODE     EQU 0x12
SVCMODE     EQU 0x13
ABORTMODE   EQU 0x17
UNDEFMODE   EQU 0x1b
MODEMASK    EQU 0x1f  ;M[4:0]
NOINT       EQU 0xc0

;定义处理器各模式下堆栈地址常量
UserStack EQU (_STACK_BASEADDRESS-0x3800) ;0x33ff4800 ~   _STACK_BASEADDRESS定义在option.inc中
SVCStack EQU (_STACK_BASEADDRESS-0x2800) ;0x33ff5800 ~
UndefStack EQU (_STACK_BASEADDRESS-0x2400) ;0x33ff5c00 ~
AbortStack EQU (_STACK_BASEADDRESS-0x2000) ;0x33ff6000 ~
IRQStack EQU (_STACK_BASEADDRESS-0x1000) ;0x33ff7000 ~
FIQStack EQU (_STACK_BASEADDRESS-0x0) ;0x33ff8000 ~

;arm处理器有两种工作状态 1.arm:32位 这种工作状态下执行字对准的arm指令 2.Thumb:16位 这种工作状
;态执行半字对准的Thumb指令
;因为处理器分为16位 32位两种工作状态 程序的编译器也是分16位和32两种编译方式 所以下面的程序用
;于根据处理器工作状态确定编译器编译方式
;code16伪指令指示汇编编译器后面的指令为16位的thumb指令
;code32伪指令指示汇编编译器后面的指令为32位的arm指令
;
;Arm上电时处于ARM状态，故无论指令为ARM集或Thumb集，都先强制成ARM集，待init.s初始化完成后
;再根据用户的编译配置转换成相应的指令模式。为此，定义变量THUMBCODE作为指示，跳转到main之前
;根据其值切换指令模式
;
;这段是为了统一目前的处理器工作状态和软件编译方式（16位编译环境使用tasm.exe编译
;Check if tasm.exe(armasm -16 ...@ADS 1.0) is used.
 GBLL    THUMBCODE   ;定义THUMBCODE全局变量注意EQU所定义的宏与变量的区别

 [ {CONFIG} = 16   ;如果发现是在用16位代码的话（编译选项中指定使用thumb指令）

THUMBCODE SETL {TRUE}  ;一方面把THUMBCODE设置为TURE

     CODE32    ;另一方面暂且把处理器设置成为ARM模式，以方便初始化

   |      ;（|表示else）如果编译选项本来就指定为ARM模式
THUMBCODE SETL {FALSE}  ;把THUMBCODE设置为FALSE就行了

 ]       ;结束

  MACRO    ;一个根据THUMBCODE把PC寄存的值保存到LR的宏
 MOV_PC_LR    ;宏名称
   [ THUMBCODE       ;如果定义了THUMBCODE，则
     bx lr      ;在ARM模式中要使用BX指令转跳到THUMB指令,并转换模式. 

		;bx指令会根据PC最后1位来确定是否进入thumb状态
   |     	;否则，
     mov pc,lr  ;如果目标地址也是ARM指令的话就采用这种方式
   ]
 MEND     ;宏定义结束标志

  MACRO     ;和上面的宏一样,只是多了一个相等的条件
 MOVEQ_PC_LR
   [ THUMBCODE
        bxeq lr
   |
     moveq pc,lr
   ]
 MEND

;=======================================================================================
;下面这个宏是用于第一次查表过程的实现中断向量的重定向,如果你比较细心的话就是发现
;在_ISR_STARTADDRESS=0x33FF_FF00里定义的第一级中断向量表是采用型如Handle***的方式的.
;而在程序的ENTRY处(程序开始处)采用的是b Handler***的方式.
;在这里Handler***就是通过HANDLER这个宏和Handle***建立联系的.
;这种方式的优点就是正真定义的向量数据在内存空间里,而不是在ENTRY处的ROM(FLASH)空间里,
;这样,我们就可以在程序里灵活的改动向量的数据了.
;========================================================================================
;;这段程序用于把中断服务程序的首地址装载到pc中，有人称之为“加载程序”。
;本初始化程序定义了一个数据区（在文件最后），34个字空间，存放相应中断服务程序的首地址。
;每个字空间都有一个标号，以Handle***命名。

;在向量中断模式下使用“加载程序”来执行中断服务程序。
;这里就必须讲一下向量中断模式和非向量中断模式的概念
;向量中断模式是当cpu读取位于0x18处的IRQ中断指令的时候，系统自动读取对应于该中断源确定
;地址上的指令取代0x18处的指令，通过跳转指令系统就直接跳转到对应地址

;函数中 节省了中断处理时间提高了中断处理速度标 例如 ADC中断的向量地址为0xC0,则在0xC0处
;代放如下码：ldr PC,=HandlerADC 当ADC中断产生的时候系统会自动跳转到HandlerADC函数中

;非向量中断模式处理方式是一种传统的中断处理方法，当系统产生中断的时候，系统将interrupt
;pending寄存器中对应标志位置位 然后跳转到位于0x18处的统一中断函数中
; 该函数通过读取interrupt pending寄存器中对应标志位 来判断中断源 并根据优先级关系再跳到
;对应中断源的处理代码中
;
;H|------|           H|------|        H|------|           H|------|         H|------|
; |/ / / |            |/ / / |         |/ / / |            |/ / / |          |/ / / |
; |------|<----sp     |------|         |------|            |------|          |------|<------sp
;L|      |            |------|<----sp L|------|            |-isr--|          |------| isr==>pc
; |      |            |      |         |--r0--|<----sp     |---r0-|<----sp  L|------| r0==>r0
;    (0)                (1)              (2)                  (3)               (4)

 MACRO
$HandlerLabel HANDLER $HandleLabel

$HandlerLabel     ;标号
 sub sp,sp,#4    ;(1)减少sp(用于存放转跳地址)
 stmfd sp!,{r0}   ;(2)把工作寄存器压入栈(lr does not push because it return to original address)
 ldr     r0,=$HandleLabel;将HandleXXX的址址放入r0
 ldr     r0,[r0]    ;把HandleXXX所指向的内容(也就是中断程序的入口)放入r0
 str     r0,[sp,#4]      ;(3)把中断服务程序(ISR)压入栈
 ldmfd   sp!,{r0,pc}     ;(4)用出栈的方式恢复r0的原值和为pc设定新值(也就完成了到ISR的转跳)
 MEND

;=========================================================================================
;在这里用IMPORT伪指令(和c语言的extren一样)引入|Image$$RO$$Base|,|Image$$RO$$Limit|...
;这些变量是通过ADS的工程设置里面设定的RO Base和RW Base设定的,
;最终由编译脚本和连接程序导入程序.
;那为什么要引入这玩意呢,最简单的用处是可以根据它们拷贝自已
;==========================================================================================
;Image$$RO$$Base等比较古怪的变量是编译器生成的。RO, RW, ZI这三个段都保存在Flash中，但RW，ZI在Flash中
;的地址肯定不是程序运行时变量所存储的位置，因此我们的程序在初始化时应该把Flash中的RW，ZI拷贝到RAM的
;对应位置。一般情况下，我们可以利用编译器替我们实现这个操作。比如我们跳转到main()时，使用 b   __Main,

;编译器就会在__Main和Main之间插入一段汇编代码，来替我们完成RW，ZI段的初始化。 如果我们使用 b   Main，

;那么初始化工作要我们自己做。编译器会生成如下变量告诉我们RO，RW，ZI三个段应该位于什么位置，但是它并

;没有告诉我们RW，ZI在Flash中存储在什么位置，实际上RW，ZI在Flash中的位置就紧接着RO存储。我们知道了

;Image$$RO$$Base，Image$$RO$$Limit，那么Image$$RO$$Limit就是RW（ROM data）的开始。

 IMPORT  |Image$$RO$$Base|  ; Base of ROM code
 IMPORT  |Image$$RO$$Limit|  ; End of ROM code (=start of ROM data)
 IMPORT  |Image$$RW$$Base|   ; Base of RAM to initialise
 IMPORT  |Image$$ZI$$Base|   ; Base and limit of area
 IMPORT  |Image$$ZI$$Limit|  ; to zero initialise

 ;这里引入一些在其它文件中实现在函数,包括为我们所熟知的main函数

 ;IMPORT MMU_SetAsyncBusMode
 ;IMPORT MMU_SetFastBusMode ;hzh

 IMPORT Main

;从这里开始就是正真的代码入口了!
 AREA    Init,CODE,READONLY ;这表明下面的是一个名为Init的代码段

 ENTRY    ;定义程序的入口(调试用)
 EXPORT __ENTRY   ;导出符号_ENTRY,但在那用到就还没查明
__ENTRY

ResetEntry

;1)The code, which converts to Big-endian, should be in little endian code.
;2)The following little endian code will be compiled in Big-Endian mode.
; The code byte order should be changed as the memory bus width.
;3)The pseudo instruction,DCD can not be used here because the linker generates error.
;条件编译，在编译成机器码前就设定好
 ASSERT :DEF:ENDIAN_CHANGE   ;判断ENDIAN_CHANGE是否已定义
 [ ENDIAN_CHANGE      ;如果已经定义了ENDIAN_CHANGE，则（在Option.inc里已经设为FALSE ）
     ASSERT  :DEF:ENTRY_BUS_WIDTH ;判断ENTRY_BUS_WIDTH是否已定义
     [ ENTRY_BUS_WIDTH=32   ;如果已经定义了ENTRY_BUS_WIDTH，则判断是不是为32
  b ChangeBigEndian       ;DCD 0xea000007
     ]
 ;在bigendian中，地址为A的字单元包括字节单元A，A+1，A+2，A+3，字节单元由高位到低位为A，A+1，A+2，A+3
 ;    地址为A的字单元包括半字单元A，A+2，半字单元由高位到低位为A，A+2
     [ ENTRY_BUS_WIDTH=16
  andeq r14,r7,r0,lsl #20    ;DCD 0x0007ea00 也是b ChangeBigEndian指令，只是由于总线不一样而取机器码
     ]        ;的顺序不一样，先取低位->高位 上述指令是通过机器码装换而来的

     [ ENTRY_BUS_WIDTH=8
  streq r0,[r0,-r10,ror #1]  ;DCD 0x070000ea 也是b ChangeBigEndian指令，只是由于总线不一样而取机器码
     ]				;的顺序不一样
 |
     b ResetHandler    ;我们的程序由于ENDIAN_CHANGE设成FALSE就到这儿了,转跳到复位程序入口
    ]

 b HandlerUndef ;handler for Undefined mode  ;0x04
 b HandlerSWI     ;handler for SWI interrupt  ;0x08
 b HandlerPabort ;handler for PAbort    ;0x0c
 b HandlerDabort ;handler for DAbort    ;0x10
 b .          ;reserved 注意小圆点   ;0x14
 b HandlerIRQ  ;handler for IRQ interrupt  ;0x18
 b HandlerFIQ  ;handler for FIQ interrupt  ;0x1c

;@0x20
 b EnterPWDN ; Must be @0x20.

;==================================================================================
;下面是改变大小端的程序,这里采用直接定义机器码的方式,至说为什么这么做就得问三星了
;反正我们程序里这段代码也不会去执行,不用去管它
;==================================================================================
;通过设置CP15的C1的位7，设置存储格式为Bigendian，三种总线方式

ChangeBigEndian ;//here ENTRY_BUS_WIDTH=16
;@0x24

 [ ENTRY_BUS_WIDTH=32
     DCD 0xee110f10 ;0xee110f10 => mrc p15,0,r0,c1,c0,0
     DCD 0xe3800080 ;0xe3800080 => orr r0,r0,#0x80;  //Big-endian
     DCD 0xee010f10 ;0xee010f10 => mcr p15,0,r0,c1,c0,0
     ;对存储器控制寄存器操作，指定内存模式为Big-endian
     ;因为刚开始CPU都是按照32位总线的指令格式运行的，如果采用其他的话，CPU别不了，必须转化
     ;但当系统初始化好以后，则CPU能自动识别
 ]
 [ ENTRY_BUS_WIDTH=16
     DCD 0x0f10ee11
     DCD 0x0080e380
     DCD 0x0f10ee01
     ;因为采用Big-endian模式，采用16位总线时，物理地址的高位和数据的地位对应
     ;所以指令的机器码也相应的高低对调
 ]
 [ ENTRY_BUS_WIDTH=8
     DCD 0x100f11ee
     DCD 0x800080e3
     DCD 0x100f01ee
    ]
 DCD 0xffffffff  ;swinv 0xffffff is similar with NOP and run well in both endian mode.
 DCD 0xffffffff
 DCD 0xffffffff
 DCD 0xffffffff
 DCD 0xffffffff
 b ResetHandler  

;====================================================================================
; Function for entering power down mode
; 1. SDRAM should be in self-refresh mode.
; 2. All interrupt should be maksked for SDRAM/DRAM self-refresh.
; 3. LCD controller should be disabled for SDRAM/DRAM self-refresh.
; 4. The I-cache may have to be turned on.
; 5. The location of the following code may have not to be changed.

;void EnterPWDN(int CLKCON);
EnterPWDN
 mov r2,r0  ;r2=rCLKCON 保存原始数据 0x4c00000c 使能各模块的时钟输入
 tst r0,#0x8  ;测试bit[3] SLEEP mode? 1=>sleep
 bne ENTER_SLEEP ;C=0,即TST结果非0，bit[3]=1

;//进入PWDN后如果不是sleep则进入stop

;//进入Stop mode
ENTER_STOP
 ldr r0,=REFRESH  ;0x48000024   DRAM/SDRAM refresh config
 ldr r3,[r0]   ;r3=rREFRESH
 mov r1, r3
 orr r1, r1, #BIT_SELFREFRESH ;Enable SDRAM self-refresh
 str r1, [r0]  ;Enable SDRAM self-refresh
 mov r1,#16   ;wait until self-refresh is issued. may not be needed.
0
 subs r1,r1,#1
 bne %B0
;//wait 16 fclks for self-refresh
 ldr r0,=CLKCON  ;enter STOP mode.
 str r2,[r0]

 mov r1,#32
0
 subs r1,r1,#1 ;1) wait until the STOP mode is in effect.
 bne %B0   ;2) Or wait here until the CPU&Peripherals will be turned-off
     ;Entering SLEEP mode, only the reset by wake-up is available.

 ldr r0,=REFRESH ;exit from SDRAM self refresh mode.
 str r3,[r0]

 MOV_PC_LR  ;back to main process

ENTER_SLEEP
 ;NOTE.
 ;1) rGSTATUS3 should have the return address after wake-up from SLEEP mode.

 ldr r0,=REFRESH
 ldr r1,[r0]  ;r1=rREFRESH
 orr r1, r1, #BIT_SELFREFRESH
 str r1, [r0]  ;Enable SDRAM self-refresh
;//Enable SDRAM self-refresh

 mov r1,#16   ;Wait until self-refresh is issued,which may not be needed.
0
 subs r1,r1,#1
 bne %B0
;//Wait until self-refresh is issued,which may not be needed

 ldr r1,=MISCCR  ;IO register
 ldr r0,[r1]
 orr r0,r0,#(7<<17)  ;Set SCLK0=1, SCLK1=1, SCKE=1.
 str r0,[r1]

 ldr r0,=CLKCON  ; Enter sleep mode
 str r2,[r0]

 b .   ;CPU will die here.
;//进入Sleep Mode，1）设置SDRAM为self-refresh
;//       2）设置MISCCR bit[17] 1:sclk0=sclk 0:sclk0=0
;//         bit[18] 1:sclk1=sclk 0:sclk1=0
;//         bit[19] 1:Self refresh retain enable
;//           0:Self refresh retain disable
;//           When 1, After wake-up from sleep, The self-refresh will be retained.

WAKEUP_SLEEP
 ;Release SCLKn after wake-up from the SLEEP mode.
 ldr r1,=MISCCR
 ldr r0,[r1]
 bic r0,r0,#(7<<17)  ;SCLK0:0->SCLK, SCLK1:0->SCLK, SCKE:0->=SCKE.
 str r0,[r1]
;//设置MISCCR

 ;Set memory control registers
  ;ldr r0,=SMRDATA
  adrl r0, SMRDATA
 ldr r1,=BWSCON ;BWSCON Address ;//总线宽度和等待控制寄存器
 add r2, r0, #52 ;End address of SMRDATA
0
 ldr r3, [r0], #4 ;数据处理后R0自加4，[R0]->R3，R0+4->R0
 str r3, [r1], #4
 cmp r2, r0
 bne %B0
;//设置所有的memory control register，他的初始地址为BWSCON，初始化
;//数据在以SMRDATA为起始的存储区

 mov r1,#256
0
 subs r1,r1,#1 ;1) wait until the SelfRefresh is released.
 bne %B0
;//1) wait until the SelfRefresh is released.

 ldr r1,=GSTATUS3  ;GSTATUS3 has the start address just after SLEEP wake-up
 ldr r0,[r1]

 mov pc,r0
;//跳出Sleep Mode，进入Sleep状态前的PC

;=================================================================================

;如上所说,这里采用HANDLER宏去建立Hander***和Handle***之间的联系
 LTORG       ;声明文字池,因为我们用了ldr伪指令

HandlerFIQ      HANDLER HandleFIQ
HandlerIRQ      HANDLER HandleIRQ
HandlerUndef    HANDLER HandleUndef
HandlerSWI      HANDLER HandleSWI
HandlerDabort   HANDLER HandleDabort
HandlerPabort   HANDLER HandlePabort

;===================================================================================
;呵呵,来了来了.好戏来了,这一段程序就是用来进行第二次查表的过程了.
;如果说第一次查表是由硬件来完成的,那这一次查表就是由软件来实现的了.
;为什么要查两次表??
;没有办法,ARM把所有的中断都归纳成一个IRQ中断异常和一个FIRQ中断异常
;第一次查表主要是查出是什么异常,可我们总要知道是这个中断异常中的什么中断呀!
;没办法了,再查一次表呗!
;===================================================================================
;//外部中断号判断，通过中断服务程序入口地址存储器的地址偏移确定
;//PC=[HandleEINT0+[INTOFFSET]]
;H|------|
; |/ / / |
; |--isr-|   ====>pc
;L|--r8--|
; |--r9--|<----sp
IsrIRQ
 sub sp,sp,#4        ;给PC寄存器保留 reserved for PC
 stmfd sp!,{r8-r9} ;把r8-r9压入栈

 ldr r9,=INTOFFSET ;把INTOFFSET的地址装入r9  INTOFFSET是一个内部的寄存器,存着中断的偏移
 ldr r9,[r9]   ;I_ISR
 ldr r8,=HandleEINT0 ;这就是我们第二个中断向量表的入口的,先装入r8
;===================================================================================
;哈哈,这查表方法够好了吧,r8(入口)+index*4(别望了一条指令是4 bytes的喔),
;这不就是我们要找的那一项了吗.找到了表项,下一步做什么?肯定先装入了!
;==================================================================================
 add r8,r8,r9,lsl #2  ;地址对齐，因为每个中断向量占4个字节，即isr = IvectTable + Offeset * 4
 ldr r8,[r8]    ;装入中断服务程序的入口
 str r8,[sp,#8]   ;把入口也入栈,准备用旧招
 ldmfd sp!,{r8-r9,pc} ;施招,弹出栈,哈哈,顺便把r8弹出到PC了,跳转成功!

 LTORG

;==============================================================================
; ENTRY(好了,我们的CPU要在这复位了.)
;==============================================================================
ResetHandler
 ldr r0,=WTCON       ;1.关看门狗
 ldr r1,=0x0         ;bit[5]: 0 - disable; 1 - enable (reset 默认)
 str r1,[r0]

 ldr r0,=INTMSK
 ldr r1,=0xffffffff  ;2.关中断
 str r1,[r0]

 ldr r0,=INTSUBMSK
 ldr r1,=0x7fff   ;3.关子中断
 str r1,[r0]

 [ {FALSE}  ;4.得有些表示了,该点点LED灯了,不过被FALSE掉了.
     ;rGPFDAT = (rGPFDAT & ~(0xf<<4)) | ((~data & 0xf)<<4);
     ; Led_Display
 ldr r0,=GPFCON
 ldr r1,=0x5500
 str r1,[r0]
 ldr r0,=GPFDAT
 ldr r1,=0x10
 str r1,[r0]
 ]

;5.为了减少PLL的lock time, 调整LOCKTIME寄存器.
;To reduce PLL lock time, adjust the LOCKTIME register.
 ldr r0,=LOCKTIME
 ldr r1,=0xffffff    ;reset的默认值
 str r1,[r0]

 ;6.下面就来设置PLL了,你的板快不快就看这了!!
 ;这里介绍一下计算公式
;//Fpllo=(m*Fin)/(p*2^s)
;//m=MDIV+8,p=PDIV+2,s=SDIV
;The proper range of P and M: 1<=P<=62, 1<=M<=248

;Fpllo必须大于200Mhz小于600Mhz
;Fpllo*2^s必须小于1.2GHz
;如下面的PLLCON设定中的M_DIV P_DIV S_DIV是取自option.h中
;#elif (MCLK==40000000)
;#define PLL_M (0x48)
;#define PLL_P (0x3)
;#define PLL_S (0x2)
;所以m=MDIV+8=80,p=PDIV+2=5,s=SDIV=2
;硬件使用晶振为10Mhz,即Fin=10Mhz
;Fpllo=80*10/5*2^2=40Mhz
 [ PLL_ON_START

; Added for confirm clock divide. for 2440.
 ; Setting value Fclk:Hclk:Pclk
 ldr r0,=CLKDIVN
 ldr r1,=CLKDIV_VAL 	;0=1:1:1, 1=1:1:2, 2=1:2:2, 3=1:2:4, 4=1:4:4, 5=1:4:8, 

			;6=1:3:3, 7=1:3:6. option.inc中定义CLKDIV_VAL=7
 str r1,[r0]    ;//数据表示分频数

;===============================================================================
;MMU_SetAsyncBusMode 和 MMU_SetFastBusMode 都在4K代码以上,
;如果你想你编译出来的程序能在NAND上运行的话,就不要在这调用这两函数了.
;如果你不要求的话,你就用把.啥事没有.
;为什么是4K,问三星吧,就提供4K的内部SRAM,要是提供400K多好呀.
;好了,好了,4K就4K吧,不能用这两函数,自己写还不行吗,下面的代码这这么来了,
;实现和上面两函数一样的功能.
;===============================================================================
; [ CLKDIV_VAL>1   ; 意思是 Fclk:Hclk 不是 1:1.
; bl MMU_SetAsyncBusMode
; |
; bl MMU_SetFastBusMode ; default value.
; ]

; ==手册第243页==
; If HDIVN is not 0, the CPU bus mode has to be changed from the fast bus mode to the asynchronous
; bus mode using following instructions
;MMU_SetAsyncBusMode
;mrc p15,0,r0,c1,c0,0
;orr r0,r0,#R1_nF:OR:R1_iA
;mcr p15,0,r0,c1,c0,0
 [ CLKDIV_VAL>1   ; 意思是 Fclk:Hclk 不是 1:1.
 mrc p15,0,r0,c1,c0,0
 orr r0,r0,#0xc0000000;R1_nF:OR:R1_iA
 mcr p15,0,r0,c1,c0,0
 |
 mrc p15,0,r0,c1,c0,0
 bic r0,r0,#0xc0000000;R1_iA:OR:R1_nF
 mcr p15,0,r0,c1,c0,0
 ]

 ;配置 UPLL
 ;//Configure UPLL Fin=12.0MHz UFout=48MHz
 ldr r0,=UPLLCON
 ldr r1,=((U_MDIV<<12)+(U_PDIV<<4)+U_SDIV) ;//USB PLL CONFIG 56,2,2===>48MHz
 str r1,[r0]

 ;7个nop必不可少！！
 nop ;// Caution: After UPLL setting, at least 7-clocks delay must be inserted for setting
 nop		  ;hardware be completed.
 nop
 nop
 nop
 nop
 nop

 ;配置 MPLL
 ;//Configure MPLL Fin=12.0MHz MFout=304.8MHz
 ldr r0,=MPLLCON
 ldr r1,=((M_MDIV<<12)+(M_PDIV<<4)+M_SDIV) ;68,1,1 ==>304MHz
 str r1,[r0]
    ]

   ;检查是否从SLEEP模式中恢复
    ;//Check if the boot is caused by the wake-up from SLEEP mode.
 ldr r1,=GSTATUS2
 ldr r0,[r1]
 tst r0,#0x2  ;test if bit[1] is 1 or 0 0->C=1
     ;        1->C=0
 ;In case of the wake-up from SLEEP mode, go to SLEEP_WAKEUP handler.
 bne WAKEUP_SLEEP ;C=0,jump

 EXPORT StartPointAfterSleepWakeUp
StartPointAfterSleepWakeUp

;===============================================================================
;设置内存控制器等寄存器的值,因为这些寄存器是连续排列的,所以采用如下办法对这些
;寄存器进行连续设置.其中用到了SMRDATA的数据,这在代码后面有定义
;===============================================================================
;这是设置SDRAM,flash ROM 存储器连接和工作时序的程序,片选定义的程序
;SMRDATA map在下面的程序中定义
;SMRDATA中涉及的值请参考memcfg.inc程序
;Set memory control registers

  ;ldr r0,=SMRDATA ;dangerous!!!
  adrl r0, SMRDATA  ;be careful!, tinko
 ldr r1,=BWSCON  ;BWSCON Address
 add r2, r0, #52  ;End address of SMRDATA ;SMRDATA数据的结束地址,共有52字节的数据

0
 ldr r3, [r0], #4
 str r3, [r1], #4
 cmp r2, r0
 bne %B0   ;%表示搜索，B表示反向-back(F表示向前-forward)，0为局部标号(0~99)

;================================================================================
;如果 EINT0 产生(这中断就是我们按键产生的), 就清除SDRAM ,不过好像没人会在这个时候按
;================================================================================
; check if EIN0 button is pressed

 ldr r0,=GPFCON
 ldr r1,=0x0     ;00 = Input
 str r1,[r0]
 ldr r0,=GPFUP
 ldr r1,=0xff   ;1- The pull up function is disabled.
 str r1,[r0]

 ldr r1,=GPFDAT
 ldr r0,[r1]
    bic r0,r0,#(0x1e<<1) ; bit clear
 tst r0,#0x1
 bne %F1   ;如果没有按,就跳到后面的1标号处 => Initialize stacks

; 这就是清零内存的代码

 ldr r0,=GPFCON
 ldr r1,=0x55aa
 str r1,[r0]
 ; ldr r0,=GPFUP
 ; ldr r1,=0xff
 ; str r1,[r0]
 ldr r0,=GPFDAT
 ldr r1,=0x0
 str r1,[r0] ;LED=****

 mov r1,#0
 mov r2,#0
 mov r3,#0
 mov r4,#0
 mov r5,#0
 mov r6,#0
 mov r7,#0
 mov r8,#0

 ldr r9,=0x4000000   ;64MB
 ldr r0,=0x30000000
0
 stmia r0!,{r1-r8}
 subs r9,r9,#32
 bne %B0

;到这就结束了.

;//4.初始化各模式下的栈指针
;Initialize stacks

1
 bl InitStacks

;=========================================================================
; 哈哈,下面又有看头了,这个初始化程序好像被名曰hzh的高手改过
; 能在NOR NAND 还有内存中运行,当然了,在内存中运行最简单了.
; 在NOR NAND中运行的话都要先把自己拷到内存中.
; 此外,还记得上面提到的|Image$$RO$$Base|,|Image$$RO$$Limit|...吗?
; 这就是拷贝的依据了!!!
;=========================================================================

;BWSCON的[2:1]反映了外部引脚OM[1:0]:若OM[1:0] != 00, 从NOR FLash启动或直接在内存运行；
;若OM[1:0]==00，则为Nand Flash Mode
 ldr r0, =BWSCON
 ldr r0, [r0]
 ands r0, r0, #6   ; #6 == 0110 --> BWSCON[2:1]
 bne copy_proc_beg   ;OM[1:0] != 00，NOR FLash boot，不读取NAND FLASH

 adr r0, ResetEntry   ;否则,OM[1:0] == 0, 为从NAND FLash启动
 cmp r0, #0     ;再比较入口是否为0地址处
       ;如果是0才是真正从NAND 启动，因为其4k被复制到0地址开始的stepingstone 内部sram中
; 注意adr得到的是 相对 地址，非绝对地址 == if use Multi-ice,
 bne copy_proc_beg   ;如果!=0,说明在using ice, 这种情况也不读取NAND FLASH. 

			;don't read nand flash for boot
;nop

;==============这一段代码完成从NAND Flash读代码到RAM=====================
nand_boot_beg   ;
 mov r5, #NFCONF ;首先设定NAND的一些控制寄存器
;set timing value
 ldr r0, =(7<<12)|(7<<8)|(7<<4)
 str r0, [r5]
;enable control
 ldr r0, =(0<<13)|(0<<12)|(0<<10)|(0<<9)|(0<<8)|(1<<6)|(1<<5)|(1<<4)|(1<<1)|(1<<0)
 str r0, [r5, #4]
 bl ReadNandID  ;按着读取NAND的ID号,结果保存在r5里
 mov r6, #0   ;r6设初值0.
 ldr r0, =0xec73 ;期望的NAND ID号
 cmp r5, r0   ;这里进行比较
 beq %F1   ;相等的话就跳到下一个1标号处
 ldr r0, =0xec75 ;这是另一个期望值
 cmp r5, r0
 beq %F1   ;相等的话就跳到下一个1标号处
 mov r6, #1   ;不相等,设置r6=1.
1
 bl ReadNandStatus ;读取NAND状态,结果放在r1里
 mov r8, #0    ; r8设初值0,意义为页号
 ldr r9, =ResetEntry ; r9设初值为初始化程序入口地址
      ; 注意,在这里使用的是ldr伪指令,而不是上面用的adr伪指令,它加载的是ResetEntry
      ;  的绝对地址,也就是我们期望的RAM中的地址,在这里,它和|Image$$RO$$Base|一样
      ;  也就是说,我如我们编译程序时RO base指定的地址在RAM里,而把生成的文件拷到
      ;  NAND里运行,由ldr加载的r9的值还是定位在内存. ???

2
 ands r0, r8, #0x1f  ;凡r8为0x1f(32)的整数倍-1,eq有效,ne无效
 bne %F3    ;这句的意思是对每个块(32页)进行检错 -- 在每个块的开始页进行
 mov r0, r8    ;r8->r0
 bl CheckBadBlk   ;检查NAND的坏区
 cmp r0, #0   ;比较r0和0
 addne r8, r8, #32  ;存在坏块的话就跳过这个坏块: + 32得到下一块. 

		    ;故: r8 = blockpage addr，因为读写是按页进行的(每页512Byte)
 bne %F4    ;然后跳到4进行循环条件判断。没有的话就跳到标号3处copy当前页
3
 mov r0, r8    ;当前页号->r0
 mov r1, r9    ;当前目标地址->r1
 bl ReadNandPage  ;读取该页的NAND数据到RAM
 add r9, r9, #512  ;每一页的大小是512Bytes
 add r8, r8, #1   ;r8指向下一页
4
 cmp r8, #256   ;比较是否读完256页即128KBytes
      ;注意：这说明此程序默认拷贝128KByte的代码(by Tinko) 

 bcc %B2    ;如果r8小于256(没读完),就返回前面的标号2处
; now  copy completed
 mov r5, #NFCONF  ;Disable NandFlash
 ldr r0, [r5, #4]
 bic r0, r0, #1
 str r0, [r5, #4]

 ldr pc, =copy_proc_beg  ;调用copy_proc_beg
       ;个人认为应该为InitRam ?????????????

;===========================================================
copy_proc_beg
 adrl r0, ResetEntry ;ResetEntry值->r0
        ;这里应该注意，使用的是adr，而不是ldr。使用ldr说明ResetEntry是个绝对地址，这个地址是在程序
        ;链接的时候确定的。而使用adr则说明ResetEntry的地址和当前代码的执行位置有关，它是一个相对的

        ;地址。比如这段代码在stepingstone里面执行，那么ResetEntry的地址就是零。如果在RAM里执行，那

        ;么ResetEntry就应是RAM的一个地址，应该等于RO base。

 ldr r2, BaseOfROM   ;BaseOfROM值(后面有定义)->r2
 cmp r0, r2    ;比较 ResetEntry 和 BaseOfROM
 ldreq r0, TopOfROM  ;如果相等的话(在内存运行 --- ice -- 无需复制code区中的ro段，

		     ;但需要复制code区中的rw段),TopOfROM->r0
 beq InitRam   ;同时跳到InitRam
     	       ;否则，下面开始复制code的RO段
;============================================================
;下面这个是针对代码在NOR FLASH时的拷贝方法
;功能为把从ResetEntry起,TopOfROM-BaseOfROM大小的数据拷到BaseOfROM
;TopOfROM和BaseOfROM为|Image$$RO$$Limit|和|Image$$RO$$Base|
;|Image$$RO$$Limit|和|Image$$RO$$Base|由连接器生成
;为生成的代码的代码段运行时的起启和终止地址
;BaseOfBSS和BaseOfZero为|Image$$RW$$Base|和|Image$$ZI$$Base|
;|Image$$RW$$Base|和|Image$$ZI$$Base|也是由连接器生成
;两者之间就是初始化数据的存放地
; --在加载阶段，不存在ZI区域--
;=============================================================
 ldr r3, TopOfROM
0
 ldmia r0!, {r4-r7}     ;开始时，r0 = ResetEntry --- source
 stmia r2!, {r4-r7}     ;开始时，r2 = BaseOfROM  --- destination
 cmp r2, r3       ;终止条件：复制了TopOfROM-BaseOfROM大小
 bcc %B0

 ;---------------------------------------------------------------
 ; 下面2行，根据理解，由tinko添加
 ; 猜测上面的代码不应该用" ! "，以至于地址被修改。这里重新赋值
 ;---------------------------------------------------------------
 adrl r0, ResetEntry   ;don't use adr, 'cause out of range error occures
 ldr r2, BaseOfROM
       ;旨在计算出正确的RW区起始位置
 ; 下面2行目的是为了计算正确的r0（必须使之指向code区中的rw域开始处）
 sub r2, r2, r3    ;r2=BaseOfROM-TopOfROM=(-)代码长度
 sub r0, r0, r2    ;r0=ResetEntry-(-)代码长度=ResetEntry+代码长度

InitRam
 ;复制代码加载位置中的RM区到|Image$$RW$$Base|
 ldr r2, BaseOfBSS   ;BaseOfBSS->r2 ,  BaseOfBSS = |Image$$RW$$Base|
 ldr r3, BaseOfZero   ;BaseOfZero->r3 , BaseOfZero = |Image$$ZI$$Base|
0
 cmp r2, r3   ;比较BaseOfBSS和BaseOfZero
 ldrcc r1, [r0], #4     ;当代码在内存中运行时，r0(初始值) = TopOfROM.

			;这之后的BaseOfZero-BaseOfBSS仍属于code，需拷贝到BaseOfBSS
 strcc r1, [r2], #4
 bcc %B0

 ;用0初始化ZI区
 mov r0, #0
 ldr r3, EndOfBSS   ;EndOfBSS = |Image$$ZI$$Limit|
1
 cmp r2, r3
 strcc r0, [r2], #4
 bcc %B1

 ;要是r21   ; means Fclk:Hclk is not 1:1.
; bl MMU_SetAsyncBusMode
; |
; bl MMU_SetFastBusMode ; default value.
; ]
;bl Led_Test
;===========================================================

; 进入C语言前的最后一步了,就是把我们用说查二级向量表
; 的中断例程安装到一级向量表(异常向量表)里.
;//5.设置缺省中断处理函数
   ; Setup IRQ handler
 ldr r0,=HandleIRQ       ;This routine is needed
 ldr r1,=IsrIRQ   ;if there isn't 'subs pc,lr,#4' at 0x18, 0x1c
 str r1,[r0]
 ;//initialize the IRQ 将普通中断判断程序的入口地址给HandleIRQ

;/////////////////////////////////////////////////////////
;注意，以下这段可能不需要!!!!!!!!!!!!!!!!!!
;//6.将数据段拷贝到ram中 将零初始化数据段清零 跳入C语言的main函数执行到这步结束bootloader初步引导结束
 ;If main() is used, the variable initialization will be done in __main().
 [ {FALSE}           ;by tinko -- 最外面的条件由tinko添加，实际上不再执行这段
    [ :LNOT:USE_MAIN ;initialized {FALSE}
        ;Copy and paste RW data/zero initialized data

 LDR     r0, =|Image$$RO$$Limit| ; Get pointer to ROM data
 LDR     r1, =|Image$$RW$$Base|  ; and RAM copy
 LDR     r3, =|Image$$ZI$$Base|

 ;Zero init base => top of initialised data
 CMP     r0, r1      ; Check that they are different just for debug????????
 BEQ     %F2
1
 CMP     r1, r3      ; Copy init data
 LDRCC   r2, [r0], #4    ;--> LDRCC r2, [r0] + ADD r0, r0, #4
 STRCC   r2, [r1], #4    ;--> STRCC r2, [r1] + ADD r1, r1, #4
 BCC     %B1
2
 LDR     r1, =|Image$$ZI$$Limit| ; Top of zero init segment
 MOV     r2, #0
3
 CMP     r3, r1      ; Zero init
 STRCC   r2, [r3], #4
 BCC     %B3
    ]
    ]
;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

;***************************************
 ;by tinko
 [ {TRUE}  ;得有些表示了,该点点LED灯了
     ;rGPFDAT = (rGPFDAT & ~(0xf<<4)) | ((~data & 0xf)<<4);
     ; Led_Display
 ldr r0,=GPFCON
 ldr r1,=0x5500
 str r1,[r0]
 ldr r0,=GPFDAT
 ldr r1,=0xe0
 str r1,[r0]

 ldr r2, =0xffffffff;
1
 sub r2,r2,#1
 bne %b1
 ldr r0,=GPFDAT
 ldr r1,=0xe0
 ;b  .   ;die here
 ]
;***************************************
;*****************************************************************************
;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
; 妈呀,终说见到艳阳天了!!!!!!!!!!
;       跳到C语言的main函数处了.
;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
;*****************************************************************************

    [ :LNOT:THUMBCODE ;if thumbcode={false} bl main   L代表logic变量
     bl Main        ;Don't use main() because ......
     b .           ;注意小圆点
    ]

;//if thumbcod={ture}
    [ THUMBCODE         ;for start-up code for Thumb mode
     orr lr,pc,#1
     bx lr
     CODE16
     bl Main        ;Don't use main() because ......
     b .           ;注意小圆点
     CODE32
    ]

;function initializing stacks
InitStacks
 ;Don't use DRAM,such as stmfd,ldmfd......
 ;SVCstack is initialized before
 ;Under toolkit ver 2.5, 'msr cpsr,r1' can be used instead of 'msr cpsr_cxsf,r1'

 mrs r0,cpsr
 bic r0,r0,#MODEMASK
 orr r1,r0,#UNDEFMODE|NOINT
 msr cpsr_cxsf,r1  ;UndefMode
 ldr sp,=UndefStack  ; UndefStack=0x33FF_5C00
 orr r1,r0,#ABORTMODE|NOINT
 msr cpsr_cxsf,r1  ;AbortMode
 ldr sp,=AbortStack  ; AbortStack=0x33FF_6000
 orr r1,r0,#IRQMODE|NOINT
 msr cpsr_cxsf,r1  ;IRQMode
 ldr sp,=IRQStack  ; IRQStack=0x33FF_7000
 orr r1,r0,#FIQMODE|NOINT
 msr cpsr_cxsf,r1  ;FIQMode
 ldr sp,=FIQStack  ; FIQStack=0x33FF_8000
 bic r0,r0,#MODEMASK|NOINT
 orr r1,r0,#SVCMODE
 msr cpsr_cxsf,r1  ;SVCMode
 ldr sp,=SVCStack  ; SVCStack=0x33FF_5800
 ;USER mode has not be initialized.
 ;//为什么不用初始化user的stacks，系统刚启动的时候运行在哪个模式下？
 mov pc,lr
 ;The LR register won't be valid if the current mode is not SVC mode.？
;//系统一开始运行就是SVCmode？
;===========================================================
ReadNandID
 mov      r7,#NFCONF
 ldr      r0,[r7,#4] ;NFChipEn();
 bic      r0,r0,#2
 str      r0,[r7,#4]
 mov      r0,#0x90 ;WrNFCmd(RdIDCMD);
 strb     r0,[r7,#8]
 mov      r4,#0   ;WrNFAddr(0);
 strb     r4,[r7,#0xc]
1       ;while(NFIsBusy());
 ldr      r0,[r7,#0x20]
 tst      r0,#1
 beq      %B1
 ldrb     r0,[r7,#0x10] ;id = RdNFDat()<<8;
 mov      r0,r0,lsl #8
 ldrb     r1,[r7,#0x10] ;id |= RdNFDat();
 orr      r5,r1,r0
 ldr      r0,[r7,#4] ;NFChipDs();
 orr      r0,r0,#2
 str      r0,[r7,#4]
 mov   pc,lr
ReadNandStatus
 mov   r7,#NFCONF
 ldr      r0,[r7,#4] ;NFChipEn();
 bic      r0,r0,#2
 str      r0,[r7,#4]
 mov      r0,#0x70 ;WrNFCmd(QUERYCMD);
 strb     r0,[r7,#8]
 ldrb     r1,[r7,#0x10] ;r1 = RdNFDat();
 ldr      r0,[r7,#4] ;NFChipDs();
 orr      r0,r0,#2
 str      r0,[r7,#4]
 mov   pc,lr
WaitNandBusy
 mov      r0,#0x70 ;WrNFCmd(QUERYCMD);
 mov      r1,#NFCONF
 strb     r0,[r1,#8]
1       ;while(!(RdNFDat()&0x40));
 ldrb     r0,[r1,#0x10]
 tst      r0,#0x40
 beq   %B1
 mov      r0,#0   ;WrNFCmd(READCMD0);
 strb     r0,[r1,#8]
 mov      pc,lr
CheckBadBlk
 mov r7, lr
 mov r5, #NFCONF
 bic      r0,r0,#0x1f ;addr &= ~0x1f;
 ldr      r1,[r5,#4] ;NFChipEn()
 bic      r1,r1,#2
 str      r1,[r5,#4]
 mov      r1,#0x50 ;WrNFCmd(READCMD2)
 strb     r1,[r5,#8]
 mov      r1, #5;6 ;6->5
 strb     r1,[r5,#0xc] ;WrNFAddr(5);(6) 6->5
 strb     r0,[r5,#0xc] ;WrNFAddr(addr)
 mov      r1,r0,lsr #8 ;WrNFAddr(addr>>8)
 strb     r1,[r5,#0xc]
 cmp      r6,#0   ;if(NandAddr)
 movne    r0,r0,lsr #16 ;WrNFAddr(addr>>16)
 strneb   r0,[r5,#0xc]
; bl WaitNandBusy ;WaitNFBusy()
;do not use WaitNandBusy, after WaitNandBusy will read part A!
 mov r0, #100
1
 subs r0, r0, #1
 bne %B1
2
 ldr r0, [r5, #0x20]
 tst r0, #1
 beq %B2
 ldrb r0, [r5,#0x10] ;RdNFDat()
 sub r0, r0, #0xff
 mov      r1,#0   ;WrNFCmd(READCMD0)
 strb     r1,[r5,#8]
 ldr      r1,[r5,#4] ;NFChipDs()
 orr      r1,r1,#2
 str      r1,[r5,#4]
 mov pc, r7
ReadNandPage
 mov   r7,lr
 mov      r4,r1
 mov      r5,#NFCONF
 ldr      r1,[r5,#4] ;NFChipEn()
 bic      r1,r1,#2
 str      r1,[r5,#4]
 mov      r1,#0   ;WrNFCmd(READCMD0)
 strb     r1,[r5,#8]
 strb     r1,[r5,#0xc] ;WrNFAddr(0)
 strb     r0,[r5,#0xc] ;WrNFAddr(addr)
 mov      r1,r0,lsr #8 ;WrNFAddr(addr>>8)
 strb     r1,[r5,#0xc]
 cmp      r6,#0   ;if(NandAddr)
 movne    r0,r0,lsr #16 ;WrNFAddr(addr>>16)
 strneb   r0,[r5,#0xc]
 ldr      r0,[r5,#4] ;InitEcc()
 orr      r0,r0,#0x10
 str      r0,[r5,#4]
 bl       WaitNandBusy ;WaitNFBusy()
 mov      r0,#0   ;for(i=0; i<512; i++)
1
 ldrb     r1,[r5,#0x10] ;buf[i] = RdNFDat()
 strb     r1,[r4,r0]
 add      r0,r0,#1
 bic      r0,r0,#0x10000
 cmp      r0,#0x200
 bcc      %B1
 ldr      r0,[r5,#4] ;NFChipDs()
 orr      r0,r0,#2
 str      r0,[r5,#4]

 mov   pc,r7
;--------------------LED test
 EXPORT Led_Test
Led_Test
 mov r0, #0x56000000
 mov r1, #0x5500
 str r1, [r0, #0x50]
0
 mov r1, #0x50
 str r1, [r0, #0x54]
 mov r2, #0x100000
1
 subs r2, r2, #1
 bne %B1
 mov r1, #0xa0
 str r1, [r0, #0x54]
 mov r2, #0x100000
2
 subs r2, r2, #1
 bne %B2
 b %B0
 mov pc, lr
;===========================================================
;=====================================================================
; Clock division test
; Assemble code, because VSYNC time is very short
;=====================================================================
 EXPORT CLKDIV124
 EXPORT CLKDIV144

CLKDIV124

 ldr     r0, = CLKDIVN
 ldr     r1, = 0x3  ; 0x3 = 1:2:4
 str     r1, [r0]
; wait until clock is stable
 nop
 nop
 nop
 nop
 nop
 ldr     r0, = REFRESH
 ldr     r1, [r0]
 bic  r1, r1, #0xff
 bic  r1, r1, #(0x7<<8)
 orr  r1, r1, #0x470 ; REFCNT135
 str     r1, [r0]
 nop
 nop
 nop
 nop
 nop
 mov     pc, lr
CLKDIV144
 ldr     r0, = CLKDIVN
 ldr     r1, = 0x4  ; 0x4 = 1:4:4
 str     r1, [r0]
; wait until clock is stable
 nop
 nop
 nop
 nop
 nop
 ldr     r0, = REFRESH
 ldr     r1, [r0]
 bic  r1, r1, #0xff
 bic  r1, r1, #(0x7<<8)
 orr  r1, r1, #0x630 ; REFCNT675 - 1520
 str     r1, [r0]
 nop
 nop
 nop
 nop
 nop
 mov     pc, lr

;存储器控制寄存器的定义区
 LTORG
SMRDATA DATA
; Memory configuration should be optimized for best performance
; The following parameter is not optimized.
; Memory access cycle parameter strategy
; 1) The memory settings is  safe parameters even at HCLK=75Mhz.
; 2) SDRAM refresh period is for HCLK<=75Mhz.
 DCD (0+(B1_BWSCON<<4)+(B2_BWSCON<<8)+(B3_BWSCON<<12)+(B4_BWSCON<<16)+(B5_BWSCON<<20)+(B6_BWSCON<<24)+(B7_BWSCON<<28)) ;各bank的bus width; 没有B0，因为由OM[1:0]pins 确定
 DCD ((B0_Tacs<<13)+(B0_Tcos<<11)+(B0_Tacc<<8)+(B0_Tcoh<<6)+(B0_Tah<<4)+(B0_Tacp<<2)+(B0_PMC))  ;GCS0
 DCD ((B1_Tacs<<13)+(B1_Tcos<<11)+(B1_Tacc<<8)+(B1_Tcoh<<6)+(B1_Tah<<4)+(B1_Tacp<<2)+(B1_PMC))  ;GCS1
 DCD ((B2_Tacs<<13)+(B2_Tcos<<11)+(B2_Tacc<<8)+(B2_Tcoh<<6)+(B2_Tah<<4)+(B2_Tacp<<2)+(B2_PMC))  ;GCS2
 DCD ((B3_Tacs<<13)+(B3_Tcos<<11)+(B3_Tacc<<8)+(B3_Tcoh<<6)+(B3_Tah<<4)+(B3_Tacp<<2)+(B3_PMC))  ;GCS3
 DCD ((B4_Tacs<<13)+(B4_Tcos<<11)+(B4_Tacc<<8)+(B4_Tcoh<<6)+(B4_Tah<<4)+(B4_Tacp<<2)+(B4_PMC))  ;GCS4
 DCD ((B5_Tacs<<13)+(B5_Tcos<<11)+(B5_Tacc<<8)+(B5_Tcoh<<6)+(B5_Tah<<4)+(B5_Tacp<<2)+(B5_PMC))  ;GCS5
 DCD ((B6_MT<<15)+(B6_Trcd<<2)+(B6_SCAN))    ;GCS6   B6_MT定义在memcfg.inc中，11-->SDRAM 

							; B6_SCAN - 非reset 默认值
 DCD ((B7_MT<<15)+(B7_Trcd<<2)+(B7_SCAN))    ;GCS7
 DCD ((REFEN<<23)+(TREFMD<<22)+(Trp<<20)+(Trc<<18)+(Tchr<<16)+REFCNT)  ;Tchr- not used
 ;DCD 0x32     ;SCLK power saving mode, BANKSIZE 128M/128M
 DCD 0x31     ;SCLK power saving mode, BANKSIZE 64M/64M
 DCD 0x30     ;MRSR6 CL=3clk
 DCD 0x30     ;MRSR7 CL=3clk
BaseOfROM  DCD |Image$$RO$$Base|
TopOfROM  DCD |Image$$RO$$Limit|
BaseOfBSS  DCD |Image$$RW$$Base|
BaseOfZero  DCD |Image$$ZI$$Base|
EndOfBSS  DCD |Image$$ZI$$Limit|

 ALIGN
 AREA RamData, DATA, READWRITE
 ^   _ISR_STARTADDRESS  ; _ISR_STARTADDRESS=0x33FF_FF00
HandleReset  #   4
HandleUndef  #   4
HandleSWI  #   4
HandlePabort    #   4
HandleDabort    #   4
HandleReserved  #   4
HandleIRQ  #   4
HandleFIQ  #   4
;Don't use the label 'IntVectorTable',
;The value of IntVectorTable is different with the address you think it may be.
;IntVectorTable
;@0x33FF_FF20
HandleEINT0  #   4
HandleEINT1  #   4
HandleEINT2  #   4
HandleEINT3  #   4
HandleEINT4_7 #   4
HandleEINT8_23 #   4
HandleCAM  #   4  ; Added for 2440.
HandleBATFLT #   4
HandleTICK  #   4
HandleWDT  #   4
HandleTIMER0  #   4
HandleTIMER1  #   4
HandleTIMER2  #   4
HandleTIMER3  #   4
HandleTIMER4  #   4
HandleUART2   #   4
;@0x33FF_FF60
HandleLCD   #   4
HandleDMA0  #   4
HandleDMA1  #   4
HandleDMA2  #   4
HandleDMA3  #   4
HandleMMC  #   4
HandleSPI0  #   4
HandleUART1  #   4
HandleNFCON  #   4  ; Added for 2440.
HandleUSBD  #   4
HandleUSBH  #   4
HandleIIC  #   4
HandleUART0  #   4
HandleSPI1   #   4
HandleRTC   #   4
HandleADC   #   4
;@0x33FF_FFA0
 END

通过以下代码的分析,可以得出一些东西

1.       内存中的代码存放是这样一个形式

1	检测大小端代码	入口在这里,处理完成之后,直接进入16
2	中断HandlerUndef
3	中断HandlerSWI
4	HandlerPabort
5	HandlerDabort
6	放了一个小圆点,保留中断
7	HandlerIRQ
8	HandlerFIQ
9	放置一个EnterPWDN段指针
10	ChangeBigEndian段
11	EnterPWDN段
12	ENTER_STOP段
13	ENTER_SLEEP段
14	WAKEUP_SLEEP段
15	IsrIRQ段
16	ResetHandler(主要运行段)	在这里面完成所有的初始化过程并跳转到MAIN函数
17	InitStacks段
18	ReadNandID段
19	ReadNandStatus段
20	WaitNandBusy段
21	CheckBadBlk段
22	ReadNandPage段
23	Led_Test段
24	CLKDIV124段
25	CLKDIV144段
26	定义段结束标识以及中断向量

其中,最精妙的应当属于中断的二次查表过程了,我想再来说一下

2440有60个中断源,但是中断向量却只有FIQ和IRQ两种,发生了IRQ中断之后,系统自动到IRQ中断处,那里放着什么呢?请看

而HandlerIRQ应该是一个标号,这个标号可以转换

转换模式是这样的

最终转换的结果就是

这就说明,发生中断之后,跳转到的第一个位置在HandleIRQ,那这个HandleIRQ在哪?

在这个地方,这个地方是预留了一个函数地址,用于处理IRQ,但是预留的函数到底是什么?需要我们自己去安装,所以在RESET初始化过程中安装了中断

从而可以看到IsrIRQ被安装到了HandleIRQ位置,那我们再来看isrIRQ

首先获得了EINT0的地址

通过这个地址跳转到对应的中断处理程序的指针,可是现在还没写中断处理程序,所以当我们使用的时候还需要一个安装过程,怎么安装,在2440addr.h中给了我们一些宏定义(不是2440addr.inc)

而ISR_STARTADDRESS地址为

(option.inc中)

所以2440addr.h中的指针每一个都是中断向量的地址,要使用中断,只要将中断处理函数地址写入对应的向量就好了,例子如下

定义中断函数

这个__irq又是什么呢?之前的没有啊,这需要看编译器手册

可以看到__irq是编译器关键字,用这个关键字之后编译器在进入这个函数的时候会自动保存相关寄存器

好,启动代码分析完成