[ActionScript 3.0] AS3 绘制正八面体（线条）

分析：

将八面体置于3D坐标系中，其中心的坐标位于原点（0，0，0），让八面体的六个顶点恰好位于3D坐标系的x轴、y轴和z轴上，则从八面体的中心到这六个顶点的距离是相等的。我们可以假设这个距离为r，则六个顶点的坐标分别为上（0，-r，0）、下（0，r，0）、四周：左（-r，0，0）、右（r，0，0）、前（0，0，-r）、后（0，0，r）。

 package
 {
     import flash.display.MovieClip;
     import flash.display.Sprite;
     import flash.events.Event;
     import flash.geom.Point;
     import flash.geom.Vector3D;
 
     /**
      * @author Frost.Yen
      * @E-mail 871979853@qq.com
      * @create 2015-9-7 下午5:10:05
      *
      */
     [SWF(width="800",height="600")]
     public class LineOctahedron extends Sprite
     {
         private var _faceArr:Array = [];
         private var _r:Number = 100;//中心到顶点的距离
         private var _focus:Number = 200;//焦距
         private var _lineContainer:Sprite;
         private var _container:Sprite;
         private var _vertexArr:Array = [{x:0,y:_r,z:0},{x:-_r,y:0,z:0},{x:0,y:0,z:_r},{x:_r,y:0,z:0},{x:0,y:0,z:-_r},{x:0,y:-_r,z:0}];
         public function LineOctahedron()
         {
             initViews();
             initEventListeners();
         }
         private function initViews():void
         {
             _container = new Sprite();
             _lineContainer = new Sprite();
             _container.x = _lineContainer.x = 400;
             _container.y = _lineContainer.y = 300;
             this.addChild(_container);
             this.addChild(_lineContainer);
             createFace();
 
         }
         private function initEventListeners():void
         {
             this.addEventListener(Event.ENTER_FRAME,onEnterFrame);
         }
         private function onEnterFrame(e:Event):void
         {
             for (var i:int=0; i<_faceArr.length; i++)
             {
                 _faceArr[i].transform.matrix3D.appendRotation((mouseX-_lineContainer.x)/50,Vector3D.Y_AXIS);
                 _faceArr[i].transform.matrix3D.appendRotation((mouseY-_lineContainer.y)/50,Vector3D.X_AXIS);
                 _faceArr[i].Z = (_faceArr[i] as MovieClip).transform.getRelativeMatrix3D(_container).position.z;
                 _faceArr[i].X = (_faceArr[i] as MovieClip).transform.getRelativeMatrix3D(_container).position.x*(_focus/(_focus+_faceArr[i].Z));
                 _faceArr[i].Y = (_faceArr[i] as MovieClip).transform.getRelativeMatrix3D(_container).position.y*(_focus/(_focus+_faceArr[i].Z));
                 //利用焦距实现透视
             }
             _lineContainer.graphics.clear();
             _lineContainer.graphics.lineStyle(3,0x00ffff);
             for(i = 1;i<=4;i++){
                 //从上面连到四周;
                 _lineContainer.graphics.moveTo(_faceArr[0].X,_faceArr[0].Y);
                 _lineContainer.graphics.lineTo(_faceArr[i].X,_faceArr[i].Y);
                 //从下面连到四周;
                 _lineContainer.graphics.moveTo(_faceArr[5].X,_faceArr[5].Y);
                 _lineContainer.graphics.lineTo(_faceArr[i].X,_faceArr[i].Y);
                 //四周顶点互连;
                 _lineContainer.graphics.moveTo(_faceArr[i].X,_faceArr[i].Y);
                 _lineContainer.graphics.lineTo(_faceArr[i!=4?i+1:1].X,_faceArr[i!=4?i+1:1].Y);
             }
         }
         private function createFace():void
         {
             for(var i:int = 0;i<6;i++){
                 var mc:MovieClip = new MovieClip();
                 _container.addChild(mc);
                 _faceArr.push(mc);
                 mc.x = _vertexArr[i].x;
                 mc.y = _vertexArr[i].y;
                 mc.z = _vertexArr[i].z;
             }
         }
     }
 }