网络错误修复工具：Network Fault Repair Tool Build20160414

 ::请勿轻易修改此文件,以避免不可预知的错误 gwsbhqt@163.com

 @echo off
 color 0A
 setlocal enabledelayedexpansion
 title Network Fault Repair Tool Build20160414          Made By gwsbhqt@163.com

 echo 网络错误修复工具 & echo 如有任何问题请与 gwsbhqt@163.com 联系... & echo.
 set /p S=继续?(y/n) :
 if /i %S% EQU y (cls & echo 请稍候... & echo.) else (exit)

 set S=F
 set str=以管理员身份运行
 reg query HKU\S-1-5-19\ >nul 2>nul && set S=T
 if %S% EQU T (echo %str% √) else (echo %str% × & goto :error)

 set S=F
 set str=系统支持
 ver | find " 6" >nul 2>nul && set S=T
 ver | find " 10" >nul 2>nul && set S=T
 if %S% EQU T (echo %str% √) else (echo %str% × & goto :error)

 for /l %%i in (1, 1, 6) do (
     if %%i EQU 1 set file=sc
     if %%i EQU 2 set file=reg
     if %%i EQU 3 set file=ping
     if %%i EQU 4 set file=netsh
     if %%i EQU 5 set file=icacls
     if %%i EQU 6 set file=takeown

     set str=!file!.exe 文件存在
     if exist %windir%\System32\!file!.exe (echo !str! √) else (echo !str! × & goto :error)
 )

 for /l %%i in (1, 1, 4) do (
     if %%i EQU 1 set dir=LogFiles& set name=LogFiles
     if %%i EQU 2 set dir=LogFiles\WMI& set name=WMI
     if %%i EQU 3 set dir=wbem& set name=wbem
     if %%i EQU 4 set dir=drivers\etc& set name=etc

     set S=T
     set str=获取 !name! 目录所有权
     takeown /f %windir%\System32\!dir!\ /r /d y >nul 2>nul || set S=F
     icacls %windir%\System32\!dir!\ /reset /t /c /q >nul 2>nul || set S=F
     icacls %windir%\System32\!dir!\ /setowner %username% /t /c /q >nul 2>nul || set S=F
     icacls %windir%\System32\!dir!\ /grant:r system:f /t /c /q >nul 2>nul || set S=F
     icacls %windir%\System32\!dir!\ /grant:r everyone:f /t /c /q >nul 2>nul || set S=F
     icacls %windir%\System32\!dir!\ /grant:r %username%:f /t /c /q >nul 2>nul || set S=F
     icacls %windir%\System32\!dir!\ /grant:r administrators:f /t /c /q >nul 2>nul || set S=F
     if !S! EQU T (echo !str! √) else (call :colour 0C "!str! ×" true)
 )

 set S=F
 set str=删除 Parameters 注册表项
 echo y | reg delete HKLM\System\CurrentControlSet\services\eventlog\Parameters >nul 2>nul
 reg query HKLM\System\CurrentControlSet\services\eventlog\Parameters >nul 2>nul || set S=T
 if %S% EQU T (echo %str% √) else (call :colour 0C "!str! ×" true)

 for /l %%i in (1, 1, 17) do (
     set str=启动& set sta=RUNNING& set cmd=auto& set cmd2=start
     if %%i EQU 1 set srv=eventlog& set name=Windows Event Log
     if %%i EQU 2 set srv=DcomLaunch& set name=DCOM Server Process Launcher
     if %%i EQU 3 set srv=RpcEptMapper& set name=RPC Endpoint Mapper
     if %%i EQU 4 set srv=RpcSs& set name=Remote Procedure Call [RPC]
     if %%i EQU 5 set srv=PlugPlay& set name=Plug and Play
     if %%i EQU 6 set srv=TapiSrv& set name=Telephony
     if %%i EQU 7 set srv=BFE& set name=Base Filtering Engine
     if %%i EQU 8 set srv=IKEEXT& set name=IKE and AuthIP IPsec Keying Modules
     if %%i EQU 9 set srv=PolicyAgent& set name=IPsec Policy Agent
     if %%i EQU 10 set srv=nsi& set name=Network Store Interface Service
     if %%i EQU 11 set srv=Netman& set name=Network Connections
     if %%i EQU 12 set srv=Winmgmt& set name=Windows Management Instrumentation
     if %%i EQU 13 set srv=SstpSvc& set name=※Secure Sckoet Tunneling Protocol Service
     if %%i EQU 14 set srv=RasMan& set name=※Remote Access Connection Manager
     if %%i EQU 15 set srv=RasAuto& set name=※Remote Access Auto Connection Manager
     if %%i EQU 16 set srv=RemoteAccess& set name=Routing and Remote Access
     if %%i EQU 17 set str=禁用& set sta=STOPPED& set cmd=disabled& set cmd2=stop& set srv=SharedAccess& set name=Internet Connection Sharing [ICS]

     set S=F
     set str2=!name! 服务
     sc config !srv! start= !cmd! >nul 2>nul
     sc !cmd2! !srv! >nul 2>nul
     ping 0 /n 4 >nul 2>nul
     sc query !srv! | find "!sta!" >nul 2>nul && set S=T
     if !S! EQU T (echo !str! !str2! √) else (call :colour 0C "!str! !str2! ×" true)
 )

 set S=F
 set str=重置 HOSTS 文件
 del /f /s /q %windir%\System32\drivers\etc\hosts >nul 2>nul
 (echo.> %windir%\System32\drivers\etc\hosts) >nul 2>nul && set S=T
 if !S! EQU T (echo %str% √) else (call :colour 0C "!str! ×" true)

 set S=F
 set str=设置 DCHP状态
 netsh interface ip set address name="本地连接" source=static 192.168.1.1 255.255.255.0 192.168.1.1 >nul 2>nul
 netsh interface ip set address name="本地连接" source=dhcp >nul 2>nul && set S=T
 if %S% NEQ T (netsh interface ip set address name="以太网" source=static 192.168.1.1 255.255.255.0 192.168.1.1 >nul 2>nul & netsh interface ip set address name="以太网" source=dhcp >nul 2>nul && set S=T)
 if %S% EQU T (echo %str% √) else (call :colour 0C "%str% ×" T)

 set S=F
 set str=设置 DNS服务器
 netsh interface ip set dns "本地连接" static 114.114.114.114 primary >nul 2>nul && netsh interface ip add dns "本地连接" 114.114.115.115 >nul 2>nul && set S=T
 if %S% NEQ T (netsh interface ip set dns "以太网" static 114.114.114.114 primary >nul 2>nul && netsh interface ip add dns "以太网" 114.114.115.115 >nul 2>nul && set S=T)
 if %S% EQU T (echo !str! √) else (call :colour 0C "!str! ×" T)

 set S=F
 set str=重启 网络适配器
 netsh interface set interface 本地连接 disabled >nul 2>nul && netsh interface set interface 本地连接 enable >nul 2>nul && set S=T
 if %S% NEQ T (netsh interface set interface 以太网 disabled >nul 2>nul && netsh interface set interface 以太网 enable >nul 2>nul && set S=T)
 if %S% EQU T (echo !str! √) else (call :colour 0C "!str! ×" T)

 for /l %%i in (1, 1, 8) do (
     if %%i EQU 1 set cmd=netsh winsock reset& set str=重置Winsock目录
     if %%i EQU 2 set cmd=ipconfig /release& set str=释放网络连接
     if %%i EQU 3 set cmd=ipconfig /renew& set str=更新网络适配器
     if %%i EQU 4 set cmd=ipconfig /flushdns& set str=清空DNS缓存
     if %%i EQU 5 set cmd=ipconfig /registerdns& set str=刷新DHCP租约并重新注册DNS
     if %%i EQU 6 set cmd=nbtstat /r& set str=重新加载远程缓存
     if %%i EQU 7 set cmd=nbtstat /rr& set str=释放刷新远程缓存
     if %%i EQU 8 set cmd=arp /d& set str=清空ARP缓存

     set S=F
     !cmd! >nul 2>nul && set S=T
     if !S! EQU T (echo !str! √) else (call :colour 0C "!str! ×" T)
 )

 echo. & echo 准备倒计时重启...
 ping 0 /n 6 >nul 2>nul
 for /l %%i in (10, -1, 1) do (
     cls & echo 网络错误修复工具 & echo 如有任何问题请与 gwsbhqt@163.com 联系... & echo. & echo 尝试修复完成,但不保证成功... & echo. & echo 剩余 %%i 秒重启...
     ping 0 /n 2 >nul 2>nul
     if %%i EQU 1 cls & shutdown /r /f /t 0 >nul 2>nul & exit
 )

 goto :eof
 :error
 color 0C & echo. & echo 环境检测异常,修复终止... & pause > nul
 goto :eof

 goto :eof
 :colour Attribute String LineFeed
 pushd "%temp%"&set/p= <nul>"%~2"&findstr /a:%~1 .* "%~2" nul&del "%~2"&popd&if /i "%~3" EQU "T" echo.
 goto :eof