erlang mnesia 数据库实现SQL查询
Mnesia是一个分布式数据库管理系统,适合于电信和其它需要持续运行和具备软实时特性的Erlang应用,越来越受关注和使用,但是目前Mnesia资料却不多,很多都只有官方的用户指南。下面的内容将着重说明 Mnesia 数据库如何实现SQL查询,实现select / insert / update / where / order by / join / limit / delete等SQL操作。
示例中表结构的定义:
- %% 账号表结构
- -record( y_account,{ id, account, password }).
- %% 资料表结构
- -record( y_info, { id, nickname, birthday, sex }).
1、Create Table / Delete Table 操作
- %%===============================================
- %% create table y_account ( id int, account varchar(50),
- %% password varchar(50), primary key(id)) ;
- %%===============================================
- %% 使用 mnesia:create_table
- mnesia:create_table( y_account,[{attributes, record_info(fields, y_account)} ,
- {type,set}, {disc_copies, [node()]} ]).
- %%===============================================
- %% drop table y_account;
- %%===============================================
- %% 使用 mnesia:delete_table
- mnesia:delete_table(y_account) .
注:参数意义可以看文档,{type,set} 表示id作为主键,不允许id重复,如果改为 {type,bag},id可以重复,但整条记录不能重复
2、Select 查询
查询全部记录
- %%===============================================
- %% select * from y_account
- %%===============================================
- %% 使用 mnesia:select
- F = fun() ->
- MatchHead = #y_account{ _ = '_' },
- Guard = [],
- Result = ['$_'],
- mnesia:select(y_account, [{MatchHead, Guard, Result}])
- end,
- mnesia:transaction(F).
- %% 使用 qlc
- F = fun() ->
- Q = qlc:q([E || E <- mnesia:table(y_account)]),
- qlc:e(Q)
- end,
- mnesia:transaction(F).
查询部分字段的记录
- %%===============================================
- %% select id,account from y_account
- %%===============================================
- %% 使用 mnesia:select
- F = fun() ->
- MatchHead = #y_account{id = '$1', account = '$2', _ = '_' },
- Guard = [],
- Result = ['$$'],
- mnesia:select(y_account, [{MatchHead, Guard, Result}])
- end,
- mnesia:transaction(F).
- %% 使用 qlc
- F = fun() ->
- Q = qlc:q([[E#y_account.id, E#y_account.account] || E <- mnesia:table(y_account)]),
- qlc:e(Q)
- end,
- mnesia:transaction(F).
3、Insert / Update 操作
mnesia是根据主键去更新记录的,如果主键不存在则插入
- %%===============================================
- %% insert into y_account (id,account,password) values(5,"xiaohong","123")
- %% on duplicate key update account="xiaohong",password="123";
- %%===============================================
- %% 使用 mnesia:write
- F = fun() ->
- Acc = #y_account{id = 5, account="xiaohong", password="123"},
- mnesia:write(Acc)
- end,
- mnesia:transaction(F).
4、Where 查询
- %%===============================================
- %% select account from y_account where id>5
- %%===============================================
- %% 使用 mnesia:select
- F = fun() ->
- MatchHead = #y_account{id = '$1', account = '$2', _ = '_' },
- Guard = [{'>', '$1', 5}],
- Result = ['$2'],
- mnesia:select(y_account, [{MatchHead, Guard, Result}])
- end,
- mnesia:transaction(F).
- %% 使用 qlc
- F = fun() ->
- Q = qlc:q([E#y_account.account || E <- mnesia:table(y_account), E#y_account.id>5]),
- qlc:e(Q)
- end,
- mnesia:transaction(F).
如果查找主键 key=X 的记录,还可以这样子查询:
- %%===============================================
- %% select * from y_account where id=5
- %%===============================================
- F = fun() ->
- mnesia:read({y_account,5})
- end,
- mnesia:transaction(F).
如果查找非主键 field=X 的记录,可以如下查询:
- %%===============================================
- %% select * from y_account where account='xiaomin'
- %%===============================================
- F = fun() ->
- MatchHead = #y_account{ id = '_', account = "xiaomin", password = '_' },
- Guard = [],
- Result = ['$_'],
- mnesia:select(y_account, [{MatchHead, Guard, Result}])
- end,
- mnesia:transaction(F).
5、Order By 查询
- %%===============================================
- %% select * from y_account order by id asc
- %%===============================================
- %% 使用 qlc
- F = fun() ->
- Q = qlc:q([E || E <- mnesia:table(y_account)]),
- qlc:e(qlc:keysort(2, Q, [{order, ascending}]))
- end,
- mnesia:transaction(F).
- %% 使用 qlc 的第二种写法
- F = fun() ->
- Q = qlc:q([E || E <- mnesia:table(y_account)]),
- Order = fun(A, B) ->
- B#y_account.id > A#y_account.id
- end,
- qlc:e(qlc:sort(Q, [{order, Order}]))
- end,
- mnesia:transaction(F).
6、Join 关联表查询
- %%===============================================
- %% select y_info.* from y_account join y_info on (y_account.id = y_info.id)
- %% where y_account.account = 'xiaomin'
- %%===============================================
- %% 使用 qlc
- F = fun() ->
- Q = qlc:q([Y || X <- mnesia:table(y_account),
- X#y_account.account =:= "xiaomin",
- Y <- mnesia:table(y_info),
- X#y_account.id =:= Y#y_info.id
- ]),
- qlc:e(Q)
- end,
- mnesia:transaction(F).
7、Limit 查询
- %%===============================================
- %% select * from y_account limit 2
- %%===============================================
- %% 使用 mnesia:select
- F = fun() ->
- MatchHead = #y_account{ _ = '_' },
- mnesia:select(y_account, [{MatchHead, [], ['$_']}], 2, none)
- end,
- mnesia:transaction(F).
- %% 使用 qlc
- F = fun() ->
- Q = qlc:q([E || E <- mnesia:table(y_account)]),
- QC = qlc:cursor(Q),
- qlc:next_answers(QC, 2)
- end,
- mnesia:transaction(F).
8、Select count(*) 查询
- %%===============================================
- %% select count(*) from y_account
- %%===============================================
- %% 使用 mnesia:table_info
- F = fun() ->
- mnesia:table_info(y_account, size)
- end,
- mnesia:transaction(F).
9、Delete 查询
- %%===============================================
- %% delete from y_account where id=5
- %%===============================================
- %% 使用 mnesia:delete
- F = fun() ->
- mnesia:delete({y_account, 5})
- end,
- mnesia:transaction(F).
注:使用qlc模块查询,需要在文件顶部声明“-include_lib("stdlib/include/qlc.hrl").”,否则编译时会产生“Warning: qlc:q/1 called, but "qlc.hrl" not included”的警告。
更新说明:
2013/11/20 补充了 mnesia:select 方式的 limit 查询
erlang mnesia 数据库实现SQL查询的更多相关文章
- oracle数据库元数据SQL查询
oracle数据库经典SQL查询 .查看表空间的名称及大小 select t.tablespace_name, round(sum(bytes/(1024*1024)),0) ts_size from ...
- erlang mnesia 数据库查询
Mnesia是一个分布式数据库管理系统,适合于电信和其它需要持续运行和具备软实时特性的Erlang应用,越来越受关注和使用,但是目前Mnesia资料却不多,很多都只有官方的用户指南.下面的内容将着重说 ...
- erlang mnesia数据库设置主键自增
Mnesia是erlang/otp自带的分布式数据库管理系统.mnesia配合erlang的实现近乎理想,但在实际使用当中差强人意,总会有一些不足.mnesia数据表没有主键自增的功能,但在mnesi ...
- erlang mnesia数据库简单应用
mnesia是erlang自带的分布式数据库,基于ets和dets实现的.mnesia兼顾了dets的持久性和ets的高性能,可以自动在多个erlang节点间同步数据库.最关键的是,mnesia实现了 ...
- Python全栈 MySQL 数据库 (SQL查询、备份、恢复、授权)
ParisGabriel 每天坚持手写 一天一篇 决定坚持几年 为了梦想为了信仰 开局一张图 今天接着昨天的说 索引有4种: 普通 索引 :ind ...
- Android adb使用sqlite3对一个数据库进行sql查询
sqlite是Android下集成的一个轻量级数据库,我们可以通过adb程序进入数据库命令行,对数据进行查询,具体操作如下: ①打开windows的cmd ②输入adb shell.此时进入了该安卓系 ...
- 在数据库中sql查询很快,但在程序中查询较慢的解决方法
在写java的时候,有一个方法查询速度比其他方法慢很多,但在数据库查询很快,原来是因为程序中使用参数化查询时参数类型错误的原因 select * from TransactionNo, fmis_Ac ...
- [转载]Oracle数据库基础--SQL查询经典例题
Oracle基础练习题,采用Oracle数据库自带的表,适合初学者,其中包括了一些简单的查询,已经具有Oracle自身特点的单行函数的应用 本文使用的实例表结构与表的数据如下: emp员工表结构如下: ...
- Oracle数据库基础--SQL查询经典例题
Oracle基础练习题,采用Oracle数据库自带的表,适合初学者,其中包括了一些简单的查询,已经具有Oracle自身特点的单行函数的应用 本文使用的实例表结构与表的数据如下: emp员工表结构如下: ...
随机推荐
- ubuntu安装kernel3.10.34
参考http://www.linuxidc.com/Linux/2014-03/98818.htm 32位系统安装 wget kernel.ubuntu.com/~kernel-ppa/mainlin ...
- size()函数的使用
matlab中对于矩阵的计算是十分方便的,其中关于矩阵的函数有很多 size() 在c/c++中sizeof用来求某变量所占用的字节数,在matlab中size()则可以用来求矩阵的“长度”,矩阵的长 ...
- C#时间戳与时间互转
/// <summary> /// 时间戳转成时间类型 /// </summary> /// <param name="timeStamp">& ...
- hbase-site.xml 参数设置
<?xml version="1.0"?> <?xml-stylesheet type="text/xsl" href="confi ...
- iOS 跳转到系统的设置界面-b
在项目中,我们经常会碰到使用位置的需求.当用户设置app不允许使用位置的时候,最好的用户体验就是直接调转到系统的位置设置界面,进行设置. 本人已经测试,在5c iOS8.3系统 和 5s iOS7.1 ...
- (转)汇编bne的问题
网址:http://blog.csdn.net/lwj103862095/article/details/8073571 memsetup: @ 设置存储控制器以便使用SDRAM等外设 mov ...
- [搜片神器]BT种子下载超时很多的问题分析
继续接着第一篇写:使用C#实现DHT磁力搜索的BT种子后端管理程序+数据库设计(开源)[搜片神器] 谢谢园子朋友的支持,已经找到个VPS进行测试,国外的服务器: h31bt.org 大家可以给提点意 ...
- 相似元素存在的意义---HTML&CSS
1.<q> 效果: 告诉浏览器这是一段短引用,让浏览器以合适的方法来显示 注: 不能直接以双引号直接代替<q>,因为有些浏览器<q>的效果不是双引号. 不要忘了移动 ...
- JavaScript 踩坑心得— 为了高速(上)
一.前言 很多情况下,产品的设计与开发人员一直想打造一套高品质的解决方案,从而快速.平稳地适应产品迭代.速度是衡量产品适应性的真正且唯一的标准,而且,这并不是笔者的一家之言. 「速度是衡量适应能力的真 ...
- 时序列数据库武斗大会之什么是 TSDB ?
本文选自 OneAPM Cloud Insight 高级工程师刘斌博客 . 刘斌,一个才思敏捷的程序员,<第一本 Docker 书>.<GitHub 入门与实践>等书籍译者,D ...