Vim技能修炼教程(3) - 语法高亮进阶

语法高亮进阶

首先我们复习一下上节学到的三个命令：

* syntax match用于定义正则表达式和规则的对应

* highlight default定义配色方案

* highlight link将正则规则和配色方案对应起来

但是，定义好了规则，如何让它自动生效呢？我们需要识别文件类型。

识别文件类型

我们创建一个新插件，建立一个ftdetect目录，然后为这个类型创建一个vim文件，比如之前logcat的例子，我们就建立一个logcat.vim。

例子我们还是找github上的：https://github.com/serpent7776/vim-logcat/blob/master/ftdetect/logcat.vim

au BufNewFile,BufRead logcat set filetype=logcat

au是autocmd的缩写，BufNewFile和BufRead是触发自动命令的事件。

BufNewFile是创建一个新文件，BufRead是将文件读入一个新缓冲区时触发。

具体事件可以参看:help autocmd

logcat是文件名匹配的模式。当符合这种模式之后，将filetype设成logcat，就激活了logcat.vim中配置的高亮。

光比较文件名还是有点low的，还可以通过文件内容来识别.我们来看个复杂一点的例子：https://github.com/thinca/vim-logcat/blob/master/ftdetect/logcat.vim

例：

autocmd BufReadPost,BufNewFile *.logcat setlocal filetype=logcat
autocmd BufReadPost,BufNewFile * if getline(1) =~# '^-\{9} beginning of.*$'
\                              |   setfiletype logcat
\                              | endif

更高级的写法，可以将文件内容识别封装成函数：

例子来源于：https://github.com/gburca/vim-logcat/blob/master/ftdetect/logcat.vim

fun! s:DetectLogcat()
    " Detect from the 2nd line. The 1st line could be:
    " -------- beginning of system
    if line('$') > 1 && getline(2) =~# '.*[F|E|W|I|D|V]/\S*\s*(.*\d'
        set filetype=logcat
    endif
endfun

au BufNewFile,BufRead *.lc set filetype=logcat
au BufNewFile,BufRead *.logcat set filetype=logcat
au BufNewFile,BufRead Boot-*_Set-*_Stream-*.txt set filetype=logcat
au BufNewFile,BufRead * call s:DetectLogcat()

如果自动命令没生效，我们也可以通过手动的方式来设置:set filetype=文件类型。filetype太常用了，也可以简写成ft.

vim插件的目录结构

第一讲我们是通过vundle插件来管理插件路径的。在古老的年代里，插件要么写在.vimrc里，要么放在~/.vim/下面。后来，可以通过指定runtimepath，简写为rtp来指定。

每个runtimepath指定的目录都可以包含下面的文件和子目录：

* filetype.vim 根据文件名来判断文件类型

* scripts.vim 根据内容还判断文件类型

* autoload/ 每次启动vim时都自动加载的脚本。相当于是对.vimrc中的autocmd命令的扩展，需要做autocmd的，都可以写进这个目录。详情请参见:help autoload-functions

* colors/ 配色方案，详情请参见:help :colorscheme

* compiler/ 跟各种语言编译器打交道的脚本，后面会讲，详情可参见:help :comp。可以运行下:comp命令试试，会列出一系列的编译器相关的vim文件，可以打开几个看看。

* doc/ 文档。这个需要强调一下，vim是以文档完备而著称的。详情参见:help write-local-help

* ftplugin/ 只处理本缓冲区的file type处理的plugin

* indent/ 处理格式缩进的脚本。详情请看:help :indent-expression

* keymap/ 有点类似于输入法的意思，将一串英文字符转化成多语言的字符，比如中文

* lang/ 菜单文字的翻译

* menu.vim 图形模式下的菜单

* pack/ 插件包。详情可参见:help :packadd

* plugin/ 通用的plugin

* print/ 用于postscript打印的插件

* spell/ 用于拼写检查的插件

* syntax/ 语法高亮，详情请参见:help mysyntaxfile

* tutor/ 教程

对于我们的语法高亮的插件来说，我们可以建立doc, ftdetect和syntax三个目录，分别放文档，类型判断脚本和语法高亮脚本。

关键字高亮

我们上次讲的syn match其实才是高亮的核心武器。不过，针对于一些比较简单的情况，比如语言中的关键字，就可以更简单一些，只要全字匹配就好。

这时候可以用到syntax keyword命令。

我们来看个llvm的例子：

syn keyword llvmType void half float double x86_fp80 fp128 ppc_fp128
syn keyword llvmType label metadata x86_mmx
syn keyword llvmType type label opaque
syn match   llvmType /\<i\d\+\>/

关键字定义了之后，还是要通过hi def link命令跟预定义的配色方案对应起来。

例：

hi def link llvmType Type
hi def link llvmStatement Statement

常用的预定义的配色方案有：

* Comment: 注释

* Identifier：标识符

* Statement：语句

* PreProc：预处理语句

* Type: 数据类型，如int, long, double

* Special: 特殊符号

* Underlined: 带下划线的符号，如超文本链接

* Ignore: 留空

* Error：错误信息

* Todo: TODO, FIXME之类的信息

实际操作练习

下面我们通过一个最简单的例子来检验一下前面的学习成果。

首先，我们在~/.vim/下建立一个ftdetect目录，随便起个文件名字，比如就叫test.vim吧，先做类型匹配：

 autocmd BufNewFile,BufRead *.test set filetype=test

第二步，我们定义几个类型关键字。在~/.vim/下建立syntax目录，还叫test.vim:

if exists("b:current_syntax")
    finish
endif
syntax keyword TestType int long short byte

highlight default link TestType Type

let b:current_syntax = "test"

最后一步，检验一下我们的成果，随便写几句用类型的语名吧，叫xxx.test之类的

int x = 10;
long y = 20;

可以看到，int和long已经被作为关键字被识别出来了。

小作业：在github上建立一个插件，用vunble来下载您的这个插件，实现语法高亮的功能

扩展阅读：

* :help group-name，除了上面介绍的常用预定义组之外，这里有更详细的说明

不过，关键字对于很多情况是不够用的，我们还是要回到上一讲的三步曲上写正则表达式。