IDL实现矢量文件裁剪栅格数据

利用ENVI_SUBSET_VIA_ROI_DOIT函数实现矢量文件裁剪栅格数据。

测试数据：栅格文件是Mercator投影，矢量文件是Geographic坐标系

   infile='F:\Temp_Data\FY3_BEIJING_HFII_DAY_200808031211_Mercator.tif'
   outfile='F:\Temp_Data\FY3_BEIJING_HFII_DAY_200808031211_Mercator_Sub.dat'
   shpfile='F:\Shapefile\beijing.shp'

   envi_open_file,infile,r_fid=tfid
   envi_file_query,tfid,dims=dims,ns=ns,nl=nl,nb=nb
   oproj=envi_get_projection(fid=tfid)
   iproj=envi_proj_create(/geographic)

   oshp=obj_new('IDLffShape',shpfile)
   oshp->GetProperty,n_Entities=n_ent,attribute_info=attr_info,n_attributes=n_attr,Entity_type=ent_type
   roi_ids=lonarr(n_ent)
   for i=0,n_ent-1 do begin
     entity=oshp->GetEntity(i)
     if ptr_valid(entity.parts) ne 0 then begin
       tempLon=reform((*entity.vertices)[0,*])
       tempLat=reform((*entity.vertices)[1,*])
       envi_convert_projection_coordinates, $
         tempLon,tempLat,iproj, $
         xmap,ymap,oproj
       envi_convert_file_coordinates, $
         tfid,xf,yf,xmap,ymap
       roi_ids[i]=envi_create_roi(ns=ns,nl=nl)
       envi_define_roi,roi_ids[i],xpts=xf,ypts=yf,/polygon
     endif

     if i eq 0 then begin
       xmin=round(min(xf,max=xmax))
       ymin=round(min(yf,max=ymax))
     endif else begin
       xmin=xmin<round(min(xf))
       xmax=xmax>round(max(xf))
       ymin=ymin<round(min(yf))
       ymax=ymax>round(max(yf))
     endelse
     oshp->DestroyEntity,entity
   endfor
   obj_destroy,oshp
   xmin=xmin>0
   xmax=xmax<ns
   ymin=ymin>0
   ymax=ymax<nl

   dims=[-1,xmin,xmax,ymin,ymax]
   envi_doit,'envi_subset_via_roi_doit', $
     fid=tfid, $
     dims=dims, $
     ns=ns,nl=nl, $
     pos=indgen(nb), $
     background=0, $
     roi_ids=roi_ids, $
     proj=oproj, $
     out_name=outfile
   envi_file_mng,id=tfid,/remove
   envi_file_mng,id=rfid,/remove
   envi_delete_rois,/all

结果如下：