64位系统VBS调用32位COM组件

标签： 32位, 64位, COM, COM组件, VB, VBS, VBScript

标题: 64位系统VBS调用32位COM组件
作者: Demon
链接: http://demon.tw/programming/64bit-vbs-32bit-com.html
版权: 本博客的所有文章，都遵守“署名-非商业性使用-相同方式共享 2.5 中国大陆”协议条款。

今天有人问我，为什么他的VBS脚本在64位Windows 7中用VbsEdit可以直接执行，但是直接双击就会出错：ActiveX 部件不能创建对象: ‘MSWinsock.Winsock’。

在64位系统中存在两组不同的wscript.exe和cscript.exe，一组是64位的，在C:\Windows\System32文件夹；一组是32位的，在C:\Windows\SysWOW64文件夹。由于64位和32位的内存模式不同，64位进程无法加载32位DLL，故以DLL封装COM组件无法在64位进程调用。

具体到上面的问题，MSWinsock.Winsock是32位COM组件，而直接双击运行VBS文件默认是以C:\Windows\System32\wscript.exe为宿主的，也就是64位的进程，64位进程无法加载32位的DLL，所以会出现“ActiveX 部件不能创建对象”的错误。如果想不报错的话需要手动指定用32位的宿主来执行。

那为什么用VbsEdit可以直接执行呢？因为早期版本的VbsEdit在64位系统上会自动调用32位的wscript.exe或者cscript.exe来执行脚本。对于比较新的VbsEdit，已经区分为32位的VbsEdit何64位的VbsEdit，不同版本的VbsEdit会调用对应版本的wscript.exe或者cscript.exe来执行。

怎样才能在64位系统里直接双击运行包含32位COM组件调用的VBS脚本呢？一种方法是改注册表，但是这个方法不通用；另一种方法是在VBS代码中做检测：

Option Explicit

Run32()

Dim Winsock

Set Winsock = CreateObject("MSWinsock.Winsock")

MsgBox "成功创建MSWinsock.Winsock对象"

Sub Run32()

    'Author: Demon

    'Date: 2015/7/9

    'Website: http://demon.tw

    Dim strComputer, objWMIService, colItems, objItem, strSystemType

    strComputer = "."

    Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")

    Set colItems = objWMIService.ExecQuery("Select * from Win32_ComputerSystem",,48)

    For Each objItem in colItems

        strSystemType = objItem.SystemType

    Next

    If InStr(strSystemType, "x64") > 0 Then

        Dim fso, WshShell, strFullName

        Set fso = CreateObject("Scripting.FileSystemObject")

        Set WshShell = CreateObject("WScript.Shell")

        strFullName = WScript.FullName

        If InStr(1, strFullName, "system32", 1) > 0 Then

            strFullName = Replace(strFullName, "system32", "SysWOW64", 1, 1, 1)

            WshShell.Run strFullName & " " &_

                """" & WScript.ScriptFullName & """", 10, False

            WScript.Quit

        End If

    End If

End Sub

参考链接：https://msdn.microsoft.com/en-us/library/windows/desktop/aa384231(v=vs.85).aspx

随机文章:

这篇文章发布于 2015年07月9日，星期四，12:38，归类于程序设计。您可以跟踪这篇文章的评论通过 RSS 2.0 feed。您可以留下评论，或者从您的站点trackback。

7 条评论发表在“64位系统VBS调用32位COM组件”上

64位系统注册32位COM组件 | Demon's Blog说道：

2015年07月15日 21:57

[…] « 64位系统VBS调用32位COM组件 […]

回复
- 萧萧说道：
  
  2016年11月14日 14:45
  
  我就是在做数据库是遇到了这个问题，现在还是没有看懂
  
  回复
leejoa说道：

2015年07月17日 12:16

所噶，大哥您是CrLf，还是pcl_test？？

回复
- CrLf说道：
  
  2015年12月1日 21:12
  
  感觉应该都不是
  
  回复
雨中风铃说道：

2015年07月24日 14:12

原理很简单，但一直没有人去普及这样的知识，很多vbs代码转到64位平台后都会报错，很多人也不知道怎么处理，比如连接access数据库的代码

回复
老伙计说道：

2016年11月17日 18:27

此代码在 Win7 x64 专业版环境下无效！

回复
炽添火说道：

2017年01月16日 22:47

非常感谢，按照您的方法已经顺利可以双击运行vbs了，之前都是报不能创建Activex的错，困扰好久的问题终于解决了，但是还是遇到另外个问题就是VBS调用组件里的窗体时，窗体闪一下就没了，不知道时什么原因

回复