批量创建采购订单 BAPI_PO_CREATE1
*&---------------------------------------------------------------------*
*& REPORT ZMM_PO_CREATE
*&
*& REPORTNAME :批量创建PO
*&---------------------------------------------------------------------*
*& CREATED BY : LIUXINYUAN
*& CREATED DATE : 2015-03-16
*&---------------------------------------------------------------------*
REPORT ZMM_PO_CREATE.
TYPE-POOLS: SLIS.
TYPE-POOLS:ICON.
*订单类型+採购组织+公司代码+採购组+工厂+供应商+合并标记同样
TYPES:BEGIN OF TY_PO,
BSART TYPE EKKO-BSART, "订单类型
EKORG TYPE EKKO-EKORG, "採购组织
BUKRS TYPE EKKO-BUKRS, "公司代码
EKGRP TYPE EKKO-EKGRP, "採购组
WERKS TYPE EKPO-WERKS, "工厂
LIFNR TYPE EKKO-LIFNR, "供应商
HBBJ(3), "合并标记
PSTYP TYPE EKPO-PSTYP, "行项目类别
MATNR TYPE EKPO-MATNR, "物料号
MENGE(13)," TYPE EKPO-MENGE, "数量
EINDT TYPE EKET-EINDT, "交货期
END OF TY_PO.
DATA:IT_PO TYPE TABLE OF TY_PO WITH HEADER LINE,
WA_PO TYPE TY_PO.
TYPES:BEGIN OF TY_PO_RESULT,
BSART TYPE EKKO-BSART, "订单类型
EKORG TYPE EKKO-EKORG, "採购组织
BUKRS TYPE EKKO-BUKRS, "公司代码
EKGRP TYPE EKKO-EKGRP, "採购组
WERKS TYPE EKPO-WERKS, "工厂
LIFNR TYPE EKKO-LIFNR, "供应商
PSTYP TYPE EKPO-PSTYP, "行项目类别
MATNR TYPE EKPO-MATNR, "物料号
MENGE(13)," TYPE EKPO-MENGE, "数量
EINDT TYPE EKET-EINDT, "交货期
HBBJ(1), "合并标记
EBELN TYPE EKPO-EBELN,
EBELP TYPE EKPO-EBELP,
FLAG(1),
MESSAGE(200),
END OF TY_PO_RESULT.
DATA:IT_PO_RESULT TYPE TABLE OF TY_PO_RESULT WITH HEADER LINE,
TIT_PO_RESULT TYPE TABLE OF TY_PO_RESULT WITH HEADER LINE.
DATA:LV_MESSAGE TYPE STRING.
DATA:LV_EBELN TYPE EKPO-EBELN.
DATA IT_FLDTAB TYPE TPIT_T_FNAME WITH HEADER LINE.
DATA: L_IRC TYPE I,L_LINE TYPE I.
DATA:L_TEXT(200).
DATA:IT_MESSTAB LIKE BDCMSGCOLL OCCURS 0 WITH HEADER LINE.
DATA:G_INFO TYPE STRING.
*----------------------------------------------------------------------*
* CONSTANTS *
*----------------------------------------------------------------------*
CONSTANTS: """上传数据准备
C_BEGIN_ROW TYPE I VALUE 1, "BEGINNING ROW OF EXCEL FILE
C_BEGIN_COL TYPE I VALUE 1, "BEGINNING COLUMN OF EXCEL FILE
C_END_ROW TYPE I VALUE 50000, "ENDING ROW OF EXCEL FILE
C_END_COL TYPE I VALUE 100. "ENDING COLUMN OF EXCEL FILE
*DATA:LV_DTYPE(1).
**ALV
DATA:GT_EVENT_EXIT TYPE SLIS_T_EVENT_EXIT.
DATA:GS_EVENT_EXIT TYPE SLIS_EVENT_EXIT.
DATA:GT_FIELDCAT TYPE LVC_T_FCAT WITH HEADER LINE.
DATA:GC_GLAY TYPE LVC_S_GLAY.
DATA:GS_LAYOUT TYPE LVC_S_LAYO, "SLIS_LAYOUT_ALV,
WK_REPID LIKE SY-REPID.
DATA:GS_GRID TYPE LVC_S_GLAY.
DATA:TEM_GRID TYPE REF TO CL_GUI_ALV_GRID.
DATA:GT_EVENTS TYPE SLIS_T_EVENT.
DATA:GS_EVENTS LIKE LINE OF GT_EVENTS.
DATA:LV_DATUM TYPE SY-DATUM.
SELECTION-SCREEN: FUNCTION KEY 1. "激活下载模板button
**选择屏幕
SELECTION-SCREEN BEGIN OF BLOCK MAIN WITH FRAME TITLE TEXT-001.
* SELECT-OPTIONS:S_BUKRS FOR BKPF-BUKRS.
* SELECT-OPTIONS:S_BUDAT FOR BKPF-BUDAT.
* SELECT-OPTIONS:S_BELNR FOR BKPF-BELNR.
PARAMETERS:P_FILE LIKE RLGRAP-FILENAME ."DEFAULT 'C:\USERS\ADMINISTRATOR\DESKTOP\计划独立需求的批量导入模板.XLS'. "上载文件路径
SELECTION-SCREEN END OF BLOCK MAIN.
AT SELECTION-SCREEN ON VALUE-REQUEST FOR P_FILE.
PERFORM FRM_GET_FILENAME USING P_FILE.
AT SELECTION-SCREEN.
* LOOP AT S_WERKS.
* AUTHORITY-CHECK OBJECT 'Z_MM_003'
* ID 'WERKS' FIELD S_WERKS-LOW.
* IF SY-SUBRC <> 0.
* MESSAGE E019(ZMM001) WITH S_WERKS-LOW.
* ENDIF.
* ENDLOOP.
AT SELECTION-SCREEN OUTPUT.
**主程序
START-OF-SELECTION.
PERFORM FRM_RETRIVE_DATA.
PERFORM FRM_BAPI_CREATE_PO .
PERFORM FRM_DOWNLOAD_DATA.
*&---------------------------------------------------------------------*
*& FORM FRM_BAPI_CREATE_PO
*&---------------------------------------------------------------------*
* TEXT
*----------------------------------------------------------------------*
* --> P1 TEXT
* <-- P2 TEXT
*----------------------------------------------------------------------*
FORM FRM_BAPI_CREATE_PO .
DATA: POHEADER LIKE TABLE OF BAPIMEPOHEADER WITH HEADER LINE ,
POHEADERX LIKE TABLE OF BAPIMEPOHEADERX WITH HEADER LINE,
RETURN LIKE TABLE OF BAPIRET2 WITH HEADER LINE,
POITEM LIKE TABLE OF BAPIMEPOITEM WITH HEADER LINE,
POITEMX LIKE TABLE OF BAPIMEPOITEMX WITH HEADER LINE,
POSCHEDULE LIKE TABLE OF BAPIMEPOSCHEDULE WITH HEADER LINE,
POSCHEDULEX LIKE TABLE OF BAPIMEPOSCHEDULX WITH HEADER LINE,
POTEXTITEM LIKE TABLE OF BAPIMEPOTEXT WITH HEADER LINE.
CONSTANTS: CON VALUE 'X'.
DATA: LIFNR TYPE LFA1-LIFNR,
NETPR TYPE EKPO-NETPR,
ROW TYPE I,
SCHEDULELINE TYPE I.
DATA: EPO LIKE BAPIMEPOHEADER-PO_NUMBER.
DATA: L_RETURN LIKE RETURN.
DATA: LV_ERROR(1).
DATA: LV_AA TYPE STRING,
LV_TYPE TYPE DD01V-DATATYPE.
REFRESH IT_PO_RESULT.
CLEAR IT_PO_RESULT.
REFRESH TIT_PO_RESULT.
CLEAR TIT_PO_RESULT.
SORT IT_PO BY BSART EKORG BUKRS EKGRP WERKS LIFNR HBBJ.
LOOP AT IT_PO.
CLEAR WA_PO.
MOVE-CORRESPONDING IT_PO TO WA_PO.
AT NEW HBBJ.
REFRESH TIT_PO_RESULT.
CLEAR TIT_PO_RESULT.
CLEAR LIFNR.
LIFNR = WA_PO-LIFNR.
CLEAR LV_AA.
CLEAR LV_TYPE.
CALL FUNCTION 'NUMERIC_CHECK'
EXPORTING
STRING_IN = LIFNR
IMPORTING
STRING_OUT = LV_AA
HTYPE = LV_TYPE.
IF LV_TYPE = 'NUMC'.
CALL FUNCTION 'CONVERSION_EXIT_ALPHA_INPUT'
EXPORTING
INPUT = LIFNR
IMPORTING
OUTPUT = LIFNR.
ENDIF.
POHEADER-DOC_TYPE = WA_PO-BSART.
POHEADER-VENDOR = LIFNR.
POHEADER-PURCH_ORG = WA_PO-EKORG.
POHEADER-PUR_GROUP = WA_PO-EKGRP.
POHEADER-COMP_CODE = WA_PO-BUKRS.
POHEADER-DOC_DATE = SY-DATUM.
POHEADERX-DOC_TYPE = CON.
POHEADERX-VENDOR = CON.
POHEADERX-PURCH_ORG = CON.
POHEADERX-PUR_GROUP = CON.
POHEADERX-COMP_CODE = CON.
POHEADERX-DOC_DATE = CON.
ENDAT.
ROW = ROW + 10.
POITEM-PO_ITEM = ROW. "採购凭证的项目编号
POITEM-QUANTITY = WA_PO-MENGE. "採购订单数量
POITEM-MATERIAL = WA_PO-MATNR.
POITEM-PLANT = WA_PO-WERKS. "工厂
IF WA_PO-PSTYP <> ''.
SELECT SINGLE
PSTYP
INTO POITEM-ITEM_CAT
FROM T163Y
WHERE SPRAS = '1'
AND EPSTP = WA_PO-PSTYP.
ELSE.
POITEM-ITEM_CAT = WA_PO-PSTYP.
ENDIF.
IF WA_PO-BSART = 'ZNPI'.
POITEM-FREE_ITEM = 'X'.
ENDIF.
APPEND POITEM.
CLEAR POITEM.
POITEMX-PO_ITEM = ROW . "採购凭证的项目编号
POITEMX-QUANTITY = CON. "採购订单数量
POITEMX-MATERIAL = CON.
POITEMX-PLANT = CON. "工厂
POITEMX-ITEM_CAT = CON.
IF WA_PO-BSART = 'ZNPI'.
POITEMX-FREE_ITEM = CON.
ENDIF.
APPEND POITEMX.
CLEAR POITEMX.
MOVE-CORRESPONDING WA_PO TO TIT_PO_RESULT.
TIT_PO_RESULT-EBELP = ROW.
APPEND TIT_PO_RESULT.
CLEAR TIT_PO_RESULT.
SCHEDULELINE = SCHEDULELINE + 1.
POSCHEDULE-PO_ITEM = ROW . "採购凭证的项目编号
POSCHEDULE-SCHED_LINE = SCHEDULELINE . "採购凭证的项目编号
POSCHEDULE-DEL_DATCAT_EXT = 'D'."交货日期的类别
POSCHEDULE-DELIVERY_DATE = WA_PO-EINDT."交货日期
POSCHEDULE-QUANTITY = WA_PO-MENGE."採购订单数量
APPEND POSCHEDULE.
CLEAR POSCHEDULE.
POSCHEDULEX-PO_ITEM = ROW . "採购凭证的项目编号
POSCHEDULEX-SCHED_LINE = SCHEDULELINE . "採购凭证的项目编号
POSCHEDULEX-DEL_DATCAT_EXT = CON."交货日期的类别
POSCHEDULEX-DELIVERY_DATE = CON."交货日期
POSCHEDULEX-QUANTITY = CON."採购订单数量
APPEND POSCHEDULEX.
CLEAR POSCHEDULEX.
AT END OF HBBJ.
CALL FUNCTION 'BAPI_PO_CREATE1'
EXPORTING
POHEADER = POHEADER
POHEADERX = POHEADERX
* POADDRVENDOR =
* TESTRUN =
* MEMORY_UNCOMPLETE =
* MEMORY_COMPLETE =
* POEXPIMPHEADER =
* POEXPIMPHEADERX =
* VERSIONS =
* NO_MESSAGING =
* NO_MESSAGE_REQ =
* NO_AUTHORITY =
* NO_PRICE_FROM_PO =
IMPORTING
EXPPURCHASEORDER = EPO
* EXPHEADER =
* EXPPOEXPIMPHEADER =
TABLES
RETURN = RETURN
POITEM = POITEM
POITEMX = POITEMX
* POADDRDELIVERY =
POSCHEDULE = POSCHEDULE
POSCHEDULEX = POSCHEDULEX
* POACCOUNT = POACCOUNT
* POACCOUNTPROFITSEGMENT =
* POACCOUNTX = POACCOUNTX
* POCONDHEADER =
* POCONDHEADERX =
* POCOND =
* POCONDX =
* POLIMITS =
* POCONTRACTLIMITS =
* POSERVICES =
* POSRVACCESSVALUES =
* POSERVICESTEXT =
* EXTENSIONIN =
* EXTENSIONOUT =
* POEXPIMPITEM =
* POEXPIMPITEMX =
* POTEXTHEADER =
* POTEXTITEM = POTEXTITEM
* ALLVERSIONS =
* POPARTNER =
* POCOMPONENTS =
* POCOMPONENTSX =
* POSHIPPING =
* POSHIPPINGX =
* POSHIPPINGEXP =
.
CLEAR LV_ERROR.
LOOP AT RETURN INTO L_RETURN WHERE TYPE = 'E' .
LV_ERROR = '1'.
EXIT.
ENDLOOP.
IF LV_ERROR = '1'.
CALL FUNCTION 'BAPI_TRANSACTION_ROLLBACK'.
CLEAR LV_MESSAGE.
LOOP AT RETURN INTO L_RETURN WHERE TYPE = 'E' .
CONCATENATE LV_MESSAGE L_RETURN-MESSAGE ';' INTO LV_MESSAGE.
ENDLOOP.
LOOP AT TIT_PO_RESULT.
TIT_PO_RESULT-FLAG = 'E'.
CONCATENATE '创建PO失败:' LV_MESSAGE INTO TIT_PO_RESULT-MESSAGE.
MODIFY TIT_PO_RESULT.
CLEAR TIT_PO_RESULT.
ENDLOOP.
ELSE.
CALL FUNCTION 'BAPI_TRANSACTION_COMMIT'
EXPORTING
WAIT = 'X'.
CLEAR LV_EBELN.
LOOP AT RETURN INTO L_RETURN WHERE TYPE = 'S' AND ID = '06' AND NUMBER = '017'.
LV_EBELN = L_RETURN-MESSAGE_V2.
ENDLOOP.
LOOP AT TIT_PO_RESULT.
TIT_PO_RESULT-FLAG = 'S'.
TIT_PO_RESULT-MESSAGE = '创建PO成功!'.
TIT_PO_RESULT-EBELN = LV_EBELN.
MODIFY TIT_PO_RESULT.
CLEAR TIT_PO_RESULT.
ENDLOOP.
ENDIF.
LOOP AT TIT_PO_RESULT.
MOVE-CORRESPONDING TIT_PO_RESULT TO IT_PO_RESULT.
APPEND IT_PO_RESULT.
CLEAR IT_PO_RESULT.
ENDLOOP.
REFRESH: POITEM,POITEMX,POSCHEDULE,POSCHEDULEX,POHEADER,POHEADERX,RETURN.
CLEAR: IT_PO, WA_PO, ROW, POITEM,POITEMX,POSCHEDULE,POSCHEDULEX,POHEADER,POHEADERX,RETURN.
ENDAT.
ENDLOOP.
ENDFORM. " FRM_BAPI_CREATE_PO
*&---------------------------------------------------------------------*
*& FORM FRM_GET_FILENAME
*&---------------------------------------------------------------------*
* TEXT
*----------------------------------------------------------------------*
* -->P_P_FILE TEXT
*----------------------------------------------------------------------*
FORM FRM_GET_FILENAME USING P_FILE.
DATA: L_FILETAB TYPE FILETABLE,
L_RC TYPE I.
CLEAR L_FILETAB.
REFRESH L_FILETAB.
* OPEN DIALOG
CALL METHOD CL_GUI_FRONTEND_SERVICES=>FILE_OPEN_DIALOG
EXPORTING
WINDOW_TITLE = '选择上传的文件'
* DEFAULT_EXTENSION =
DEFAULT_FILENAME = '*.XLS'
* FILE_FILTER = '*.XLS'
INITIAL_DIRECTORY = 'C:\'
MULTISELECTION = ''
CHANGING
FILE_TABLE = L_FILETAB
RC = L_RC
EXCEPTIONS
CNTL_ERROR = 1
ERROR_NO_GUI = 2
NOT_SUPPORTED_BY_GUI = 3
OTHERS = 4.
* GET FILE PATH
CHECK L_RC EQ 1.
READ TABLE L_FILETAB INDEX 1 INTO P_FILE.
ENDFORM. " FRM_GET_FILENAME
*&---------------------------------------------------------------------*
*& FORM FRM_RETRIVE_DATA
*&---------------------------------------------------------------------*
* TEXT
*----------------------------------------------------------------------*
* --> P1 TEXT
* <-- P2 TEXT
*----------------------------------------------------------------------*
FORM FRM_RETRIVE_DATA.
CALL FUNCTION 'SAPGUI_PROGRESS_INDICATOR'
EXPORTING
TEXT = '数据处理中.................'.
DATA I_EXCEL TYPE KCDE_INTERN_STRUC OCCURS 0 WITH HEADER LINE.
REFRESH I_EXCEL.
CLEAR I_EXCEL.
*从已知文件名称读入内表
CALL FUNCTION 'KCD_EXCEL_OLE_TO_INT_CONVERT'
EXPORTING
FILENAME = P_FILE
I_BEGIN_COL = 1
I_BEGIN_ROW = 1
I_END_COL = 20
I_END_ROW = 65535
TABLES
INTERN = I_EXCEL[]
EXCEPTIONS
INCONSISTENT_PARAMETERS = 1
UPLOAD_OLE = 2
OTHERS = 3.
IF SY-SUBRC <> 0.
MESSAGE '打开文件错误，请检查文件，确保关闭文件!' TYPE 'E'.
STOP.
ENDIF.
REFRESH IT_PO.
CLEAR IT_PO.
LOOP AT I_EXCEL.
CASE I_EXCEL-COL.
WHEN '001'.
WRITE I_EXCEL-VALUE TO IT_PO-BSART.
WHEN '002'.
WRITE I_EXCEL-VALUE TO IT_PO-EKORG.
WHEN '003'.
WRITE I_EXCEL-VALUE TO IT_PO-BUKRS.
WHEN '004'.
WRITE I_EXCEL-VALUE TO IT_PO-EKGRP.
WHEN '005'.
WRITE I_EXCEL-VALUE TO IT_PO-WERKS.
WHEN '006'.
WRITE I_EXCEL-VALUE TO IT_PO-LIFNR.
WHEN '007'.
WRITE I_EXCEL-VALUE TO IT_PO-PSTYP.
WHEN '008'.
WRITE I_EXCEL-VALUE TO IT_PO-MATNR.
CALL FUNCTION 'CONVERSION_EXIT_ALPHA_INPUT'
EXPORTING
INPUT = IT_PO-MATNR
IMPORTING
OUTPUT = IT_PO-MATNR.
WHEN '009'.
WRITE I_EXCEL-VALUE TO IT_PO-MENGE.
WHEN '010'.
WRITE I_EXCEL-VALUE TO IT_PO-EINDT.
IF I_EXCEL-VALUE <> '交货期'.
CALL FUNCTION 'CONVERT_DATE_TO_INTERNAL'
EXPORTING
DATE_EXTERNAL = I_EXCEL-VALUE
IMPORTING
DATE_INTERNAL = IT_PO-EINDT.
ENDIF.
WHEN '011'.
WRITE I_EXCEL-VALUE TO IT_PO-HBBJ.
ENDCASE.
AT END OF ROW.
APPEND IT_PO.
CLEAR IT_PO.
ENDAT.
ENDLOOP.
* 删除表头
DELETE IT_PO INDEX 1.
ENDFORM. " FRM_RETRIVE_DATA
*&---------------------------------------------------------------------*
*& Form FRM_DOWNLOAD_DATA
*&---------------------------------------------------------------------*
* 下载数据到xls文件
*----------------------------------------------------------------------*
FORM FRM_DOWNLOAD_DATA .
DATA:LV_FILENAME TYPE STRING.
DATA:BEGIN OF T_FIELDNAMES OCCURS 0,
NAME TYPE CHAR20,
END OF T_FIELDNAMES.
REFRESH T_FIELDNAMES.
CLEAR T_FIELDNAMES.
T_FIELDNAMES-NAME = '订单类型'.
APPEND T_FIELDNAMES.
T_FIELDNAMES-NAME = '採购组织'.
APPEND T_FIELDNAMES.
T_FIELDNAMES-NAME = '公司代码'.
APPEND T_FIELDNAMES.
T_FIELDNAMES-NAME = '採购组'.
APPEND T_FIELDNAMES.
T_FIELDNAMES-NAME = '工厂'.
APPEND T_FIELDNAMES.
T_FIELDNAMES-NAME = '供应商'.
APPEND T_FIELDNAMES.
T_FIELDNAMES-NAME = '行项目类别'.
APPEND T_FIELDNAMES.
T_FIELDNAMES-NAME = '物料号'.
APPEND T_FIELDNAMES.
T_FIELDNAMES-NAME = '数量'.
APPEND T_FIELDNAMES.
T_FIELDNAMES-NAME = '交货期'.
APPEND T_FIELDNAMES.
T_FIELDNAMES-NAME = '合并标记'.
APPEND T_FIELDNAMES.
T_FIELDNAMES-NAME = '採购订单号'.
APPEND T_FIELDNAMES.
T_FIELDNAMES-NAME = '採购订单行项目'.
APPEND T_FIELDNAMES.
T_FIELDNAMES-NAME = '订单创建是否成功标记'.
APPEND T_FIELDNAMES.
T_FIELDNAMES-NAME = '订单创建返回信息'.
APPEND T_FIELDNAMES.
CLEAR LV_FILENAME.
CONCATENATE 'C:\PO批导日志' SY-DATUM SY-UZEIT '.XLS' INTO LV_FILENAME.
CALL FUNCTION 'GUI_DOWNLOAD'
EXPORTING
FILENAME = LV_FILENAME "'C:\1234.XLS'
FILETYPE = 'DAT'
"这里一般用DAT，假设用ASC则1000-不会显示为-1000，而DAT会显示为-1000，假设用DBF则不会有缩进，即字符前面的空格会被除去,并且字符的前导0也会输出。
CODEPAGE = '8404'
TABLES
DATA_TAB = IT_PO_RESULT
FIELDNAMES = T_FIELDNAMES.
MESSAGE '已完毕创建凭证,结果保存在C盘文件夹下,请查看!.' TYPE 'I'.
ENDFORM. " FRM_DOWNLOAD_DATA
版权声明：本文博主原创文章。博客，未经同意不得转载。
批量创建采购订单 BAPI_PO_CREATE1的更多相关文章
- 【MM系列】SAP MM模块-收货自动创建采购订单
公众号:SAP Technical 本文作者:matinal 原文出处:http://www.cnblogs.com/SAPmatinal/ 原文链接:[MM系列]SAP MM模块-收货自动创建采购订 ...
- 函数使用一：采购订单BAPI_PO_CREATE1
REPORT YTEST01. DATA:GS_POHEADER TYPE BAPIMEPOHEADER, GS_POHEADERX TYPE BAPIMEPOHEADERX, GT_RETURN T ...
- 创建采购订单批到程序用的BAPI
CALL FUNCTION 'BAPI_PO_CREATE1' EXPORTING poheader = poheader poheaderx = poheaderx * POADDRVENDOR = ...
- 3.21 采购订单导入MDS
3.21.1 业务方案描述 同一企业集团内部的不同法人之间,双方间内部往来业务频繁.受集团财务各自独立核算的要求,买方和卖方间采用买卖方式进行业务运作和财务结算. 对于买方,按照内部商定的协议价格 ...
- 2018.05.17 nace关于采购订单的配置笔记
由于公司的打印都是使用nast作为记录表,在给日企中国客户做扩展时单独配置了一下nace的设置 ZM01作为采购订单批量打印的输出类型,ZM02作为采购订单创建变更时输出的pdf打印输出类型 1.TC ...
- ME_PROCESS_PO_CUST 实现采购订单行项目增强
用户希望创建采购订单时,输入行项目时,能根据采购订单类型,自动带出科目分类类别. 业务顾问看了一下配置,不能实现这个功能,所以用增强实现. 采购订单BADI增强:ME_PROCESS_PO_CUST. ...
- [AX]AX2012 R2 采购订单的“Request change”
在采购订单List或者Detail窗口的操作面板上有一个叫做“Request change”的按钮,如果这个按钮是激活的,采购订单不能直接编辑,而必须先使用这个按钮请求修改后,采购订单才能进入编辑状态 ...
- SAP IDOC 通过采购订单输出消息生成销售订单
题记: 在网络上看到一篇类似的公众号文章,叫<通过IDoc逐步指导PO&SO集成>,个人觉得整个配置过程中还是少了一些重点配置,也少了说明整个功能的核心逻辑,那么,趁着这个机会,就 ...
- 20190615 NACE关于采购订单的输出类型
项目已经做好的配置,我们复盘一下 一.使用NACE 进入输出控制条件: EF 采购订单,首先看->输出类型 标准是使用 nast 作为记录表 1输出类型, 2过程, 3 存取顺序,4 条件记录: ...
随机推荐
- u-boot TFTP: 'Access violation' (2)
今天做tftp下载时间会遇到以下问题. --->8--- Load address: 0x20000000 Loading: * TFTP error: 'Access violation' ( ...
- 分享几个免费的开源邮件server软件
因为企业的须要,我们非常可能须要架设一个邮件server,微软的Exchange太复杂?GOOGLE出来的又收费!头大了吧,OK,贾芸斐在这里给大家分享推荐几个免费的开源的邮件server软件.希望你 ...
- Naive Bayes Classification
Maching Learning QQ群:2 请说明来自csdn 微信:soledede
- Hadoop学习笔记（两）设置单节点集群
本文描写叙述怎样设置一个单一节点的 Hadoop 安装.以便您能够高速运行简单的操作,使用 Hadoop MapReduce 和 Hadoop 分布式文件系统 (HDFS). 參考官方文档:Hadoo ...
- abstract修改方法
abstract这种方法修饰,主要用在抽象类和抽象方法. 抽象的类是不可实例化的比如 public abstract class Test{ } 他能够含有抽象的方法 public abstract ...
- [C/C++]_[VS2010来源与UTF8中国字符串转码ANSI问题]
现场: 1.思想vs设置源文件UTF8编码,代码中国串出现在它必须是utf8编码,不幸的是,,假定源代码将出现在中国字符串,在存储器中转码ANSI编码. Unicode(UTF8签名) 代码页(650 ...
- AndroidAnnotations说明—AndroidAnnotations它是如何工作的？
AndroidAnnotations它的工作原理很easy,它使用标准java注塑加工工具,自己主动加她一个额外的步骤生成源代码编译. 源代码是什么?每个增强的类.比方每个用@EAct ...
- pig询问top k，每个返回hour和ad_network_id最大的两个记录（SUBSTRING，order，COUNT_STAR，limit）
pig里面有一个TOP功能.我不知道为什么用不了.有时间去看看pig源代码. SET job.name 'top_k'; SET job.priority HIGH; --REGISTER piggy ...
- 这两个成员函数inline重新virtual种类
inlineType表示在编译时扩展功能,随着在函数调用的函数体而出替换函数调用:和vitual它是c++多态的必要条件,但为了表现出多态性,您将需要等到执行,要知道什么是真正的函数调用.从表面上看这 ...
- [LeetCode62]Unique Paths
题目: A robot is located at the top-left corner of a m x n grid (marked 'Start' in the diagram below). ...