[ActionSprit 3.0] FMS远程共享

 package
 {
     import flash.display.Sprite;
     import flash.events.NetStatusEvent;
     import flash.events.SyncEvent;
     import flash.net.NetConnection;
     import flash.net.SharedObject;
     import flash.text.TextField;
 
     /**
      * @author Frost.Yen
      * @E-mail 871979853@qq.com
      * @create 2015-7-17 下午4:27:23
      *
      */
     public class SharedRemote extends Sprite
     {
         private var _nc:NetConnection = new NetConnection();
         private var _text:TextField = new TextField();
         private var _so:SharedObject;
         public function SharedRemote()
         {
             _text.x = 100;
             _text.y = 50;
             _text.autoSize = "left";
             this.addChild(_text);
             _nc.connect("rtmp://localhost/TestRemote");
             _nc.addEventListener(NetStatusEvent.NET_STATUS,onStatus);
         }
         private function onStatus(e:NetStatusEvent):void
         {
             trace("connected is: " + _nc.connected );
             trace("e.info.level: " + e.info.level);
             trace("e.info.code: " + e.info.code);
             switch (e.info.code)
             {
                 case "NetConnection.Connect.Success":
                     trace("Congratulations! you're connected");
                     _so = SharedObject.getRemote("testRemote", _nc.uri, true);
                     _so.connect(_nc);
                     var random:int = int(Math.random()*10000);
                     _so.addEventListener(SyncEvent.SYNC, onSync);
                     _so.data.text = "update data:"+random;
 //                    _so.setProperty("text","update data:"+random);
                     break;
                 case "NetConnection.Connect.Rejected":
                 case "NetConnection.Connect.Failed":
                     trace ("Oops! you weren't able to connect");
                     break;
             }
         }
 
         /*当共享数据发生更改时，更新客户端数据*/
         private function onSync(e:SyncEvent):void
         {
             trace(_so.data.text);
             _text.text = _so.data.text;
 
         }
     }
 }